/*
Under Construction Sign
*/

actor UnderConstruction 600
{
  Height 128
  Radius 50
  +SOLID
  States
  {
  Spawn:
    UNDC A -1
    Stop
  }
}


//BloodLustSphere start

//Notes, the bloodlust sphere give double damage, higher speed and drains enemy health
//it lasts for a total of 45 seconds, it also boosts health and armor by 50  -hnsolo77
actor PowerBloodLustDamage : PowerDamage
{
damagefactor "normal", 2
}
actor BloodlustSphere : CustomInventory 10077
{
inventory.pickupmessage "bloodlust sphere!"
inventory.maxamount 0
inventory.pickupsound "misc/p_pkup"
+INVENTORY.FANCYPICKUPSOUND
+INVENTORY.AUTOACTIVATE
+COUNTITEM
+INVENTORY.ALWAYSPICKUP
states
{
Spawn:
QLST ABCD 6 BRIGHT
loop
Pickup:
TNT1 A 0 A_GiveInventory("BloodlustDamageActivate",1)
TNT1 A 0 A_GiveInventory("BloodlustSphereHealth",1)
TNT1 A 0 A_GiveInventory("BloodlustSphereDrain",1)
TNT1 A 0 A_GiveInventory("BloodlustSphereSpeed",1)
TNT1 A 0 A_GiveInventory("BloodLustSphereArmor",1)
stop
}
}
actor BloodlustDamageActivate : PowerupGiver
{
inventory.pickupmessage ""
powerup.type "BloodLustDamage"
powerup.color red 0.3
inventory.maxamount 0
powerup.duration 1575
inventory.pickupsound ""
+INVENTORY.AUTOACTIVATE
+COUNTITEM
+INVENTORY.ALWAYSPICKUP
states
{
Spawn:
TNT1 A -1
stop
}
}
actor BloodlustSphereHealth : Health 
{
inventory.pickupmessage ""
inventory.amount 50
inventory.maxamount 200
+INVENTORY.AUTOACTIVATE
-COUNTITEM
+INVENTORY.ALWAYSPICKUP
states
{
Spawn:
TNT1 A -1
stop
}
}
actor BloodlustSphereDrain : PowerupGiver
{
inventory.pickupmessage ""
powerup.type "Drain"
powerup.duration 1575
inventory.maxamount 0
+INVENTORY.AUTOACTIVATE
-COUNTITEM
+INVENTORY.ALWAYSPICKUP
states
{
Spawn:
TNT1 A -1
stop
}
}
actor BloodlustSphereSpeed : PowerupGiver
{
inventory.pickupmessage ""
powerup.type "Speed"
powerup.duration 1575
inventory.maxamount 0
+INVENTORY.AUTOACTIVATE
-COUNTITEM
+INVENTORY.ALWAYSPICKUP
states
{
Spawn:
TNT1 A -1
stop
}
}
actor BloodLustSphereArmor : BlueArmor
{
inventory.pickupmessage ""
Armor.SavePercent 50
Armor.SaveAmount 50
}
//BloodlustSphere end


/*
Slime Imp
*/
ACTOR SlimeImp 602
{  
   Health 90
   Radius 20
   Height 56
   Speed 15
   PainChance 200
   MONSTER
   +FLOORCLIP
   SeeSound "imp/sight" 
   PainSound "imp/pain"
   DeathSound "imp/death"
   ActiveSound "imp/active"
   MeleeSound "imp/melee"
   Obituary "%o was defeated by a slime imp."
   HitObituary "%o was ripped apart by a slime imp."
   MissileType SlimeBall
   MeleeDamage 3
   States
   { 
   Spawn:
       WEAK AB 10 A_Look
       Loop
   See:
       WEAK AABBCCDD 4 A_Chase
       Loop
   Melee:
   Missile:
       WEAK EF 10 A_FaceTarget
       WEAK G 6 A_ComboAttack
       WEAK EF 10 A_FaceTarget
       WEAK G 6 A_ComboAttack
       WEAK EF 10 A_FaceTarget
       WEAK G 6 A_ComboAttack
       Goto See
   Pain:
       WEAK H 3
       WEAK H 3 A_Pain
       Goto See
   Death:
       WEAK I 5 A_Scream
       WEAK J 5 A_Fall
       WEAK K 5 
       WEAK L 5
       WEAK M -1
       Stop
   XDeath:
       WEAK N 5 
       WEAK O 5 A_XScream
       WEAK P 5 
       WEAK Q 5 A_Fall
       WEAK RST 5
       WEAK U -1
       Stop
   Raise:
       WEAK LKJI 5
       Goto See
   }
}

ACTOR SlimeBall
{
    Speed 15
    Radius 6
    Height 8
    Damage 3
    SeeSound "imp/attack"
    DeathSound "imp/shotx"
    PROJECTILE
    RENDERSTYLE ADD
    Decal DoomImpScorch
    States
    {
    Spawn: 
        POOP AB 4 Bright A_SpawnItemEx("SlimeBallTrail", 0, 0, 0, 0, 0, 0, 0, 128)
        Loop
    Death:
        POOP CDE 4 Bright
        Stop
    }
}

ACTOR SlimeBallTrail
{
        Speed 0
        Damage 0
        Height 8
        Radius 5
        SeeSound "NULL"
        DeathSound "NULL"
        RENDERSTYLE ADD
        PROJECTILE
        States
        {
        Spawn:
           SHIT ABCDE 4 BRIGHT
           Stop
        }
}
//End of Slime Imp

//Poison Soul
ACTOR PoisonSoul 603 
{ 
Health 150 
Radius 16 
Height 56 
Mass 50 
Speed 6 
Damage 4 
RENDERSTYLE SoulTrans 
PAINCHANCE 255 
MONSTER 
+NOGRAVITY 
+FLOAT 
+dontfall 
AttackSound "SHRK04" 
PainSound "SHRK02" 
DeathSound "SHRK01" 
ActiveSound "SHRK03B" 
Missiletype TorturedSoulPoison
States 
   { 
   Spawn: 
       SKLL A 10 A_Look 
       Loop 
   See: 
       SKLL AAAAA 4 A_Chase 
       SKLL A 0 A_PlaySound("torturedsoul/poison") 
       SKLL A 0 A_CustomMissile(PoisonSoulPoison, 0, 0, 180)
       Loop 
   Missile: 
       SKLL B 10 A_FaceTarget 
       SKLL B 0 A_PlaySound("torturedsoul/poison") 
       SKLL B 0 A_CustomMissile(PoisonSoulPoison, 0, 0, 180)
       SKLL B 4 A_SkullAttack 
       SKLL BB 4 
       Goto Missile+1 
   Pain: 
       SKLL C 3
       SKLL C 3 A_Pain 
       Goto See 
   Death: 
       SKLL D 6 
       SKLL E 6 A_Scream 
       SKLL F 6 
       SKLL F 0 A_PlaySound("torturedsoul/poison") 
       SKLL F 0 A_CustomMissile(PoisonSoulPoison, 0, 0, 0)
       SKLL G 6 A_Noblocking 
       SKLL H 6 
       Stop 
   } 
}

actor PoisonSoulPoison 
{ 
    Radius 24 
    Height 6 
    Speed 0 
    Damage 1 
    +STRIFEDAMAGE 
    +RIPPER
    +NOGRAVITY
    +MISSILE
    RENDERSTYLE Translucent 
    ALPHA 0.67 
    States 
    { 
    Spawn: 
        TRPS ABCDEFGDEFGDEFGDEFGDEFGDCBA 4 
        Stop 
    Death: 
        TRPS DCBA 4 
        Stop 
    } 
}
//End of Poison Soul
