Actor MotherShipDrone
  {
   Health 450
  Radius 31
  Height 56
  Mass 400
  Speed 14
  PainChance 15
  DamageFactor "KaBeemDrone", 0
  BloodType "MetalSurface"
  Monster
  Translation "64:79=80:111", "128:151=80:111", "232:239=80:111", "0:2=5:8", "13:15=80:111"
  Obituary "%o was outnumbered by the MotherShip Jet Drone" 
  Seesound "MotherShipDrone/See"
  PainSound "HDRPAIN"
  ActiveSound "MotherShipDrone/Active"
  DeathSound "BIGBOOM"
  Tag "Mothership Jet Drone"
  +NOICEDEATH
  +FLOAT
  +NOBLOODDECALS
  +NOGRAVITY
       States
	        {
			Spawn:       
			   NZMS A 3 A_Look
			  Loop
			 See:
			   TNT1 A 0
			   TNT1 A 0 A_Jump (125, "VerticalManeuvr", "SlightFallBack")
			   TNT1 A 0 A_PlaySound ("BOLJET", 6, 1.0, true) 
			   NZMS BCDE 2 BRIGHT A_Chase
			  Loop
			 VerticalManeuvr:
			   TNT1 A 0
			   TNT1 A 0 A_SentinelBob
			   NZMS BCDE 2 BRIGHT A_Chase
			   Goto See+3
			 SlightFallBack:
			   NZMS BCDE 2 BRIGHT A_Chase
			   TNT1 A 0 A_Recoil (random (9, 14))
			   Goto See+3
			 UpMove:
			    TNT1 A 0
				TNT1 A 0 ThrustThingZ (0,random (10,18),0,0)
				NZMS BCDE 2 BRIGHT A_Chase
				TNT1 A 0 ThrustThingZ (0,random (10,18),0,0)
				NZMS BCDE 2 BRIGHT A_Chase
				Goto See
			 Missile:
			   TNT1 A 0
			   TNT1 A 0 A_TakeInventory ("GrenadecoolDown", 1)
			   TNT1 A 0 A_JumpIfInventory ("GrenadeCoolDown", 1, "See")
			   TNT1 A 0 A_JumpIfCloser (300, "MissileRetreat")
			   NZMS FGHIJKLM 1 BRIGHT A_FaceTarget
			   TNT1 A 0 A_PainAttack ("ShockerStealthDrone")
			   NZMS MLKJIHGF 1 BRIGHT A_GiveInventory ("GrenadecoolDown", 6) 
			   Goto See
			  MissileRetreat:
			   TNT1 A 0
			   TNT1 A 0 A_TakeInventory ("GrenadecoolDown", 1)
			   TNT1 A 0 A_JumpIfInventory ("GrenadeCoolDown", 1, "See")
			   NZMS BCDE 3 BRIGHT A_Recoil (random (9, 15))
			   NZMS FGHIJKLM 1 BRIGHT A_FaceTarget
			   TNT1 A 0 A_PainAttack ("ShockerStealthDrone")
			   NZMS MLKJIHGF 1 BRIGHT
			   Goto See
			 Pain:
			   TNT1 A 0 A_PlaySound ("BOLJET", 6, 1.0, true) 
			   NZMS B 3 BRIGHT
			   NZMS C 3 BRIGHT A_Pain
			   TNT1 A 0 A_Jump (105, "UpMove") 
			  Goto See
			 Death:
			   TNT1 A 0 A_StopSound (6)
			   TNT1 A 0 A_NoBlocking
			   TNT1 A 0 A_SpawnItemEx ("TinCanExplosion", 0, 0, 0, 0, 0, 0)
			   TNT1 A 0 A_SpawnItemEx ("TinCanExplosion", random (2,4), random (2,4), random (2,4), 0, 0, 0)
			   TNT1 A 0 A_SpawnItemEx ("TinCanExplosion", random (-4,-2), random (-4,-2), random (-4,-2), 0, 0, 0)
		       TNT1 AAAAAAA 0 A_CustomMissile ("CrapMetal", random (-4,4), random (-4,4), random (-360,360), CMF_OffSetPitch | CMF_AIMDIRECTION, random (30,90)) 
			   NZMS N 5 A_SpawnItemEx ("TinCanExplosion", 0, 0, 0, 0, 0, 0)
			   TNT1 A 0 A_SpawnItemEx ("LittleTinCanExplosion", random (-4,-2), random (-4,-2), random (-4,-2), 0, 0, 0)
			   NZMS O 5 A_Scream
			   NZMS P 4 A_SpawnItemEx ("TinCanExplosion", 0, 0, 0, 0, 0, 0)
			   NZMS Q 4 A_SpawnItemEx ("BigTinCanExplosion", 0, 0, 0, 0, 0, 0)
			  Stop 
			}

  }