actor SpinWheelWep : BaseMM8BDMWep
{
//$Category RNC-Weapons
//$Title Spin Wheel
Weapon.AmmoUse 1
Weapon.AmmoGive 56
Weapon.SlotNumber 3
Tag "$TAG_SPINWHEEL"
Obituary "$OB_SPINWHEEL"
Inventory.Pickupmessage "$PU_SPINWHEEL"
weapon.ammotype "SpinWheelAmmo"
inventory.icon "RNCWP6"
States
{
SpawnLoop:
RNCW F -1
loop
Ready:
NCH2 K 0 ACS_ExecuteAlways(998,0,COL_SPINWHEEL)
NCH2 K 0 A_JumpIfNoAmmo(2)
NCH2 K 1 A_WeaponReady
Goto Ready+1
NCH2 U 1 A_WeaponReady
Goto Ready+1
Deselect:
TNT1 AAAAAAAAAAAAAAAAAAAAAA 0 A_Lower
NCH2 K 1 A_Lower
Loop
Select:
TNT1 AAAAAAAAAAAAAAAAAAAAAA 0 A_Raise
NCH2 K 1 A_Raise
Loop
Fire:
NCH2 K 0 A_JumpIfNoAmmo("NoAmmo")
NCH2 K 0 A_PlaySoundEx("weapon/metalblade","Weapon")
NCH2 K 0 A_FireCustomMissile("SpinWheelSpawner",0,1,8,0)
NCH2 LMNOP 1
TNT1 A 2
TNT1 A 0 A_JumpIfNoAmmo(4)
NCH2 QR 1
NCH2 R 0 A_Refire
Goto Ready+1
NCH2 ST 1
NCH2 T 0 A_Refire
Goto Ready+1
NoAmmo:
NCH2 U 1 ACS_Execute(979,0)
Goto Ready+1
}
}
actor SpinWheelWepSH : SpinWheelWep replaces SpinWheelWep
{+INVENTORY.RESTRICTABSOLUTELY Inventory.RestrictedTo megamans}

actor SpinWheelAmmo : Ammo {inventory.amount 1 inventory.maxamount 56}

actor SpinWheelSpawner : ScrewCrusherSpawner
{
speed 1
States
{
Spawn:
TNT1 A 0
TNT1 A 1 A_SpawnItemEx("SpinWheel", 0, 0, 0, momx*1.0, momy*1.0, 0.3+momz*0.7, 0, SXF_MULTIPLYSPEED|SXF_ABSOLUTEMOMENTUM)stop
}
}

actor SpinWheel
{
PROJECTILE
damagetype "SpinWheel"
Obituary "$OB_SPINWHEEL"
scale 2.5
-NOGRAVITY
+DONTBLAST
Speed 14
Radius 15
Height 8
gravity 1.0
Damage (25)
reactiontime 30
States
{
Spawn:
TNT1 A 0
TNT1 A 1 ThrustThingZ(0,15,0,1)
RNCP NOP 3
Goto Spawn+3
Death:
TNT1 A 1 A_SpawnItemEx("WheelForward")
stop
XDeath:
TNT1 A 0
stop
}
}

actor WheelForward
{
PROJECTILE
damagetype "SpinWheel"
Obituary "$OB_SPINWHEEL"
scale 2.5
-NOGRAVITY
+DONTBLAST
+NOEXPLODEFLOOR
Speed 0
Radius 15
Height 8
gravity 1.0
Damage (30)
reactiontime 30
States
{
Spawn:
RNCP NOP 3 A_Recoil(-20)
Loop
}
}