//======================================================================
//  Original credits
//======================================================================
//  DECORATE: 	DavidRaven
//	Sounds:		DavidRaven, Id software
//  Sprites: 	d Software (Zombieman), the Skulltag Team (Illucia, Player II), DavidRaven, ItsNatureToDie (altdeath)
//	GLDEFs: 	DavidRaven
//======================================================================
//  Additional credits
//======================================================================
//	Sounds:		Westwood Studios	
//======================================================================

ACTOR VirusZombie //don't inherit so they can damage other zombies
{
	Tag "Virus"
	obituary "%o got infected by a Virus."
	Radius 20
	Height 56
	Health 110
	Speed 8
	painchance 180
	seesound "fem/sight"
	painsound "fem/pain"
	deathsound "fem/death"
	activesound "fem/active"
	Monster
	+FLOORCLIP
	+DONTHARMCLASS
	+MISSILEMORE
	DamageFactor "Poison", 0.0
	States
	{
	Spawn:
		ZOMW AB 10 A_Look
		loop
	See:
		ZOMW AABBCCDD 4 A_Chase
		loop
	Missile:
		ZOMW E 20 A_FaceTarget
		TNT1 A 0 A_PlaySound("Virus/FireDart")
		ZOMW F 4 BRIGHT A_CustomMissile ("VirusDart", 32, 0)
		ZOMW E 20
		goto See
	Pain:
		ZOMW G 3
		ZOMW G 3 A_Pain
		goto See
	Death:
		ZOMW H 5
		ZOMW I 5 A_Scream
		ZOMW J 5 A_NoBlocking
		ZOMW K 5
		ZOMW L 5
		ZOMW M 5
		ZOMW N -1
		stop
	XDeath:
		ZOMW O 5
		ZOMW P 5 A_XScream
		ZOMW Q 5 A_NoBlocking
		ZOMW RSTUV 5
		ZOMW W -1
		stop
	Raise:
		ZOMW MLKJIH 5
		goto See
	}
}

ACTOR VirusDart : FastProjectile
{
	Radius 6
	Height 4
	Speed 75
	Damage (random(25,35)) //don't use the default "random(1,8) x damage" formula
	DamageType "Poison"
	poisondamage 75
	Renderstyle "Add"
	Scale 0.2
	Decal "BulletChip"
	+MTHRUSPECIES
	Obituary "%o got infected by a Virus."
	States
	{
	Spawn:
		MISL A 1
		Loop
	Death:
		TNT1 A 0
		Stop
	}
}