//Sprites modified from original Doom sources by Obake.
ACTOR BaronTwoPointO : BaronOfHell 16088
{
Game Doom
//$Category NewMonsters
+NEVERRESPAWN
+MISSILEMORE 
 Radius 24
 Height 64
 MeleeRange 64
 MeleeThreshold 100
 AttackSound "DECAPIT"
 PainChance 15
 MissileType "BaronBall2"
 Speed 12
 States
{
  Spawn:
    HAIR AB 10 A_Look
    Loop
  See:
    HAIR AABBCCDD 3 A_Chase
    Loop
  Missile:
  	HAIR EF 8 A_FaceTarget
	HAIR G 8 A_CustomMissile("BaronBall2", 32, -3, (random(-15,15)), 0, 0)
    HAIR EF 8 A_FaceTarget
	HAIR G 8 A_CustomMissile("BaronBall3", 32, -3, 0, 0, 0) 
    Goto See
  Melee:
    HAIR EF 8 A_FaceTarget
	HAIR G 9 A_CustomMeleeAttack(random(10, 80),"DECAPIT","none") 
	Goto See
  Pain:
    HAIR H 2
    HAIR H 2 A_Pain
    Goto See
  Death:
    HAIR I 8
    HAIR J 8 A_Scream
    HAIR K 8
    HAIR L 8 A_NoBlocking
    HAIR MN 8
    HAIR O -1 A_BossDeath
    Stop
   Raise:
    stop
}
}

ACTOR BaronBall2 : BaronBall
{
  Speed 13
  FastSpeed 13
  Projectile
  +RANDOMIZE
  Obituary "$OB_MPROCKET" // "%o was splattered by a new Baron"
}

ACTOR BaronBall3 : BaronBall
{
  Speed 10
  FastSpeed 10
  Damage (random(8, 64))
  Projectile
  +RANDOMIZE
  Obituary "$OB_MPROCKET" // "%o was splattered by a new Baron"
}

ACTOR SupplyBox : CustomInventory 10492
{
  Inventory.PickupMessage "Picked up various ammo."
  Inventory.PickupSound "misc/ammo_pkup"
  +COUNTITEM
  Radius 20
  Height 16
  states
  {
  Spawn:
    SUPP A -1
    stop
  Pickup:
    SUPP A 0 A_GiveInventory ("Clip", 20)
    SUPP A 0 A_GiveInventory ("Shell", 8)
	SUPP A 0 A_GiveInventory ("RocketAmmo", 2)
	SUPP A 0 A_GiveInventory ("Cell", 40)
    stop
  }
}

ACTOR MaintenanceTurret 15050
{
  //$Category Turrets
  Game Doom
  Health 125
  Scale 0.8
  Radius 16
  Height 32
  Speed 0 
  Mass 90000
  MinMissileChance 85
  Obituary "%o was terminated by a turret." 
  +SOLID
  +NEVERFAST
  +ISMONSTER 
  +NOGRAVITY
  +SHOOTABLE
  +NOBLOOD
   ActiveSound "INDUST"
   SeeSound "INDUST"
   DeathSound "CANNONS"
   RenderStyle Normal
   States
 {
  Spawn:
    NEWT ABC 8  A_Look 
    Loop
	 See:
    NEWT ABC 4 A_Chase
    Loop
  Missile:
    NEWT DE 3 A_FaceTarget
    NEWT F 2 A_CustomMissile("MaintenanceShot", 15, 0, 0)  
   Goto See
	 Death: 
    NEWT GHIJ 3 A_Scream
    NEWT K -2 A_NoBlocking
	Stop	
}
}


ACTOR MaintenanceShot
{
  Radius 6
  Height 8
  Speed 14
  FastSpeed 16
  Damage (random(8, 24)+2)
  Projectile
  +RANDOMIZE
  RenderStyle Add
  Alpha 1
  SeeSound "imp/attack"
  DeathSound "imp/shotx"
  States
  {
  Spawn:
    BMA1 AB 4 Bright
    Loop
  Death:
    BMA1 CDEF 6 Bright
    Stop
  }
}

ACTOR SpreadShot
{
  Radius 6
  Height 8
  Speed 15
  Scale 0.7
  FastSpeed 19
  Damage (random(8, 16)+2)
  Projectile
  +RANDOMIZE
  RenderStyle Add
  Alpha 1
  Translation "0:175=%[0,0,0]:[1,0,0]"
  SeeSound "imp/attack"
  DeathSound "imp/shotx"
  States
  {
  Spawn:
    BMA1 AB 4 Bright
    Loop
  Death:
    BMA1 CDEF 6 Bright
    Stop
  }
}

ACTOR CannonShot
{
  Radius 6
  Height 8
  Speed 20
  Scale 0.7
  Damage 4
  Projectile
  Damagetype Ice
  +RANDOMIZE
  ProjectileKickBack 5
  Reactiontime 5
  RenderStyle Add
  Alpha 1
  Translation "0:175=%[0,0,0]:[1,0,0]"
  SeeSound "LAZERR"
  DeathSound "LASERZ"
  States
  {
  Spawn:
    BMA1 AB 4 Bright A_Countdown 
    Loop
  Death:
    BMA1 CDEF 6 Bright
    Stop
  }
}

ACTOR SpreadTurret 15051
{
  //$Category Turrets
  Game Doom
  Health 100
  Radius 16
  Height 32
  Speed 0 
  Mass 90000
  Translation "115:175=%[0,0,0]:[0,1,1]"
  MinMissileChance 100
  Obituary "%o has been flame grilled." 
  +SOLID
  +NEVERFAST
  +ISMONSTER 
  +NOGRAVITY
  +SHOOTABLE
  +NOBLOOD
   ActiveSound "INDUST"
   SeeSound "INDUST"
   DeathSound "CANNONS"
   RenderStyle Normal
   States
 {
  Spawn:
    NEWT ABC 8  A_Look 
    Loop
	 See:
    NEWT ABC 4 A_Chase
    Loop
  Missile:
    NEWT DE 3 A_FaceTarget
    NEWT F 0 A_CustomMissile("SpreadShot", 15, 0, -10, 0, 0)
	NEWT E 0 A_CustomMissile("SpreadShot", 15, 0, 0, 0, 0)
	NEWT F 0 A_CustomMissile("SpreadShot", 15, 0, 10, 0, 0)
   Goto See
	 Death: 
    NEWT GHIJ 3 A_Scream
    NEWT K -2 A_NoBlocking
	Stop	
}
}

ACTOR WarningSignal : ArachnotronPlasma 
{
  
  Game Doom
  Radius 3
  Height 2
  XScale 0.4
  YScale 0.4
  Speed 255
  ProjectileKickBack 1
  Damage 0
  Projectile
  +PIERCEARMOR
  +RANDOMIZE
  +NOGRAVITY
  +BLOODLESSIMPACT
  +RIPPER
  +SEEKERMISSILE
  Translation "145:43=%[0,0,0]:[1,1,0]"
  Renderstyle None
  DeathSound "FRYING_C"
  SeeSound "FRYING_C"
  States
  {
  Spawn:
   APLS AB 5 
   APLS AB 5 
    Loop
  Death:
  SKUL K 6 Bright A_PlaySound("UFO_TAKE", 0, 100, 0, 1)
    Stop
  }
}

ACTOR MiniPlasma : ArachnotronPlasma 
{
  
  Game Doom
  Radius 3
  Height 2
  Scale 0.2
  Speed 65
  ProjectileKickBack 1
  Damage(random(8, 10))
  Projectile
  +RANDOMIZE
  +NOGRAVITY
  +NOEXPLODEFLOOR
  +SEEKERMISSILE
  RenderStyle Stencil
  StencilColor "Purple"
  DeathSound "PAGETUR"
  SeeSound "SNIPER_R"
  States
  {
  Spawn:
   APLS AB 5 Bright
   APLS AB 5 Bright
    Loop
  Death:
    APBX ABCDE 5 Bright  
    Stop
  }
}



