 Actor USNPMCSniper : GenericHumanScum 
     {
	  scale 1.0
  obituary "%o was lethally amazed by the outstanding abilities of USN PMC sniper"
  health 175
  radius 15
  height 54
  mass 100
  Species "Reva"
+DONTHARMSPECIES
  speed 12
  painchance 135
  SeeSound "USNMilitarist5/See"
  PainSound "USM5PA01"
  DeathSound "Manhunt/Death"
  ActiveSound "USNMilitarist5/Active"
  dropitem "ClipBox", 5
  Tag "USN PMC Sniper"
  MONSTER
  +FLOORCLIP
  States
       {
  Spawn:
    TNT1 A 0
	TNT1 A 0 A_JumpIf(ACS_NamedExecuteWithResult("STFUCheck") == 1, "STFU")
	TNT1 A 0 A_JumpIf(ACS_NamedExecuteWithResult ("VanJumpCheck") == 1, "VanJump")
	TNT1 A 0 A_SetScale (scaleX+frandom(-0.02, 0.02), scaleY+frandom(-0.08,0.08))
	TNT1 A 0 A_SpawnItemEx ("HumanTrails", 0, 0, 0)
  Spawn2:
    CNFS A 10 A_Look
    loop
  STFU:
     TNT1 A 0
	 TNT1 A 0 ACS_NamedExecute ("STFUUSNMilitarist5")
	 Goto Spawn+2
  VanJump:
	 TNT1 A 0
	 TNT1 A 0  NODELAY ACS_NamedExecuteAlways ("VanillaHeights")
	Goto Spawn+3	 
  See:
   "####" A random(1,5)
    TNT1 A 0 A_Jump (170, "DodgeLeft", "DodgeRight", "DodgeLeftF", "DodgeLeftB", "DodgeRightF", "DodgeRightB")
	TNT1 A 0 A_Jump (180, "MissileCheck")
  SeeLoop:
    TNT1 A 0 A_CheckSight ("CheckReload")
	TNT1 A 0 A_JumpIfCloser (600, "Retreat")
    TNT1 A 0 A_JumpIfInventory ("CSniperShotCounter", 10, "Reload")
	TNT1 A 0 A_Jump (199, "DodgeLeft", "DodgeRight", "DodgeLeftF", "DodgeLeftB", "DodgeRightF", "DodgeRightB")
    CNFS AABBCCDD 2 A_Chase
    loop
  Retreat:
    TNT1 A 0 A_ChangeFlag ("Frightened", true)
    CNFS AABBCCDDAABBCCDDAABBCCDDAABBCCDD 2 A_Chase ("","")
	TNT1 A 0 A_ChangeFlag ("Frightened", false)
	Goto MissileCheck
  CheckReload:
    TNT1 A 0 A_Jump (150, "CheckReload2")
 	Goto SeeLoop+1
  CheckReload2:
    TNT1 A 0 A_JumpIfInventory ("CSniperShotCounter", 10, "Reload")
	Goto SeeLoop+1
  DodgeCheck:
    TNT1 A 0 A_Jump (255, "DodgeLeft", "DodgeRight", "DodgeLeftF", "DodgeLeftB", "DodgeRightF", "DodgeRightB")
	Goto MissileCheck	
  DodgeLeft:
        TNT1 A 0 A_FaceTarget
	    CNFS AABBCCDD 2 ThrustThing(angle*256/360+192, 2, 0, 0)
		TNT1 A 0 A_Jump (228, "MissileCheck")
		TNT1 A 0 A_Jump (50, "DodgeRight")
		Goto SeeLoop+1
	DodgeLeftF:
	    TNT1 A 0 A_FaceTarget
	    TNT1 A 0 ThrustThingZ (0, 15, 0, 0)
	    TNT1 A 0 A_Recoil (random (-8,-3))
	    CNFS AABBCCDD 2 ThrustThing(angle*256/360+192, 2, 0, 0)
		TNT1 A 0 A_Jump (228, "MissileCheck")
		Goto SeeLoop+1
    DodgeLeftB:
	    TNT1 A 0 A_FaceTarget
	    TNT1 A 0 ThrustThingZ (0, 15, 0, 0)
	    TNT1 A 0 A_Recoil (random (3,8))
	    CNFS AABBCCDD 2 ThrustThing(angle*256/360+192, 2, 0, 0)
		TNT1 A 0 A_Jump (228, "MissileCheck")
		Goto SeeLoop+1
	DodgeRight:
	    TNT1 A 0 A_FaceTarget
	    CNFS AABBCCDD 2 ThrustThing(angle*256/360+64, 2, 0, 0)
		TNT1 A 0 A_Jump (228, "MissileCheck")
		Goto SeeLoop+1
	DodgeRightF:
	    TNT1 A 0 A_FaceTarget
	    TNT1 A 0 ThrustThingZ (0, 15, 0, 0)
	    TNT1 A 0 A_Recoil ( random (-8,-3)) 
	    CNFS AABBCCDD 2 ThrustThing(angle*256/360+64, 2, 0, 0)
		TNT1 A 0 A_Jump (228, "MissileCheck")
		Goto SeeLoop+1
	DodgeRightB:
	    TNT1 A 0 A_FaceTarget
	    TNT1 A 0 ThrustThingZ (0, 15, 0, 0)
	    TNT1 A 0 A_Recoil ( random (3,8)) 
	    CNFS AABBCCDD 2 ThrustThing(angle*256/360+64, 2, 0, 0)
		TNT1 A 0 A_Jump (228, "MissileCheck")
		Goto SeeLoop+1
	RetreatStop:
	    TNT1 A 0
		TNT1 A 0 A_Changeflag ("FRIGHTENED", false)
	   Goto SeeLoop+1
	 ShortRetreat:
	    TNT1 A 0 A_ChangeFlag ("FRIGHTENED", true)
	    CNFS AABBCCDDAABBCCDDAABBCCDD 2 A_Chase ("", "")
	   Goto RetreatStop
  AlphaBravo:
    TNT1 A 0 A_JumpIfInventory ("CSniperShotCounter", 10, "ReloadAlphaBravo")
    CNFS E 2 A_FaceTarget
	TNT1 A 0 A_Chase ("", "MissileAmbush", CHF_DONTMOVE)
	CNFS E 2 A_FaceTarget
	TNT1 A 0 A_Chase ("", "MissileAmbush", CHF_DONTMOVE)
	CNFS E 2 A_FaceTarget
	TNT1 A 0 A_Chase ("", "MissileAmbush", CHF_DONTMOVE)
	TNT1 A 0 A_TakeInventory ("GrenadeCoolDown", 1)
	TNT1 A 0 A_Jump (1, "SeeLoop")
   Loop
  MissileAmbush:
    CNFS EE 4 A_FaceTarget	   
  MissileCheck:
    TNT1 A 0 A_JumpIfTargetInLos ("Missile", 0, JLOSF_DEADNOJUMP)
	Goto SeeLoop
  Missile:
    TNT1 A 0 A_JumpIfCloser (400, "PanicNade")
	TNT1 A 0 A_JumpIfTargetInLos ("LongRange", 0, JLOSF_DEADNOJUMP | JLOSF_CLOSENOJUMP, 0, 1000)
    CNFS E 35 A_FaceTarget
	TNT1 A 0 A_JumpIfInventory ("CSniperShotCounter", 10, "Reload")
	TNT1 A 0 A_Playsound ("PA2SSGF3")
	TNT1 A 0 A_PlaySound ("PA2SSGFF", 6, 0.5, 0)
	TNT1 A 0 A_FaceTarget
	CNFS F 3 Bright A_CustomMissile ("CSniperTracer", 46, 2)
	TNT1 A 0 A_FaceTarget
	TNT1 A 0 A_GiveInventory ("CSniperShotCounter", 1)
	TNT1 A 0 A_JumpIfTargetInLos ("RetreatNade", 0, JLOSF_DEADNOJUMP | JLOSF_CLOSENOJUMP, 700, 400)
	Goto ShortRetreat
  LongRange:
    CNFS E 15 A_FaceTarget
	TNT1 A 0 A_JumpIfCloser (1000, "ShortRetreat")
	CNFS E 20 A_FaceTarget
	TNT1 A 0 A_JumpIfInventory ("CSniperShotCounter", 10, "Reload")
	TNT1 A 0 A_Playsound ("PA2SSGF3")
	TNT1 A 0 A_PlaySound ("PA2SSGFF", 6, 0.5, 0)
	TNT1 A 0 A_FaceTarget
	CNFS F 3 Bright A_CustomMissile ("CSniperTracer", 46, 2)
	TNT1 A 0 A_FaceTarget
	TNT1 A 0 A_GiveInventory ("CSniperShotCounter", 1)
	TNT1 A 0 A_MonsterRefire (2, "AlphaBravo")
   Loop
  RetreatNade:
    CNFS DE 12 A_FaceTarget
	TNT1 A 0 A_PlaySound ("GRNTOSS", CHAN_WEAPON)
	CNFS E 4 A_CustomMissile ("M67Grenade", 42, 0, random (-4,4), CMF_OFFSETPITCH, random (10, 12))
	Goto Retreat
  PanicNade:
    //TNT1 A 0 A_Print ("Granata")
    CNFS D 6 A_FaceTarget
	TNT1 A 0 A_PlaySound ("GRNTOSS", CHAN_WEAPON)
	CNFS E 4 A_CustomMissile ("M67Grenade", 42, 0, random (-9,9), CMF_OFFSETPITCH, random (10, 12))
	Goto Retreat
  Reload:
    CNFS D 12 A_Playsound ("SNMAGOUT")
	TNT1 A 0 A_TakeInventory ("CSniperShotCounter", 10)
	CNFS E 34 A_Playsound ("SNMAGIN")
	CNFS D 9
	Goto SeeLoop
  ReloadAlphaBravo:
    CNFS D 12 A_Playsound ("SNMAGOUT")
	TNT1 A 0 A_TakeInventory ("CSniperShotCounter", 10)
	CNFS E 34 A_Playsound ("SNMAGIN")
	CNFS D 9
	Goto AlphaBravo+1	
  Pain:
    CNFS H 3
	TNT1 A 0 A_ChangeFlag ("FRIGHTENED", false) 
    CNFS H 3 A_Pain
    goto SeeLoop
  Death:
  	//TNT1 A 0 A_Jump(20, "Suren")
    CNFS I 5 A_Scream
    CNFS J 5
    CNFS K 5 A_NoBlocking
    CNFS L 5 A_Playsound ("FallingBodyGear", CHAN_BODY) 
	CNFS M -1
    stop
  XDeath:
    TNT1 A 0
    TNT1 A 0 A_SpawnItemEx ("VgavnonahCore", 0, 0, 0, 0, 0, 0, 0, SXF_NOCHECKPOSITION)
    PGIB A 5 A_NoBlocking
    PGIB BCD 5
    PGIB E -1
    Stop
  Raise:
    TNT1 A 0 
    TNT1 A 0 A_SpawnItemEx ("NanoResEffect", 0, 0, 15, 0, 0, 0, 0, SXF_NOCHECKPOSITION)
	CNFS MLKJIH 5
   Goto See	
  Idle:
    CNFS AA 4 A_Wander
    CNFS A 0 A_Look
    CNFS BB 4 A_Wander
    CNFS A 0 A_Look
    CNFS CC 4 A_Wander
    CNFS A 0 A_Look
    CNFS DD 4 A_Wander
    CNFS A 0 A_Look
    loop
  } 
	 
 }
 
 
 
 
 
 
 
	Actor USNRPGDropDrone
{
Health 20
Monster
Radius 16
Height 56
Mass 50
Scale 0.65
Speed 10
BloodType "MetalSurface"
PainChance 0
Damage (3)
Monster
+FLOAT
+NOGRAVITY
+NOBLOODDECALS
+MISSILEMORE
-DONTFALL
+NOICEDEATH
PainSound ""
Seesound "MINDRSE"
DeathSound "misc/boom"
ActiveSound ""
Obituary "%o got bullseyed penetrated by the RPG Drop Drone" 
States
     {
	  Spawn:
	      TNT1 A 0 A_JumpIfInventory ("ArtCoolDown", 1, "SpawnNoBomb")
	      TNT1 A 0 A_SentinelBob
	      CSDB A 4 A_Look
		  Loop
	  SpawnNoBomb:
	      TNT1 A 0 A_SentinelBob
	      CSDB BBBB 1 A_Look
		 Loop 
	  See:
		  TNT1 A 0
		  TNT1 A 0 A_PlaySound ("DRONLOOP", 6, 1.0, true)
		  TNT1 A 0 ThrustThingZ (0,random (6,9),0,0)
		  TNT1 A 0 A_JumpIfInventory ("ArtCoolDown", 1, "SeeNoBomb")
		  CSDB A random (4,7) 
	  SeeLoop:
	      TNT1 A 0 A_JumpIfInventory ("ArtCoolDown", 1, "SeeNoBomb")
	      TNT1 A 0 A_SentinelBob
	      CSDB AAAA 1 A_Chase
		  Loop
	  SeeNoBomb:
	      TNT1 A 0 A_SentinelBob
	      CSDB BBBB 1 A_Chase ("","Ram")
		 Loop   
	  Missile: 	 
	     TNT1 A 0
		 TNT1 A 0 A_JumpIfTargetInLos ("Bombing", 0, JLOSF_DEADNOJUMP, 200)
		Goto SeeLoop  
	  Bombing:	 
		 TNT1 A 0 A_Stop
		 TNT1 A 0 ThrustThingZ (0, random (12,20), 0, 0)
		 CSDB A 14 A_FaceTarget
		 CSDB AAAA 1 A_Recoil (random (-3,-2))
		 TNT1 A 0 A_FaceTarget
		 //CSDB A 5
		 TNT1 A 0 A_FaceTarget
		 CSDB AAAAA 1 A_Recoil (random (-3,-2))
		 CSDB A 5 A_CustomMissile ("QuadroRPGShell", 0, 0)
		 TNT1 A 0 A_GiveInventory ("ArtCoolDown", 2)
		Goto SeeNoBomb
	   Ram:
	     CSDB BBBB 2 A_FaceTarget
         CSDB BBBB 1  A_SkullAttack 
         CSDB BBBB 1
       goto Ram+2
	  Death:
	      TNT1 A 0 A_StopSound (6)
		  TNT1 A 0 A_JumpIfInventory ("ArtCoolDown", 2, "D2")
	      TNT1 A 0 A_SpawnItemEx ("TacticoolJetPackerExplosion", random (-1,20), random (10,20), random (10,20), 0, 0, 0)
		  TNT1 AAAAAA 0 A_CustomMissile ("CrapMetal", random (-4,4), random (-4,4), random (-360,360), CMF_OffSetPitch | CMF_AIMDIRECTION, random (30,90))
          TNT1 A 0 A_SpawnItemEx ("LittleTinCanExplosion", random (-1,2), random (-1,2), random (-1,20), 0, 0, 0)   
	      CSDB A 2 A_Scream
		  TNT1 A 0 A_SpawnItemEx ("TinCanExplosion", random (-1,2), random (-1,2), random (-1,20), 0, 0, 0)
		  CSDB A 2 A_NoBlocking
		  TNT1 A 0 A_SpawnItemEx ("TacticoolJetPackerExplosion", random (-1,2), random (-1,2), random (-1,20), 0, 0, 0)	
		  CSDB A 5
		  TNT1 A 0 A_SpawnItemEx ("LittleTinCanExplosion", random (-1,2), random (-1,2), random (-1,20), 0, 0, 0)
		  TNt1 A 1
		  Stop
	    D2:
	      TNT1 A 0 A_StopSound (6)
	      TNT1 A 0 A_SpawnItemEx ("TacticoolJetPackerExplosion", random (-1,20), random (10,20), random (10,20), 0, 0, 0)
		  TNT1 AAAAAA 0 A_CustomMissile ("CrapMetal", random (-4,4), random (-4,4), random (-360,360), CMF_OffSetPitch | CMF_AIMDIRECTION, random (30,90))
          TNT1 A 0 A_SpawnItemEx ("LittleTinCanExplosion", random (-1,2), random (-1,2), random (-1,20), 0, 0, 0)   
	      CSDB B 2 A_Scream
		  TNT1 A 0 A_SpawnItemEx ("TinCanExplosion", random (-1,2), random (-1,2), random (-1,20), 0, 0, 0)
		  CSDB B 2 A_NoBlocking
		  TNT1 A 0 A_SpawnItemEx ("TacticoolJetPackerExplosion", random (-1,2), random (-1,2), random (-1,20), 0, 0, 0)	
		  CSDB B 5
		  TNT1 A 0 A_SpawnItemEx ("LittleTinCanExplosion", random (-1,2), random (-1,2), random (-1,20), 0, 0, 0)
		  TNt1 A 1
		  Stop
		  }
		  
} 
 
 
 
 
 
 
 
		Actor QuadroRPGShell
		   {
		 projectile
		+MISSILE
		-NOGRAVITY
		+BLOODSPLATTER
		gravity 0.5
		radius 5
		height 5
		//SeeSound "DROPBOMB"
		speed 4
		scale 1.0
		damage (8)
		Obituary "%o was blown up back into the stone age"
		states
			{
			 Spawn:
				 ABMB A 3 
				Loop
			 Death:
				 TNT1 A 0
				 TNT1 A 0 A_StopSound (CHAN_VOICE)
				 TNT1 A 0 A_PlaySound("misc/boom",5)
				 TNT1 A 0 A_PlaySound("misc/distanceboom",6,1.0,0,0)
				 TNT1 A 0 A_Explode((20),40, 0 ,0,60)
				 TNT1 A 0 A_SpawnItemEx("CSMiniMIssileExplosionflame",0,0,0,0,0,0,0,SXF_NOCHECKPOSITION) 
				 TNT1 AAA 0 A_CustomMissile ("CSMiniMissileBoomSmoke", 0, 0, random (0, 360), 2, random (0, 360))
				 TNT1 A 0 A_SpawnItemEx("CSMiniMissileShockwave",0,0,0,0,0,0,0,SXF_NOCHECKPOSITION)
				 TNT1 A 1 Radius_Quake (2,4,0,7,0)
				 TNT1 A 20
		stop
				}		
		}
	