Class Aracnorb : Actor
{
	Default
	{
		//$Title Aracnorb
		Health 170;
		Radius 24;
		Height 56;
		Mass 400;
		Speed 12;
		Scale 0.85;
		PainChance 150;
		SeeSound "aracnorb/sight";
		ActiveSound "baby/active";
		PainSound "baby/pain";
		DeathSound "aracnorb/death";
		MONSTER;
		+FLOAT
		+FLOATBOB
		+NOGRAVITY
		Obituary "%o suffered psychic trauma from an Aracnorb's brainwaves.";
		HitObituary "%o had %p skull chewed by an Aracnorb.";
	}

	States
	{
	Spawn:
		ACNB A 1 A_Look();
		Loop;
	See:
		ACNB A 2 A_Chase();
		Loop;
	Melee:
		ACNB AB 5;
		ACNB C 6 A_CustomMeleeAttack(6,"aracnorb/melee","","Melee",TRUE); //put all parameters so modders can custom it easily later - ozy81
		Goto See;
	Missile:
		ACNB B 12 A_FaceTarget();
		ACNB C 2 A_SpawnProjectile("AracnorbBall",36);
		ACNB B 2;
		ACNB D 0 A_Jump(32,"See");
		ACNB D 0 A_SpidRefire;
		Goto Missile+1;
	Pain:
		ACNF I 2;
		ACNF I 2 A_Pain();
		Goto See;
	Death:
		ACNB D 0 {bFLOATBOB = False;}
		ACNB D 0 A_Scream();
		ACNB D 6 A_Fall();
		ACNB D 1;
		Wait;
	Crash:
		ACNB EFG 6;
		ACNB H -1;
		Stop;
	Raise:
		ACNB HGFEDA 8;
		ACNB A 0 {bFLOATBOB = True;}
		Goto See;
	}
}

Class AracnorbBall : Actor
{
	Default
	{
		Radius 13;
		Height 8;
		Speed 8;
		Damage 3;
		RenderStyle "STYLE_Add";
		Alpha 0.75;
		SeeSound "baby/attack";
		DeathSound "baby/shotx";
		PROJECTILE;
		+BRIGHT
		+SEEKERMISSILE
		+STRIFEDAMAGE
		+RANDOMIZE
	}

	States
	{
	Spawn:
		ACNF AABB 1 A_Weave(2, 2, 2.0, 1.0);
		Loop;
	Death:
		ACNF CDEFG 5;
		Stop;
	}
}