//------------------------------------------------------------
//Healing effect seeker missile
//------------------------------------------------------------
ACTOR HealingFXSeeker
{
	//Properties
	Radius 2
	Height 2
	Scale 0.75
	Projectile
	Speed 16
	Damage (0)
	Alpha 0.6
	
	//Flags
	+SEEKERMISSILE
	+NOBLOCKMAP
	+NOGRAVITY
	+NOINTERACTION
	+CLIENTSIDEONLY
	+NONETID
	+BRIGHT
	
	//Projectile lifespan
	args 0
	
	//States
	States
	{
	Spawn:
		TNT1 A 0 nodelay A_RearrangePointers(AAPTR_TARGET, AAPTR_DEFAULT, AAPTR_TARGET)
		Goto Spawn1
	Spawn1:
		HLFX A 1 A_SeekerMissile(3, 4, SMF_PRECISE, 0, 8)
		TNT1 A 0 A_SpawnItemEx("HealingFXSeekerTrail")
		TNT1 A 0 A_JumpIfCloser(48, "Death")
		TNT1 A 0 A_SetArg(0, args[0] + 1)
		TNT1 A 0 A_JumpIf(args[0] > 140, "Death")
		loop
	Death:
		HLFX A 1 A_FadeOut(0.1)
		loop
	}
}

//------------------------------------------------------------
//Healing effect
//------------------------------------------------------------
Actor HealingFX : LSParticleBase
{
	Vspeed 2
	States
	{
		Spawn:
		TNT1 A 0 A_SetScale(scalex * 0.9, scaley * 0.9)
		HLFX A 1 A_FadeOut(0.1)
		loop
	}
}

//------------------------------------------------------------
//Healing effect seeker missile trail
//------------------------------------------------------------
ACTOR HealingFXSeekerTrail : LSParticleBase
{
	Alpha 0.6
	Scale 0.25
	States
	{
	Spawn:
		HLFX A 5
		goto Death
	Death:
		HLFX A 1 A_FadeOut(0.1)
		loop
	}

}