class Tritankle : SquareMonster
{
	Default
	{
		Health 450;
		FastSpeed 16;
		SeeSound "tritankle/see";
		PainSound "tritankle/pain";
		DeathSound "tritankle/death";
		AttackSound "tritankle/minigun/fire";
		Obituary "$OB_TRITANKLE";
		PainChance 100;
		+NOTARGET;
		+NOBLOOD;
		+NEVERRESPAWN;
		+DONTBLAST;
		Mass 2000;

		DamageFactor "Vacuum", 0.0;
	}
	States
	{
	Spawn:
		TRIT A 0;
		TRIT A 0 A_StopSound(5);
		TRIT A 1 A_Look();
		Wait;
	See:
		TRIT A 0 A_PlaySound("tritankle/active", 5, 0.8, 1);
		SeeLoop:
		TRIT ABCB 3 A_Chase();
		Loop;
	Missile:
		TRIT A 0 A_StopSound(5);
		TRIT A 0 A_PlaySound("tritankle/minigun/begin");
		TRIT A 10 A_FaceTarget();
		TRIT DEF 2 A_FaceTarget();
	MissileLoop:
		TRIT G 0 A_FaceTarget();
		TRIT G 2 Bright A_CustomBulletAttack(10, 3, 1, 3, "PaintPuff4");
		TRIT G 2;
		TRIT H 2 Bright A_CustomBulletAttack(10, 3, 1, 3, "PaintPuff4");
		TRIT H 2;
		TRIT H 0 A_SpidRefire();
		Loop;
	Pain:
		TRIT I 3 A_StopSound(5);
		TRIT I 3 A_Pain();
		Goto See;
	Death:
		TRIT A 0 A_StopSound(5);
		TRIT I 2 A_Scream();
		TRIT I 0 A_Fall();
		TRIT I 0 Bright A_SpawnItem("CrystalGibSpawner");
		TRIT I 2 Bright A_SpawnItem("MibSpawnerTritankle");
		TRIT J 0 A_Explode(60,100);
		TRIT J 0 A_Fall();
		TRIT J 2 Bright A_SpawnItemEx("ExplosionAlt", 0, 0, 20);
		TRIT JJJJJJJJJJ 2 A_SpawnItemEx("Smoke", frandom(-7.0,7.0), frandom(-7.0,7.0), 4.0, 0, 0, 2);
		TRIT JJJJJJJJJJ 2 A_SpawnItemEx("Smoke", frandom(-7.0,7.0), frandom(-7.0,7.0), 4.0, 0, 0, 2);
		TRIT J -1;
		Stop;
	}
}
