ACTOR BloodDemonClone : FPlus_Monster 3110
{ 
spawnid 237
	//$Category Monsters
    Health 300 
    Speed 12 
    Height 56
    Radius 15
    Mass 400
    PainChance 180
    //Meleedamage 5 
    REACTIONTIME 8 
    +FLOORCLIP
    SeeSound "blooddemon/sight"
    PainSound "blooddemon/pain"
    DeathSound "blooddemon/death"
    ActiveSound "blooddemon/active"
    //MeleeSound "blooddemon/melee"
    HitObituary "%o Was chewed up and spat out by a Mech-demon." 
	
	meleerange 64
	
    States 
    { 
    Spawn: 
       SRG2 AB 10 A_Look
       goto Spawn 
    See: 
       SRG2 A 0 A_PlaySound("blooddemon/walk")
       SRG2 AABB 2 A_Chase
       SRG2 C 0 A_PlaySound("blooddemon/walk")
       SRG2 CCDD 2 A_Chase
       goto See 
	Missile:
		TNT1 A 0 A_JumpIfCloser(300, "Melee")
		goto See
	Melee:
		SRG2 E 8 A_FaceTarget
		TNT1 A 0 ThrustThingZ(0,24,0,0)
		TNT1 A 0 A_Recoil(-20)
		TNT1 A 0 A_FaceTarget
		SRG2 E 0 A_PlaySound("blooddemon/melee", CHAN_AUTO)
		SRG2 F 4 A_CustomMeleeAttack(random(2, 15))
		
		TNT1 A 0 A_Recoil(-5)
		TNT1 A 0 A_FaceTarget
		SRG2 F 4 A_CustomMeleeAttack(random(2, 15))
		
		TNT1 A 0 A_Recoil(-5)
		TNT1 A 0 A_FaceTarget
		SRG2 G 4 A_CustomMeleeAttack(random(2, 15))
		
		TNT1 A 0 A_Recoil(-2)
		TNT1 A 0 A_FaceTarget
		SRG2 G 4 A_CustomMeleeAttack(random(2, 15))
		goto See
    Pain: 
       SRG2 H 2
       SRG2 H 2 A_Pain
       Goto See
	   
    MonDeath: 
       SRG2 I 8 
       SRG2 I 8 
       SRG2 I 0 A_FaceTarget
       SRG2 J 0 A_SpawnItemEx("BloodDemonArm", 10, 0, 32, 0, 8, 0, 0, 128)
       SRG2 J 8 A_Scream
       SRG2 K 4 
       SRG2 L 4 A_NoBlocking
       SRG2 M 4 
       SRG2 N 650
	goto Super::FadeOut
    MonRaise: 
       SRG2 NMLKJI 5 
       Goto See 
    } 
}

ACTOR BloodDemonArm
{
	Radius 8
	Height 8
	Speed 8
	+CLIENTSIDEONLY
	+DOOMBOUNCE
	+DROPOFF
	+Missile
      States
	{
	Spawn:
         SG2A ABCDEFGH 2
         goto Spawn
	Death:
	 SG2A I 2 A_FadeOut(0.1)
	 goto Death
	}
}