class JetpackJerk : SquareMonster
{
	Default
	{
		Speed 8;
		FastSpeed 12;
		Height 56;
		Health 300;
		PainChance 64;
		Mass 1200;
		BloodColor "ff d9 30";
		Obituary "$OB_JETPACKJERK";
		+FLOAT;
		+NOGRAVITY;
		SeeSound "circlejerk/jetpack/see";
		PainSound "circlejerk/jetpack/pain";
		DeathSound "circlejerk/jetpack/death";
		ActiveSound "circlejerk/jetpack/active";
	}
	States
	{
	Spawn:
		JETJ AB 4 A_Look();
		Loop;
	See:
		JETJ AABB 2 A_Chase();
		Loop;
	Missile:
		JETJ CCCC 4 A_FaceTarget();
		JETJ D 0 Bright A_SpawnProjectile("JetpackJerkLaserSilent", 46, 20, 0);
		JETJ D 4 Bright A_SpawnProjectile("JetpackJerkLaser", 46, 24, 0);
		JETJ E 4;
		Goto See;
	Pain:
		JETJ F 3;
		JETJ F 3 A_Pain();
		Goto See;
	Death:
		JETJ F 0 A_NoBlocking();
		JETJ F 2 A_Scream();
		JETJ F 4 A_SpawnItem("GibSpawnerJetpackJerk");
		JETJ F 0 A_SpawnItemEx("ExplosionAlt", 0.0, 0.0, 24.0);
		JETJ F 0 A_SpawnItemEx("GibEye", -8.0, 0.0, 40.0, random[SquareGibRandom](-2,2), random[SquareGibRandom](-2,2));
		JETJ F 0 A_SpawnItemEx("GibEye", 8.0, 0.0, 40.0, random[SquareGibRandom](-2,2), random[SquareGibRandom](-2,2));
		LEGS A -1;
		Stop;
	}
}
