

ACTOR NukageFallToxicity  17889
{
	+NOGRAVITY
	Mass 99999
	-SHOOTABLE
	+THRUACTORS
	+NOCLIP
	+NOBLOCKMAP
	+THRUACTORS
	+NOTARGET
	+NEVERTARGET
	//$SPRITE FRPRC0
	States {
		Spawn:
			TNT1 AAAA 2 A_CustomMissile ("NukageFallStreamEffect", 0, random(0, 16), random (20, 160), 2, -90)
			TNT1 A 0 A_CustomMissile ("NukageFallAOEEffect", 0, random(0, 16), random (20, 160), 2, -90)
			Loop
	
	}
}
	
ACTOR NukageFallStreamEffect: FastProjectile
{
	Radius 4
	Height 4
	Speed 200
	FastSpeed 200
	+NODAMAGETHRUST
	Translation "208:223=152:157", "236:239=109:109", "160:167=152:159", "224:231=152:152", "48:63=152:156", "0:0=111:111"
	Scale 1.0
	Alpha 0.15
	Renderstyle Translucent
	States {
		Spawn:
			TNT1 A 1
			Loop
		Death:
			TNT1 A 0 
			TNT1 A 0 A_Stop
			TNT1 A 0 A_RadiusGive("ToxicDOT15_5", 24, RGF_PLAYERS | RGF_MONSTERS) // triple the rate if standing under the stream!
			Stop
	}
}

ACTOR NukageFallAOEEffect: NukageFallStreamEffect
{
	States {
		Death:
			TNT1 A 0 
			TNT1 A 0 A_Stop
			TNT1 A 0 A_RadiusGive("ToxicDOT", 120, RGF_PLAYERS | RGF_MONSTERS) // | RGF_OBJECTS)
			EFIR BCD 2 A_CustomMissile ("NukageWaterfallParticle", 1, 0, random (0, 360), 2, random (40, 90))
			EFIR BCDEFGHIJKLM 2
			Stop
	}
}


ACTOR ToxicDOT15_5: ToxicDOT {
	// increase 3x, from 5/second to 15/second, make the total amount run its course faster
	States
    {
		Pickup:
			TNT1 A 0
			// script checks for radsuit
			TNT1 A 0 ACS_NamedExecuteWithResult("FBD_RunToxicDOT", 5, 15)
			Stop
    }
}