Actor KnifeGI : GenericHumanScum 
{
  scale 1.02
  hitobituary "%o was opened up like a pack of MRE, by the CommieSlayer"
  health 140
  radius 16
  height 56
  mass 100
  speed 12
  BloodType "DASBLUT"
  painchance 100
  SeeSound "USNMilitarist4/see"
  PainSound "USNMilitarist4/pain"
  DeathSound "Manhunt/Death"
  ActiveSound "USNMilitarist4/Active"
  Tag "CommieSlayer"
  MONSTER
  +FASTMELEE
  +JUMPDOWN
  states
  {
  Spawn:
    TNT1 A 0
	TNT1 A 0 A_JumpIf(ACS_NamedExecuteWithResult("STFUCheck") == 1, "STFU")
	TNT1 A 0 A_JumpIf(ACS_NamedExecuteWithResult ("VanJumpCheck") == 1, "VanJump")
    TNT1 A 0 A_SetScale (scaleX+frandom(-0.08, 0.08), scaleY+frandom(-0.08,0.08)) 
	TNT1 A 0 A_SpawnItemEx ("HumanTrails", 0, 0, 0)
  Spawn2:
     UKNI A 10 A_Look
    loop
  STFU:
     TNT1 A 0
	 TNT1 A 0 ACS_NamedExecute ("STFUUSNMilitarist4")
	 Goto Spawn+2
  VanJump:
	 TNT1 A 0
	 TNT1 A 0  NODELAY ACS_NamedExecuteAlways ("VanillaHeights")
	Goto Spawn+3	 
  See:
    TNT1 A 0 A_Jump (170, "DodgeLeft", "DodgeRight", "DodgeLeftF", "DodgeRightF")
    UKNI AABBCCDD 2 A_Chase
	TNT1 A 0 A_JumpIfTargetInLos ("Smackdown", 0, JLOSF_CLOSENOJUMP | JLOSF_DEADNOJUMP, 240, 110)
    loop
 DodgeAttackCheck:
	TNT1 A 0
	TNT1 A 0 A_Jump (256, "DodgeAttackLeft", "DodgeAttackRight") 	
  DodgeLeft:
        TNT1 A 0 A_FaceTarget
	    UKNI AABBCCDD 2 ThrustThing(angle*256/360+192, 1, 0, 0)
		TNT1 A 0 A_Jump (50, "DodgeRight")
		Goto See+1
	DodgeLeftF:
	    TNT1 A 0 A_FaceTarget
	    TNT1 A 0 ThrustThingZ (0, 15, 0, 0)
	    TNT1 A 0 A_Recoil (random (-8,-3))
	    UKNI AABBCCDD 2 ThrustThing(angle*256/360+192, 1, 0, 0)
		Goto See+1
	DodgeRight:
	    TNT1 A 0 A_FaceTarget
	    UKNI AABBCCDD 2 ThrustThing(angle*256/360+64, 1, 0, 0)
		Goto See+1
	DodgeRightF:
	    TNT1 A 0 A_FaceTarget
	    TNT1 A 0 ThrustThingZ (0, 15, 0, 0)
	    TNT1 A 0 A_Recoil ( random (-8,-3)) 
	    UKNI AABBCCDD 2 ThrustThing(angle*256/360+64, 1, 0, 0)
		Goto See+1
    DodgeAttackLeft:
	    TNT1 A 0 A_FaceTarget
	    UKNI AABBCCDD 2 ThrustThing(angle*256/360+192, 2, 0, 0)
		UKNI E 2 A_Stop
		UKNI E 2 A_FaceTarget
		TNT1 A 0 A_Recoil (random (-8,-5))
		TNT1 A 0 ThrustThingZ (0, 15, 0, 0)
		UKNI F 2 A_FaceTarget
		UKNI F 4 A_CustomMeleeAttack ((9), "KNFHIT", "KNFSW")
	    Goto See
	DodgeAttackRight:
	    TNT1 A 0 A_FaceTarget
	    UKNI AABBCCDD 2 ThrustThing(angle*256/360+64, 2, 0, 0)
		UKNI E 2 A_Stop
		UKNI E 2 A_FaceTarget
		TNT1 A 0 A_Recoil (random (-8,-5))
		TNT1 A 0 ThrustThingZ (0, 15, 0, 0)
		UKNI F 2 A_FaceTarget
		UKNI F 4 A_CustomMeleeAttack ((9), "KNFHIT", "KNFSW")
	    Goto See		
	Retreat:
	    TNT1 A 0 A_ChangeFlag ("FRIGHTENED", true)
	  RetreatLoop:
	    UKNI ABCDABCDABCDABCD 2 A_Chase ("Melee", "")
		TNT1 A 0 A_CheckSight ("AlphaBravo")
		UKNI ABCDABCDABCDABCD 2 A_Chase ("Melee", "")
		TNT1 A 0 A_JumpIfTargetInLos ("RetreatStop", 0, JLOSF_DEADNOJUMP, 400) 
		TNT1 A 0 A_GiveInventory ("MovingCounter", 1) 
		UKNI ABCDABCDABCDABCD 2 A_Chase ("Melee", "")
		TNT1 A 0 A_CheckSight ("AlphaBravo")
		TNT1 A 0 A_JumpIfInventory ("MovingCounter", 15, "RetreatStop")
	   Loop	
	   RetreatStop:
	    TNT1 A 0
		TNT1 A 0 A_TakeInventory ("MovingCounter", 15)
		TNT1 A 0 A_Changeflag ("FRIGHTENED", false)
	   Goto See+1
	 AlphaBravo:
	   TNT1 A 0
	   TNT1 A 0 A_TakeInventory ("MovingCounter", 15)
	   TNT1 A 0 A_Changeflag ("FRIGHTENED", false)
	 AlphaBravoLoop:
		UKNI E 2 A_FaceTarget
		TNT1 A 0 A_Chase ("", "MissileAmbush", CHF_DONTMOVE)
		UKNI E 2 A_FaceTarget
		TNT1 A 0 A_Chase ("", "MissileAmbush", CHF_DONTMOVE)
		UKNI E 2 A_FaceTarget
		TNT1 A 0 A_Chase ("", "MissileAmbush", CHF_DONTMOVE)
		TNT1 A 0 A_Jump (1, "See")
	   Loop
	  MissileAmbush:
		UKNI EE 4 A_FaceTarget
	  Screamer:
	    TNT1 A 0 A_PlaySound ("USNMilitarist4/Attack", CHAN_VOICE)
	    UKNI E 10 A_FaceTarget
		TNT1 A 0 ThrustThingZ (0, 22, 0, 0)
		TNT1 A 0 A_Recoil (random (-18, -14))
		UKNI F 6
		TNT1 A 0 A_PlayWeaponSound ("KNFSW")
		UKNI F 4 A_CustomMeleeAttack ((12), "KNFHIT", "KNFSW")  
	  Goto Melee
  SmackDown:
    UKNI E 6 A_FaceTarget
	TNT1 A 0 ThrustThingZ (0, 22, 0, 0)
	TNT1 A 0 A_Recoil (random (-18, -14))
	UKNI F 6
	TNT1 A 0 A_PlayWeaponSound ("KNFSW")
	UKNI F 4 A_CustomMeleeAttack ((12), "KNFHIT", "KNFSW")  
  Melee:
    UKNI EF 7 A_FaceTarget
	TNT1 A 0 A_PlayWeaponSound ("KNFSW") 
    UKNI F 3 A_CustomMeleeAttack ((9), "KNFHIT", "KNFSW")
	UKNI FE 4 A_JumpIfInTargetLos ("DodgeAttackCheck", 3, JLOSF_DEADNOJUMP)
    goto See
   Pain: 
    UKNI H 3
    UKNI H 3 A_Pain
	TNT1 A 0 A_JumpIfInTargetLos ("Retreat", 5, JLOSF_CLOSENOJUMP | JLOSF_DEADNOJUMP, 0, 700)
    goto See
  Death:
  	UKNI H 5 A_Scream
    UKNI I 5 A_NoBlocking
    UKNI J 5  
    UKNI K 5 
    UKNI L 3 A_Playsound ("FallingBodyLight", CHAN_BODY)
    UKNI L -1
    stop
 Raise:
    TNT1 A 0 
    TNT1 A 0 A_SpawnItemEx ("NanoResEffect", 0, 0, 15, 0, 0, 0, 0, SXF_NOCHECKPOSITION)
	UKNI LKJIH 5
   Goto See 		
 XDeath:
    TNT1 A 0 
    TNT1 A 0 A_SpawnItemEx ("VgavnonahCore", 0, 0, 0, 0, 0, 0, 0, SXF_NOCHECKPOSITION)
    PGIB A 5 A_XScream
    PGIB B 5 A_NoBlocking
    PGIB CD 5
    PGIB E -1
    Stop
	}
}


