actor ShotgunFascista : GenericHumanScum 
{

  //----------------------------COMPLEX DOOM COMPATIBILITY DROPS------------------------
 	   
	DropItem "HealthFlask" 40
	DropItem "ArmorCharge" 40
	DropItem "AmmoPack" 20
	DropItem "HandGrenadeAmmo" 50 1
	DropItem "MineAmmo" 25 1

  scale 1.0
  obituary "%o was gunned down by the shotgunner of the strong country with the strong leader"
  health 42
  radius 15
  height 54
  mass 100
  speed 10
    Species "Z"
  +DOHARMSPECIES
  painchance 150
  SeeSound "ShotgunFascist/see"
  PainSound "FrenchNaziPistol/pain"
  DeathSound "FNAZDE01"
  ActiveSound "ShotgunFascist/Active" 
  dropitem "Shotgun"
  Tag "FreakKorps Shotgun Fascist"
  MONSTER
  +FLOORCLIP
  states
  {
  Spawn:
    TNT1 A 0
	TNT1 A 0 A_JumpIf(ACS_NamedExecuteWithResult("STFUCheck") == 1, "STFU")
	TNT1 A 0 A_JumpIf(ACS_NamedExecuteWithResult ("VanJumpCheck") == 1, "VanJump")
	TNT1 A 0 A_SetScale (scaleX+frandom(-0.03, 0.03), scaleY+frandom(-0.08,0.08))
	TNT1 A 0 A_SpawnItemEx ("SiegWRITER", 0, 0, 0, 0, 0, 0, 0, SXF_NOCHECKPOSITION, 69)
	TNT1 A 0 A_SpawnItemEx ("HumanTrails", 0, 0, 0)
  Spawn2:
    ITNZ T 10 A_Look
    loop
  STFU:
     TNT1 A 0
	 TNT1 A 0 ACS_NamedExecute ("STFUShotgunFascista")
	 Goto Spawn+2
  VanJump:
	 TNT1 A 0
	 TNT1 A 0  NODELAY ACS_NamedExecuteAlways ("VanillaHeights")
	Goto Spawn+3	 
  See:
    "####" A random(1,5)
	 TNT1 A 0 A_Jump (70, "DodgeLeft", "DodgeRight", "DodgeLeftF", "DodgeLeftB", "DodgeRightF", "DodgeRightB")
	 TNT1 A 0 A_Jump (180, "MissileCheck")		
  SeeLoop:
    TNT1 A 0 A_CheckSight ("CheckReload")
    TNT1 A 0 A_JumpIfInventory ("ShotgunShotCounter", 8, "Reload")
	TNT1 A 0 A_Jump (199, "DodgeLeft", "DodgeRight", "DodgeLeftF", "DodgeLeftB", "DodgeRightF", "DodgeRightB")
    ITNZ AABBCCDD 3 A_Chase
    loop
  CheckReload:
    TNT1 A 0 A_Jump (150, "CheckReload2")
 	Goto SeeLoop+1
  CheckReload2:
    TNT1 A 0 A_JumpIfInventory ("ShotgunShotCounter", 8, "Reload")
	Goto SeeLoop+1
  DodgeLeft:
        TNT1 A 0 A_FaceTarget
	    ITNZ AABBCCDD 2 ThrustThing(angle*256/360+192, 1, 0, 0)
		TNT1 A 0 A_Jump (228, "MissileCheck")
		TNT1 A 0 A_Jump (50, "DodgeRight")
		Goto SeeLoop+1
	DodgeLeftF:
	    TNT1 A 0 A_FaceTarget
	    TNT1 A 0 ThrustThingZ (0, 15, 0, 0)
	    TNT1 A 0 A_Recoil (random (-8,-3))
	    ITNZ AABBCCDD 2 ThrustThing(angle*256/360+192, 1, 0, 0)
		TNT1 A 0 A_Jump (228, "MissileCheck")
		Goto SeeLoop+1
    DodgeLeftB:
	    TNT1 A 0 A_FaceTarget
	    TNT1 A 0 ThrustThingZ (0, 15, 0, 0)
	    TNT1 A 0 A_Recoil (random (3,8))
	    ITNZ AABBCCDD 2 ThrustThing(angle*256/360+192, 1, 0, 0)
		TNT1 A 0 A_Jump (228, "MissileCheck")
		Goto SeeLoop+1
	DodgeRight:
	    TNT1 A 0 A_FaceTarget
	    ITNZ AABBCCDD 2 ThrustThing(angle*256/360+64, 1, 0, 0)
		TNT1 A 0 A_Jump (228, "MissileCheck")
		Goto SeeLoop+1
	DodgeRightF:
	    TNT1 A 0 A_FaceTarget
	    TNT1 A 0 ThrustThingZ (0, 15, 0, 0)
	    TNT1 A 0 A_Recoil ( random (-8,-3)) 
	    ITNZ AABBCCDD 2 ThrustThing(angle*256/360+64, 1, 0, 0)
		TNT1 A 0 A_Jump (228, "MissileCheck")
		Goto SeeLoop+1
	DodgeRightB:
	    TNT1 A 0 A_FaceTarget
	    TNT1 A 0 ThrustThingZ (0, 15, 0, 0)
	    TNT1 A 0 A_Recoil ( random (3,8)) 
	    ITNZ AABBCCDD 2 ThrustThing(angle*256/360+64, 1, 0, 0)
		TNT1 A 0 A_Jump (228, "MissileCheck")
		Goto SeeLoop+1
  AlphaBravo:
    TNT1 A 0 A_JumpIfInventory ("ShotgunShotCounter", 8, "Reload")
    ITNZ E 4 A_FaceTarget
	TNT1 A 0 A_Chase ("", "MissileAmbush", CHF_DONTMOVE)
	ITNZ E 4 A_FaceTarget
	TNT1 A 0 A_Chase ("", "MissileAmbush", CHF_DONTMOVE)
	ITNZ E 4 A_FaceTarget
	TNT1 A 0 A_Chase ("", "MissileAmbush", CHF_DONTMOVE)
	TNT1 A 0 A_Jump (1, "SeeLoop")
   Loop
  MissileAmbush:
    ITNZ EE 4 A_FaceTarget
	TNT1 A 0 A_JumpIfTargetInLos ("Accuracy", 0, JLOSF_CLOSENOJUMP | JLOSF_DEADNOJUMP, 0, 1200)
	TNT1 A 0 A_JumpIfTargetInLos ("TripleShot", 0, JLOSF_DEADNOJUMP, 500)		
  MissileCheck:
    TNT1 A 0 A_JumpIfInventory ("GrenadeCoolDown", 1, 2)
	TNT1 A 0 A_Jump ( 175, "GranataCheck")
    TNT1 A 0 A_JumpIfTargetInLos ("Missile", 0, JLOSF_DEADNOJUMP)
	Goto SeeLoop		
  Missile:
    ITNZ E 12 A_FaceTarget
	TNT1 A 0 A_TakeInventory ("GrenadeCoolDown", 1)
	TNT1 A 0 A_JumpIfTargetInLos ("Accuracy", 0, JLOSF_CLOSENOJUMP | JLOSF_DEADNOJUMP, 0, 1200)
	TNT1 A 0 A_JumpIfTargetInLos ("TripleShot", 0, JLOSF_DEADNOJUMP, 500) 
	TNT1 A 0 A_PlaySound ("BSHFR")
	TNT1 A 0 A_PlaySound ("BSHFRF", 6, 0.5, 0)
	TNT1 AAAAAAAA 0 A_CustomMissile ("ShotgunTracer", 32, 9, random (-4,4))
	ITNZ F 5 BRIGHT A_FaceTarget 
	TNT1 A 0 A_GiveInventory ("ShotgunShotCounter", 1)
    ITNZ E 7 A_FaceTarget
    goto SeeLoop
  Accuracy:
    ITNZ E 18 A_FaceTarget
	TNT1 A 0 A_PlaySound ("BSHFR")
	TNT1 A 0 A_PlaySound ("BSHFRF", 6, 0.5, 0)
	TNT1 AAAAAAAA 0 A_CustomMissile ("ShotgunTracer", 32, 9, random (-2,2))
	TNT1 A 0 A_GiveInventory ("ShotgunShotCounter", 1)
    ITNZ F 5 Bright A_FaceTarget 
    ITNZ E 2 A_JumpIfInventory ("ShotgunShotCounter", 8, "Reload")
	TNT1 A 0 A_JumpIfInTargetLos ("SeeLoop", 1, JLOSF_CLOSENOJUMP | JLOSF_DEADNOJUMP, 0, 400)
	ITNZ E 3 A_MonsterRefire (2, "AlphaBravo")
   Loop
  TripleShot:
	ITNZ E 9 A_FaceTarget
	TNT1 A 0 A_PlaySound ("BSHFR")
	TNT1 A 0 A_PlaySound ("BSHFRF", 6, 0.5, 0)
	TNT1 AAAAAAAA 0 A_CustomMissile ("ShotgunTracer", 32, 9, random (-8,-2))
	TNT1 A 0 A_GiveInventory ("ShotgunShotCounter", 1)
	ITNZ F 6 BRIGHT A_FaceTarget
	ITNZ E 4 A_JumpIfInventory ("ShotgunShotCounter", 8, "Reload")
	ITNZ E 14 A_FaceTarget 
	TNT1 A 0 A_PlaySound ("BSHFR")
	TNT1 A 0 A_PlaySound ("BSHFRF", 6, 0.5, 0)
	TNT1 AAAAAAAA 0 A_CustomMissile ("ShotgunTracer", 32, 9, random (2,8))
	TNT1 A 0 A_GiveInventory ("ShotgunShotCounter", 1)
	ITNZ F 6 BRIGHT A_FaceTarget
	TNT1 A 0 A_JumpIfInventory ("ShotgunShotCounter", 8, "Reload")
	ITNZ E 14 A_FaceTarget 
	TNT1 A 0 A_PlaySound ("BSHFR")
	TNT1 A 0 A_PlaySound ("BSHFRF", 6, 0.5, 0)
	TNT1 AAAAAAAA 0 A_CustomMissile ("ShotgunTracer", 32, 9, random (-4,4))
	TNT1 A 0 A_GiveInventory ("ShotgunShotCounter", 1)
	ITNZ F 6 BRIGHT A_FaceTarget
	TNT1 A 0 A_JumpIfInventory ("ShotgunShotCounter", 8, "Reload")
	Goto SeeLoop
  GranataCheck:
	TNT1 A 0 
    TNT1 A 0 A_JumpIfTargetInLos ("Granata", 0, JLOSF_CLOSENOJUMP | JLOSF_DEADNOJUMP, 700, 300)
	Goto MissileCheck+2
  Granata:
    //TNT1 A 0 A_Print ("Granata")
	TNT1 A 0 A_PlaySound ("ShotgunFascist/Grenade", CHAN_VOICE)
    ITNZ D 12 A_FaceTarget
	TNT1 A 0 A_PlaySound ("GRNTOSS", CHAN_WEAPON)
	TNT1 A 0 A_CustomMissile ("Deutschnade", 42, 0, random (-8,8), CMF_OFFSETPITCH, random (12, 17)) 
	ITNZ DE 6 
	TNT1 A 0 A_GiveInventory ("GrenadeCoolDown", 5)
	Goto SeeLoop	
  Reload: 
    ITNZ DE 6 A_Playsound ("SHOTLOD")
	ITNZ DE 6 A_Playsound ("SHOTLOD")
	ITNZ DE 6 A_Playsound ("SHOTLOD")
	ITNZ DE 6 A_Playsound ("SHOTLOD")
	TNT1 A 0 A_TakeInventory ("ShotgunShotCounter", 8)
	ITNZ DE 6 A_Playsound ("SHOTLOD")
	ITNZ DE 6 A_Playsound ("SHOTLOD")
	ITNZ DE 5 A_Playsound ("SHOTLOD")
	ITNZ DE 5 A_Playsound ("SHOTLOD")
	ITNZ E 7 A_Playsound ("SHOTPUMP")
	TNT1 A 0 A_JumpIfInTargetLos ("MissileCheck", 1, JLOSF_DEADNOJUMP, 800, 0) 
	Goto SeeLoop	
  Pain:
    ITNZ G 3
    ITNZ G 3 A_Pain
    goto SeeLoop
  Death:
    ITNZ H 5  A_Scream
    ITNZ I 5 A_NoBlocking
    ITNZ J 5 
    ITNZ K 5 A_Playsound ("FallingBodyGear", CHAN_BODY)
    ITNZ L -1
    stop
  XDeath:
    TNT1 A 0
    TNT1 A 0 A_SpawnItemEx ("VgavnonahCore", 0, 0, 0, 0, 0, 0, 0, SXF_NOCHECKPOSITION)
    PGIB A 5
    PGIB B 5 A_XScream
    PGIB C 5 A_NoBlocking
    PGIB D 5
    PGIB E -1
    Stop
  Raise:
    TNT1 A 0 
	TNT1 A 0 A_SpawnItemEx ("NanoResEffect", 0, 0, 15, 0, 0, 0, 0, SXF_NOCHECKPOSITION)
	ITNZ LKJIH 5
   Goto See	
  Idle:
    ITNZ AA 4 A_Wander
    ITNZ A 0 A_Look
    ITNZ BB 4 A_Wander
    ITNZ A 0 A_Look
    ITNZ CC 4 A_Wander
    ITNZ A 0 A_Look
    ITNZ DD 4 A_Wander
    ITNZ A 0 A_Look
    loop
  }
}



	
	