Actor Vore 22063
{
Monster
Health 600
Speed 4
Radius 30
Height 56
Mass 1000
PainChance 28
RadiusDamageFactor 0.5
+FloorClip
+NoTarget //Intended so they don't infight with other Vores. If a DontInfightSpecies gets in, use that
Obituary "%o couldn't escape a Vore."
SeeSound "Vore/Sight"
ActiveSound "Vore/Active"
PainSound "Vore/Pain"
DeathSound "Vore/Death"
States
	{
	Spawn:
		VORE D 10 A_Look
		Loop
	See:
		VORE AA 3 A_Chase
		VORE B 7 A_Chase
		VORE CC 3 A_Chase
		VORE D 7 A_Chase
		VORE EE 3 A_Chase
		VORE F 7 A_Chase
		Loop
	Melee:
	Missile:
		VORE G 0 Bright A_PlaySoundEx("Vore/Attack", "Body")
		VORE GHHHH 4 Bright A_FaceTarget
		VORE II 4 Bright A_FaceTarget
		VORE J 8 Bright A_CustomMissile("VoreFirepod", 32, 0, 0)
		VORE JJ 4 Bright A_FaceTarget
		Goto See
	Pain:
		VORE K 4
		VORE K 4 A_Pain
		Goto See
	Death:
		VORE L 6
		VORE M 6 A_Scream
		VORE N 6
		VORE O 6 A_NoBlocking
		VORE P 8
		VORE Q -1
		Stop
	Raise:
		VORE QPONML 6
		Goto See
	}
}

Actor VoreFirepod
{
Projectile
Radius 6
Height 8
Speed 12
FastSpeed 18
Damage (Random(20,40))
+SeekerMissile
RenderStyle Add
Alpha 0.9
SeeSound "Vore/Throw"
DeathSound "Vore/Hit"
Decal RevenantScorch
States
	{
	Spawn:
		VOBA A 0 Bright A_SpawnItemEx("VoreFirepodTrail",random(5,-5),0,random(5,-1),0,0,0,180)
		VOBA A 1 Bright A_SpawnItemEx("VoreFirepodTrail",random(5,-5),0,random(5,-1),0,0,0,180)
		VOBA A 0 Bright A_SpawnItemEx("VoreFirepodTrail",random(5,-5),0,random(5,-1),0,0,0,180)
		VOBA A 1 Bright A_SpawnItemEx("VoreFirepodTrail",random(5,-5),0,random(5,-1),0,0,0,180)
		VOBA B 0 Bright A_SpawnItemEx("VoreFirepodTrail",random(5,-5),0,random(5,-1),0,0,0,180)
		VOBA B 1 Bright A_SpawnItemEx("VoreFirepodTrail",random(5,-5),0,random(5,-1),0,0,0,180)
		VOBA B 0 Bright A_SpawnItemEx("VoreFirepodTrail",random(5,-5),0,random(5,-1),0,0,0,180)
		VOBA B 1 Bright A_SpawnItemEx("VoreFirepodTrail",random(5,-5),0,random(5,-1),0,0,0,180)
		VOBA C 0 Bright A_SpawnItemEx("VoreFirepodTrail",random(5,-5),0,random(5,-1),0,0,0,180)
		VOBA C 1 Bright A_SpawnItemEx("VoreFirepodTrail",random(5,-5),0,random(5,-1),0,0,0,180)
		VOBA C 0 Bright A_SpawnItemEx("VoreFirepodTrail",random(5,-5),0,random(5,-1),0,0,0,180)
		VOBA C 1 Bright A_SpawnItemEx("VoreFirepodTrail",random(5,-5),0,random(5,-1),0,0,0,180)
		VOBA C 0 Bright A_JumpIfTargetInLOS(1,360,1)
		Loop
		VOBA A 0 Bright A_SpawnItemEx("VoreFirepodTrail",random(5,-5),0,random(5,-1),0,0,0,180)
		VOBA A 1 Bright A_SpawnItemEx("VoreFirepodTrail",random(5,-5),0,random(5,-1),0,0,0,180)
		VOBA A 0 Bright A_SpawnItemEx("VoreFirepodTrail",random(5,-5),0,random(5,-1),0,0,0,180)
		VOBA A 1 Bright A_SpawnItemEx("VoreFirepodTrail",random(5,-5),0,random(5,-1),0,0,0,180)
		VOBA C 0 Bright A_JumpIfTargetInLOS(1, 360, 1)
		Goto Spawn+4
		VOBA BBB 0 Bright A_SeekerMissile(90,90,2)
		Goto Spawn+4
	Death:
		VOBA D 0 Bright A_Explode(30,90)//Part of the original game was that Vores can be hurt by their own projectiles
		VOBA DEFGHI 4 Bright
		Stop
	}
}


Actor VoreFirepodTrail
{
Radius 1
Height 1
Speed 0
Projectile
RenderStyle Add
Alpha 0.9
+NoClip
States
	{
	Spawn:
	Death:
		TNT1 A 3
		VOBT ABCDE 3 Bright
		Stop
	}
}

