ACTOR SFortPlasmaRifle : PlasmaRifle
{
  Tag "Plasma Rifle"
  +WEAPON.NOAUTOAIM
  +WEAPON.NOLMS
  +WEAPON.ALLOW_WITH_RESPAWN_INVUL
  States
  {
  Ready:
    PLSG A 1 A_WeaponReady(WRF_ALLOWRELOAD)
	Loop
  Deselect:
    PLSG A 0 A_Lower
    Loop
  Select:
    PLSG A 1 A_Raise
    Loop
  Fire:
	TNT1 A 0 A_TakeInventory("PowerInvulnerable",1)
  Hold:
	TNT1 A 0 A_JumpIfInventory("PowerQuadDamage",1,"Quad")
	TNT1 A 0 A_FirePlasma
    PLSG A 3 A_GunFlash("Flash")
	TNT1 A 0 A_ReFire("Hold2")
    PLSG B 20 A_WeaponReady(WRF_NOPRIMARY|WRF_NOBOB)
    Goto Ready
  Hold2:
	TNT1 A 0 A_JumpIfInventory("PowerQuadDamage",1,"Quad2")
	TNT1 A 0 A_FirePlasma
    PLSG A 3 A_GunFlash("Flash2")
	PLSG B 20 A_ReFire("Hold")
    Goto Ready
  Quad:
    TNT1 A 0 A_Playsound("misc/qdmg2",CHAN_7)
	Goto Hold+1
  Quad2:
    TNT1 A 0 A_Playsound("misc/qdmg2",CHAN_7)
	Goto Hold2+1
  Flash:
    PLSF A 3 Bright A_Light1
    Goto LightDone
  Flash2:
    PLSF B 3 Bright A_Light1
    Goto LightDone
  }
}

ACTOR SFortPlasmaBall : PlasmaBall replaces PlasmaBall
{
  Damage (6)
  DamageType "Plasma"
  Speed 50
  ProjectileKickback 200
  Decal Plasmascorchlower
  Decal Plasmascorch
  States
  {
  Death:
    PLSE A 4 Bright A_Explode(15,32,0,0,32)
	PLSE BCDE 4 Bright
    Stop
  }
}