// Assault Rifle

ACTOR AssaultRifle : IDMWeapon
{ 
	Weapon.Kickback 100
	Weapon.SelectionOrder 400
	Weapon.SisterWeapon "MachinegunCannon"
	Weapon.AmmoType "IDMClip"
	Weapon.AmmoGive 80
	Weapon.AmmoUse 3
	//Weapon.PreferredSkin "CarbineMarine"
	Inventory.PickupSound "misc/w_pkup"
	Inventory.PickupMessage "Assault Rifle! (Slot 4)"
	Obituary "%o was sprayed by %k's Assault Rifle."
	Tag "Assault Rifle"
	AttackSound "weapons/akfire"
	Decal BulletChip
	Damagetype "Bullet"
	+WEAPON.NOLMS
	States 
	{  
	Spawn:
	  AK4I A -1 Bright
	  Stop
	Ready:
	  AK47 A 1 A_WeaponReady
	  Loop
	Deselect:
	  TNT1 A 0 A_Lower
	  TNT1 A 0 A_Lower
	  AK47 A 1 A_Lower
	  Loop 
	Select: 
	  TNT1 A 0 A_PlaySound("weapons/wswitch",CHAN_WEAPON)
	Sloop:
	  TNT1 A 0 A_Raise
	  TNT1 A 0 A_Raise
	  AK47 A 1 A_Raise
	  Loop
	Fire: 
	  TNT1 A 0 A_GunFlash
	  TNT1 A 0 A_JumpIfInventory("PowerQuadDamage",1,"Quad")
	  AK4F A 2 Bright Offset(0,43) A_FireBullets(2.8,1.775,1,30,"IDMBulletPuff")
	  AK4F B 1 Bright Offset(0,41)
	  AK47 B 1 Offset(0,38)
	  AK47 A 1 Offset(0,36)
	  AK47 A 4 Offset(0,33) A_Refire
	  Goto Ready
	Quad:
	  TNT1 A 0 A_Playsound("misc/qdmg2",CHAN_5)
	  AK4F A 2 Bright Offset(0,43) A_FireBullets(2.8,1.775,1,30,"ExtremePuff")
	  Goto Fire+3
	Flash:
	  TNT1 A 2 A_Light2
	  TNT1 A 2 A_Light1
	  Goto LightDone
	}
}

ACTOR MachinegunCannon : AssaultRifle
{
	Weapon.SisterWeapon "AssaultRifle"
	Attacksound "weapons/hmg2fire"
	+POWERED_UP
	States
	{
	Ready:
	  HMG2 A 1 A_WeaponReady
	  Loop
	Deselect:
	  TNT1 A 0 A_Lower
	  TNT1 A 0 A_Lower
	  HMG2 A 1 A_Lower
	  Loop
	Select:
	  TNT1 A 0 A_PlaySound("weapons/wswitch",CHAN_WEAPON)
	Sloop:
	  TNT1 A 0 A_Raise
	  TNT1 A 0 A_Raise
	  HMG2 A 1 A_Raise
	  Loop
	Fire:
	  TNT1 A 0 A_GunFlash
	  TNT1 A 0 A_JumpIfInventory("PowerQuadDamage",1,"Quad")
	  HMG2 B 3 Bright A_FireBullets(5.6,3.55,3,30,"IDMBulletPuff")
	  HMG2 C 2 Bright
	  HMG2 A 5 A_Refire
	  Goto Ready
	Quad:
	  TNT1 A 0 A_Playsound("misc/qdmg2",CHAN_5)
	  HMG2 B 3 Bright A_FireBullets(5.6,3.55,3,30,"ExtremePuff")
	  Goto Fire+3
	}
}