ACTOR MedikitSpawnActor : CustomInventory 10059
{
	Tag "Medikit (Insanity)"
	//$Category Health and Armor
	//$Sprite MEDIA0
	+NOBLOCKMAP
	+NOGRAVITY
	States
	{
	Spawn:
	  TNT1 A 0
	  TNT1 A 1
	  TNT1 A 1 A_JumpIf(ACS_NamedExecuteWithResult("GunModifierSpawn") == 666,"Nothing")
	  TNT1 A 1 A_SpawnItemEx("MedikitSpawner")
	Nothing:
	  TNT1 A 1
	  TNT1 A -1
	  Stop
	}
}

ACTOR MedikitSpawner : RandomSpawner
{
	DropItem "IDMMedikitPickup"
}

ACTOR IDMMedikitPickup : CustomInventory
{
  Radius 20
  Height 16
  Inventory.PickupMessage "Medikit."
  Inventory.PickupSound "misc/health_pkup"
  Inventory.RespawnTics 1050
  Tag "Medikit"
  +BASEHEALTH
  +COUNTITEM
  States
  {
  Spawn:
    MEDI A -1
    Stop
  Pickup:
	TNT1 A 0 A_JumpIfInventory("PowerSoul",1,"Soulbonus")
	TNT1 A 0 A_GiveInventory("IDMMedikit")
	Stop
  Soulbonus:
	TNT1 A 0 A_GiveInventory("SoulMedikit",1)
	Stop
  }
}

ACTOR IDMMedikit : Health
{
  Inventory.Amount 50
  Inventory.PickupMessage "Medikit."
  Inventory.PickupSound "misc/health_pkup"
  Health.LowMessage 25, "Ooh, I needed that!"
  States
  {
  Spawn:
    MEDI A -1
    Stop
  }
}

ACTOR SoulMedikit : IDMMedikit
{
  Inventory.Amount 100
  Inventory.MaxAmount 300
}