actor GeminiLaserWep : BaseMM8BDMWep 10041
{
//$Category MM8BDM-Weapons
//$Title Gemini Laser
//$Sprite WEAPM0
Weapon.AmmoUse 2
Weapon.AmmoGive 28
Weapon.SlotNumber 2
Inventory.Pickupmessage "$PU_GEMINILASER"
Obituary "$OB_GEMINILASER"
Tag "$TAG_GEMINILASER"
weapon.ammotype "GeminiLaserAmmo"
inventory.icon "GEMISI"
States
{
SpawnLoop:
WEAP M -1
loop
Ready:
BLIZ D 0 ACS_ExecuteAlways(998,0,11)
BLIZ D 1 A_WeaponReady
Goto Ready+1
Deselect:
TNT1 AAAAAAAAAAAAAAAAAAAAAA 0 A_Lower
BLIZ D 1 A_Lower
Loop
Select:
TNT1 AAAAAAAAAAAAAAAAAAAAAA 0 A_Raise
BLIZ D 1 A_Raise
Loop
Fire:
BLIZ D 0 A_JumpIfNoAmmo("NoAmmo")
BLIZ D 0 A_PlaySoundEx("weapon/gemini","Weapon")
BLIZ D 0 A_FireCustomMissile("GeminiLaser",0,1,8,0)
BLIZ EF 3
BLIZ D 16
BLIZ D 0 A_Refire
Goto Ready+1
NoAmmo:
BLIZ D 1 ACS_Execute(979,0)
Goto Ready+1
}
}

actor GeminiLaserAmmo : Ammo
{
inventory.amount 1
inventory.maxamount 28
+INVENTORY.IGNORESKILL
ammo.backpackamount 0
ammo.backpackmaxamount 28
}


actor GeminiLaser
{
PROJECTILE
+HEXENBOUNCE
-ALLOWBOUNCEONACTORS
+CANBOUNCEWATER
+USEBOUNCESTATE
WALLBOUNCEFACTOR 0.95
BOUNCEFACTOR 0.95
Obituary "$OB_GEMINILASER"
speed 53
Radius 5
Height 5
damagetype "GeminiLaser"
scale 2.5
damage (35)
+FORCEXYBILLBOARD
reactiontime 150
Bouncecount 12
States
{
Spawn:
TNT1 A 0
TNT1 A 0 A_SpawnItemEx("GeminiTrail", -momx, -momy, -momz,0, 0, 0, 0,SXF_ABSOLUTEPOSITION)
TNT1 A 0 A_SpawnItemEx("GeminiTrail", momx*(-.25), momy*(-.25), momz*(-.25),0, 0, 0, 0,SXF_ABSOLUTEPOSITION)
TNT1 A 0 A_SpawnItemEx("GeminiTrail", momx*(-.50), momy*(-.50), momz*(-.50),0, 0, 0, 0,SXF_ABSOLUTEPOSITION)
TNT1 A 0 A_SpawnItemEx("GeminiTrail", momx*(-.75), momy*(-.75), momz*(-.75),0, 0, 0, 0,SXF_ABSOLUTEPOSITION)
TNT1 A 1 A_CountDown
loop
Bounce:
TNT1 A 0 A_SpawnItemEx("GeminiImpact")
goto Spawn
}
}

actor GeminiTrail
{
+NOINTERACTION
+NOGRAVITY
+CLIENTSIDEONLY
+FORCEXYBILLBOARD
-SOLID
+BRIGHT
scale 2.5
height 0
radius 0
States
{
Spawn:
GEMI A 4
stop

}
}

actor GeminiTrail2 : GeminiTrail
{
States
{
Spawn:
GEMI A 3 
stop
}
}

actor GeminiImpact : BasicGraphicEffect
{
	Speed 80
	+FORCEXYBILLBOARD
	States
	{
	Spawn:
		TNT1 A 0
		TNT1 AAA 1 A_SpawnItemEx("GeminiImpactFX", 0, 0, 0, 0, 0, 0, 0, SXF_TRANSFERPOINTERS)
		stop
	}
}

actor GeminiImpactFX : GeminiImpact
{
	States
	{
	Spawn:
		GEMI BCDE 2
		stop
	}
}
