ACTOR GrandShotgunner : GenericHumanScum 
{

  //----------------------------COMPLEX DOOM COMPATIBILITY DROPS------------------------
 	   
	DropItem "HealthFlask" 40
	DropItem "ArmorCharge" 40
	DropItem "AmmoPack" 20
	DropItem "HandGrenadeAmmo" 50 1
	DropItem "MineAmmo" 25 1

  Health 37
  Radius 20
  Height 56
  Mass 100
  Speed 10
  PainChance 170
    Species "Z"
  +DOHARMSPECIES
  Monster
  +FLOORCLIP
  Species "Shotgunner"
  SeeSound "Skin1/See"
  Tag "Grand Shotgunner"
  PainSound "Skin1/pain"
  DeathSound "SKN1DE01"
  ActiveSound "Skin1/active"
  Obituary "%o was executed by the Grand Shotgunner"
  Translation "84:84=111:111", "96:96=109:109", "82:82=108:108", "87:87=108:108", "93:93=107:107"
  //+DROPOFF
  +JUMPDOWN
  DropItem "Shotgun"
  States
  {
  Spawn:
    TNT1 A 0
	TNT1 A 0 A_JumpIf(ACS_NamedExecuteWithResult("STFUCheck") == 1, "STFU")
	TNT1 A 0 A_JumpIf(ACS_NamedExecuteWithResult ("VanJumpCheck") == 1, "VanJump")
	TNT1 A 0 A_SetScale (scaleX+frandom(-0.03, 0.03), scaleY+frandom(-0.08,0.08))
	TNT1 A 0 A_SpawnItemEx ("HumanTrails", 0, 0, 0)
	TNT1 A 0 A_SpawnItemEx ("SiegWRITER", 0, 0, 0, 0, 0, 0, 0, SXF_NOCHECKPOSITION, 69)
  Spawn2:
    X2CO A 10 A_Look
    Loop
  STFU:
     TNT1 A 0
	 TNT1 A 0 ACS_NamedExecute ("STFUSkin1")
	 Goto Spawn+2
   VanJump:
	 TNT1 A 0
	 TNT1 A 0  NODELAY ACS_NamedExecuteAlways ("VanillaHeights")
	Goto Spawn+3	 
  See:
    "####" A random(1,5)
	 TNT1 A 0 A_Jump (70, "DodgeLeft", "DodgeRight", "DodgeLeftF", "DodgeLeftB", "DodgeRightF", "DodgeRightB")
	 TNT1 A 0 A_Jump (180, "MissileCheck")	
  SeeLoop:
    TNT1 A 0 A_CheckSight ("CheckReload")
    TNT1 A 0 A_JumpIfInventory ("ShotgunShotCounter", 6, "Reload")
	TNT1 A 0 A_Jump (199, "DodgeLeft", "DodgeRight", "DodgeLeftF", "DodgeLeftB", "DodgeRightF", "DodgeRightB")
    X2CO AABBCCDD 3 A_Chase
    Loop
  CheckReload:
    TNT1 A 0 A_Jump (150, "CheckReload2")
 	Goto SeeLoop+1
  CheckReload2:
    TNT1 A 0 A_JumpIfInventory ("ShotgunShotCounter", 6, "Reload")
	Goto SeeLoop+1
  DodgeLeft:
        TNT1 A 0 A_FaceTarget
	    X2CO AABBCCDD 2 ThrustThing(angle*256/360+192, 1, 0, 0)
		TNT1 A 0 A_Jump (228, "MissileCheck")
		TNT1 A 0 A_Jump (50, "DodgeRight")
		Goto SeeLoop+1
	DodgeLeftF:
	    TNT1 A 0 A_FaceTarget
	    TNT1 A 0 ThrustThingZ (0, 15, 0, 0)
	    TNT1 A 0 A_Recoil (random (-8,-3))
	    X2CO AABBCCDD 2 ThrustThing(angle*256/360+192, 1, 0, 0)
		TNT1 A 0 A_Jump (228, "MissileCheck")
		Goto SeeLoop+1
    DodgeLeftB:
	    TNT1 A 0 A_FaceTarget
	    TNT1 A 0 ThrustThingZ (0, 15, 0, 0)
	    TNT1 A 0 A_Recoil (random (3,8))
	    X2CO AABBCCDD 2 ThrustThing(angle*256/360+192, 1, 0, 0)
		TNT1 A 0 A_Jump (228, "MissileCheck")
		Goto SeeLoop+1
	DodgeRight:
	    TNT1 A 0 A_FaceTarget
	    X2CO AABBCCDD 2 ThrustThing(angle*256/360+64, 1, 0, 0)
		TNT1 A 0 A_Jump (228, "MissileCheck")
		Goto SeeLoop+1
	DodgeRightF:
	    TNT1 A 0 A_FaceTarget
	    TNT1 A 0 ThrustThingZ (0, 15, 0, 0)
	    TNT1 A 0 A_Recoil ( random (-8,-3)) 
	    X2CO AABBCCDD 2 ThrustThing(angle*256/360+64, 1, 0, 0)
		TNT1 A 0 A_Jump (228, "MissileCheck")
		Goto SeeLoop+1
	DodgeRightB:
	    TNT1 A 0 A_FaceTarget
	    TNT1 A 0 ThrustThingZ (0, 15, 0, 0)
	    TNT1 A 0 A_Recoil ( random (3,8)) 
	    X2CO AABBCCDD 2 ThrustThing(angle*256/360+64, 1, 0, 0)
		TNT1 A 0 A_Jump (228, "MissileCheck")
		Goto SeeLoop+1
  MissileCheck:
	TNT1 A 0 A_JumpIfInventory ("GrenadeCoolDown", 1, 2)
	TNT1 A 0 A_Jump (100, "MollyCheck")
    TNT1 A 0 A_JumpIfTargetInLos ("Missile", 0, JLOSF_DEADNOJUMP )
	Goto SeeLoop	
  Missile:
    TNT1 A 0 A_JumpIfInventory ("ShotgunShotCounter", 6, "Reload") 
    X2CO E 18 A_FaceTarget
	TNT1 A 0 A_JumpIfTargetInLos ("Accuracy", 0, JLOSF_CLOSENOJUMP | JLOSF_DEADNOJUMP, 0, 1200)
	TNT1 A 0 A_JumpIfTargetInLos ("Trishot", 0, JLOSF_CLOSENOJUMP | JLOSF_DEADNOJUMP, 1199, 600)
	TNT1 A 0 A_PlaySound ("BSHFR")
	TNT1 A 0 A_PlaySound ("BSHFRF", 6, 0.5, 0)
	TNT1 AAAAAAAA 0 A_CustomMissile ("ShotgunTracer", 32, 9, random (-5,5))
	TNT1 A 0 A_GiveInventory ("ShotgunShotCounter", 1)
    X2CO F 6 Bright
    X2CO E 5 A_FaceTarget 
    Goto SeeLoop
  Accuracy:
    X2CO E 12 A_FaceTarget
	TNT1 A 0 A_PlaySound ("BSHFR")
	TNT1 A 0 A_PlaySound ("BSHFRF", 6, 0.5, 0)
	TNT1 AAAAAAAA 0 A_CustomMissile ("ShotgunTracer", 32, 9, random (-3,3))
	TNT1 A 0 A_GiveInventory ("ShotgunShotCounter", 1)
    X2CO F 6 Bright 
    X2CO E 5
    Goto SeeLoop
  Trishot:
	TNT1 A 0 A_PlaySound ("BSHFR")
	TNT1 A 0 A_PlaySound ("BSHFRF", 6, 0.5, 0)
	TNT1 AAAAAAAA 0 A_CustomMissile ("ShotgunTracer", 32, 9, random (-5,5))
	TNT1 A 0 A_GiveInventory ("ShotgunShotCounter", 1)
	X2CO F 6 Bright
	TNT1 A 0 A_JumpIfInventory ("ShotgunShotCounter", 6, "Reload")
	X2CO E 18 A_FaceTarget
	TNT1 A 0 A_PlaySound ("BSHFR")
	TNT1 A 0 A_PlaySound ("BSHFRF", 6, 0.5, 0)
	TNT1 AAAAAAAA 0 A_CustomMissile ("ShotgunTracer", 32, 9, random (-8,3))
	TNT1 A 0 A_GiveInventory ("ShotgunShotCounter", 1)
	X2CO F 6 Bright
	TNT1 A 0 A_JumpIfInventory ("ShotgunShotCounter", 6, "Reload")
	X2CO E 18 A_FaceTarget
	TNT1 A 0 A_PlaySound ("BSHFR")
	TNT1 A 0 A_PlaySound ("BSHFRF", 6, 0.5, 0)
	TNT1 AAAAAAAA 0 A_CustomMissile ("ShotgunTracer", 32, 9, random (3,8))
	TNT1 A 0 A_GiveInventory ("ShotgunShotCounter", 1)
	X2CO F 6 Bright 
	X2CO E 5 A_Jump (50, "MollyCheck")
	Goto SeeLoop
   MollyCheck:
	TNT1 A 0 A_JumpIfTargetInLos ("Molly", 0, JLOSF_DEADNOJUMP | JLOSF_CLOSENOJUMP, 700, 325)
 Goto SeeLoop
 Molly:
	TNT1 A 0
	X2CO D 8 Bright A_FaceTarget
	X2CO E 4 Bright A_CustomMissile ("Molotow1", 42, 0, random (-4,4), CMF_OFFSETPITCH, random (10, 15))
	TNT1 A 0 A_GiveInventory ("GrenadeCoolDown", 6)	
 Goto SeeLoop		
  Reload:
    X2CO DE 8 A_Playsound ("SHOTLOD")
	X2CO DE 8 A_Playsound ("SHOTLOD")
	X2CO DE 8 A_Playsound ("SHOTLOD")
	TNT1 A 0 A_TakeInventory ("ShotgunShotCounter", 6)
	X2CO DE 8 A_Playsound ("SHOTLOD")
	X2CO DE 8 A_Playsound ("SHOTLOD")
	X2CO DE 8 A_Playsound ("SHOTLOD")
	TNT1 A 0 A_PlaySound ("SHOTPUMP")
	Goto SeeLoop
  Pain:
    X2CO G 3
    X2CO G 3 A_Pain
    Goto SeeLoop
  Death:
    X2CO H 5
    X2CO I 5 A_Scream
    X2CO J 5 A_NoBlocking
    X2CO K 5 A_Playsound ("FallingBodyLight", CHAN_BODY)
    X2CO L -1
    Stop
  XDeath:
    TNT1 A 0
    TNT1 A 0 A_SpawnItemEx ("VgavnonahCore", 0, 0, 0, 0, 0, 0, 0, SXF_NOCHECKPOSITION)
    SPOS M 5 A_XScream
	SPOS N 5 A_NoBlocking
	SPOS OQ 2 
	SPOS RST 5
	SPOS U -1
	Stop
  Raise:
    TNT1 A 0 
	TNT1 A 0 A_SpawnItemEx ("NanoResEffect", 0, 0, 15, 0, 0, 0, 0, SXF_NOCHECKPOSITION)
    X2CO L 5
    X2CO KJIH 5
    Goto See
  }
}


