ACTOR SFortFist : Fist
{
  Obituary "%o was fisted by %k."
  Tag "Fist"
  DamageType "Fist"
  +WEAPON.NOLMS
  +WEAPON.ALLOW_WITH_RESPAWN_INVUL
  States
  {
  Ready:
    PUNG A 1 A_WeaponReady(WRF_ALLOWRELOAD)
    Loop
  Deselect:
    PUNG A 0 A_Lower
    Loop
  Select:
    PUNG A 1 A_Raise
    Loop
  Fire:
  FireNormal:
	TNT1 A 0 A_TakeInventory("PowerInvulnerable",1)
    PUNG B 2
	TNT1 A 0 A_JumpIfInventory("PowerQuadDamage",1,"Quad")
	TNT1 A 0 A_JumpIfInventory("PowerStrength",1,"Berserked")
    PUNG C 2 A_CustomPunch(100,true,0,"FistHitPuff",72)
  FireEnd:
    PUNG D 5
    PUNG C 4
	PUNG B 4
    PUNG B 1 A_ReFire
    Goto Ready
  Quad:
    TNT1 A 0 A_Playsound("misc/qdmg",CHAN_AUTO)
	Goto FireNormal+3
  Berserked:
    PUNG E 2 A_CustomPunch(1000,true,0,"FistHitPuff",70)
    PUNG F 5
	PUNG E 4
    Goto FireEnd+2
  }
}

ACTOR FistHitPuff : BulletPuff
{
  +PUFFONACTORS
  SeeSound "weapons/punch"
  ActiveSound "silent"
  AttackSound "weapons/pwall"
  DamageType "Fist"
  Decal BulletChip
  States
  {
  Spawn:
	PUFF CD 3
    Stop
  }
}