//======================================================================
//  Original credits
//======================================================================
//  DECORATE: 	KDiZD Team
//	Sounds:		Id Software
//  Sprites: 	Id Software (edits by Eriance)
//	GLDEFs: 	Sandypaper (Brightmaps)
//======================================================================

//slightly stronger Demon that has a ranged attack besides the normal melee attack
ACTOR Bloodfiend : Demon
{
	Tag "Blood fiend"
	Health 225
	PainChance 170
	+DONTHARMSPECIES
	MeleeThreshold 192 //don't fire projectile up close, use melee instead
	OBITUARY "%o died from the toxic blood of a blood fiend."
	HITOBITUARY "%o was eaten by a blood fiend."
	SEESOUND "monster/sg2sit"
	ATTACKSOUND "monster/sg2atk"
	PAINSOUND "demon/pain"
	DEATHSOUND "demon/death"
	ACTIVESOUND "demon/sg2act"
	states
	{
	Spawn:
		SAR2 AB 10 A_Look
		Loop
	See:
		SAR2 AABBCCDD 2 A_Chase
		Loop
	Melee:
		SAR2 EF 8 A_FaceTarget
		SAR2 G 8 A_SargAttack
		Goto See
	Missile:
		SAR2 GF 8 A_FaceTarget
		SAR2 E 0 A_PlaySound ("Weapons/bloodf")
		SAR2 E 0 A_SpawnProjectile("Bloodshot",22,0,-1,0,0)
		SAR2 E 8 A_SpawnProjectile("Bloodshot",22,0,1,0,0)
		Goto See
	Pain:
		SAR2 H 2
		SAR2 H 2 A_Pain
		Goto See
	Death:
		SAR2 I 8
		SAR2 J 8 A_Scream
		SAR2 K 4
		SAR2 L 4 A_NoBlocking
		SAR2 M 4
		SAR2 N -1
		Stop
	XDeath:
		SAR2 O 5
		SAR2 P 5 A_XScream
		SAR2 Q 5 A_NoBlocking
		SAR2 RSTUV 5
		SAR2 W -1
		Stop
	Raise:
		SAR2 NMLKJI 5
		Goto See
	}
}

ACTOR Bloodshot
{
	Radius 3
	Height 3
	Speed 20
	Damage 2
	PROJECTILE
	RENDERSTYLE TRANSLUCENT
	ALPHA 0.80
	+THRUGHOST
	DeathSound "weapons/bloodx"
	States
	{
	Spawn:
		FBLD A 2 Bright A_CStaffMissileSlither		
		TNT1 A 0 {
			If(GetCvar("dmr_fancydoom")) { 
				A_SpawnItemEx("DMR_BloodTrail",0,0);
			}
		}
		FBLD B 2 Bright A_CStaffMissileSlither		
		TNT1 A 0 {
			If(GetCvar("dmr_fancydoom")) { 
				A_SpawnItemEx("DMR_BloodTrail",0,0);
			}
		}
		loop
	Death:
		FBLD CDE 3 Bright
		stop
	}
}