actor ClassBase0 : PlayerPawn
{
player.displayname "megaman"
player.soundclass "megaman"
player.damagescreencolor "yellow"
player.forwardmove 0.8, 0.8
player.sidemove 0.78, 0.78
player.jumpz 10
Player.MaxHealth 100
player.colorrange 0 0
player.startitem "MegaBuster"
player.startitem "BusterAmmo", 3
player.startitem "ModeWeps", 1
player.startitem "BaseFlagPack", 1
painchance 256
mass 9999
gravity 0.8
renderstyle translucent
alpha 1.0
+NOGRAVITY
-SOLID
+THRUSPECIES
species "Megaman"
+NODAMAGETHRUST
+DONTBLAST
+NOBLOOD
+QUICKTORETALIATE
+USEDAMAGEEVENTSCRIPT
damagefactor "Dummy", 0.0
Player.MaxSkinSizeFactor 0, 0
scale 2.5
bloodtype "MegamanBlood"
var int user_hp;
States
{
SuperSpawn:
"----" A 1 A_Jump(256,"Spawn")
wait
SuperClassPain:
"----" A 1 A_Jump(256,"ClassPain")
wait
SuperClassDeath:
"----" A 1 A_Jump(256,"ClassDeath")
wait

ClassPain:
"----" A 0 A_Log("Please define ClassPain on this class")
"----" A 1 A_Jump(256,"MegamanPain")
wait
ClassDeath:
"----" A 0 A_Log("Please define ClassDeath on this class")
"----" A 1 A_Jump(256,"MegamanDeath")
wait

MegamanPain:
"----" A 0 A_Pain
"----" AAAAAAAAAA 2 A_SpawnItemEx("PainFX",-5,0,3,0,0,0)
"----" A 1
goto SuperSpawn

MegamanDeath:
"----" AAAAAAAAAAAAAAAAAAAA 1 A_JumpIfInventory("CriticalDeath",1,"MegamanGib")
MegamanExplode:
"----" A 0 A_SpawnItemEx("FakeDeathFX", 0, 0, 32)
MegamanFall:
"----" A 0 A_PlayerScream
MegamanErase:
//TNT1 A 1 A_CheckPlayerDone
"####" Z 1 A_CheckPlayerDone
wait
MegamanGib:
"----" A 0 A_GiveInventory("CriticalDeathGiver", 1)
"----" A 0 A_SpawnItemEx("FakeDeathFX", 0, 0, 32)
goto MegamanErase

// SINGLEPLAYER STUFF
TheEnd: // Used in the original ending
"####" G 4
loop
WalkForward: 
"####" BBBBBCCCCCDDDDDEEEEE 1 A_Recoil(-0.8)
loop
CreditWalk: 
"####" BCDE 8
loop
CreditRun:
"####" BCDE 5
loop
DozerCarry:
"####" BBBBCCCCDDDDEEEEBBBBCCCCDDDDBBBBCCCCDDDD 1 A_Recoil(-1)
"####" F 10 A_Stop
"####" F -1
stop
DozerThrow:
"####" F 0 A_ChangeFlag("THRUACTORS",1)
"####" F 20 ThrustThingZ(0, 60, 0, 1)
"####" G 20
"####" A -1
stop
EndlessPain:
"####" H -1
stop
NoSprite:
"####" Z 1
loop
}
}