Actor FistOfLiberty : GenericHumanScum
{
  scale 1.08
  hitobituary "%o felt the fist of liberty incoming"
  health 85
  radius 16
  height 56
  mass 100
  speed 14
  BloodType "DASBLUT"
  painchance 115
  Translation "112:127=121:127"
  SeeSound "USNFister/see"
  PainSound "GTS/pain"
  DeathSound "GTS/Death"
  ActiveSound "USNFister/Active"
  Tag "Fist Of Liberty"
  MONSTER
  +FASTMELEE
  +JUMPDOWN
  states
  {
  Spawn:
    TNT1 A 0
	TNT1 A 0 A_JumpIf(ACS_NamedExecuteWithResult("STFUCheck") == 1, "STFU")
	TNT1 A 0 A_JumpIf(ACS_NamedExecuteWithResult ("VanJumpCheck") == 1, "VanJump")
    TNT1 A 0 A_SetScale (scaleX+frandom(-0.08, 0.08), scaleY+frandom(-0.08,0.08)) 
	TNT1 A 0 A_SpawnItemEx ("HumanTrails", 0, 0, 0)
  Spawn2:
     USFI A 10 A_Look
    loop
  STFU:
     TNT1 A 0
	 TNT1 A 0 ACS_NamedExecute ("STFUUSNFister")
	 Goto Spawn+2
  VanJump:
	 TNT1 A 0
	 TNT1 A 0  NODELAY ACS_NamedExecuteAlways ("VanillaHeights")
	Goto Spawn+3	 
  See:
    TNT1 A 0 A_Jump (170, "DodgeLeft", "DodgeRight", "DodgeLeftF", "DodgeRightF")
    USFI AABBCCDD 2 A_Chase
	TNT1 A 0 A_JumpIfTargetInLos ("Smackdown", 0, JLOSF_CLOSENOJUMP | JLOSF_DEADNOJUMP, 240, 110)
    loop
  DodgeLeft:
        TNT1 A 0 A_FaceTarget
	    USFI AABBCCDD 2 ThrustThing(angle*256/360+192, 1, 0, 0)
		TNT1 A 0 A_Jump (50, "DodgeRight")
		Goto See+1
	DodgeLeftF:
	    TNT1 A 0 A_FaceTarget
	    TNT1 A 0 ThrustThingZ (0, 15, 0, 0)
	    TNT1 A 0 A_Recoil (random (-8,-3))
	    USFI AABBCCDD 2 ThrustThing(angle*256/360+192, 1, 0, 0)
		Goto See+1
	DodgeRight:
	    TNT1 A 0 A_FaceTarget
	    USFI AABBCCDD 2 ThrustThing(angle*256/360+64, 1, 0, 0)
		Goto See+1
	DodgeRightF:
	    TNT1 A 0 A_FaceTarget
	    TNT1 A 0 ThrustThingZ (0, 15, 0, 0)
	    TNT1 A 0 A_Recoil ( random (-8,-3)) 
	    USFI AABBCCDD 2 ThrustThing(angle*256/360+64, 1, 0, 0)
		Goto See+1
  SmackDown:
    USFI F 7 A_FaceTarget
	TNT1 A 0 ThrustThingZ (0, 22, 0, 0)
	TNT1 A 0 A_Recoil (random (-18, -14))
	USFI F 6
	TNT1 A 0 A_PlayWeaponSound ("Fist/swing")
	USFI E 4 A_CustomMeleeAttack ((9), "Fist/Hit", "Fist/Swing")  
  Melee:
    USFI FE 2 A_FaceTarget
	TNT1 A 0 A_PlayWeaponSound ("Fist/swing") 
    USFI E 3 A_CustomMeleeAttack ((6), "Fist/Hit", "Fist/Swing")
	USFI EF 3
    goto See
   Pain: 
    USFI G 3
    USFI G 3 A_Pain
	TNT1 A 0 A_Jump (70, "DodgeLeftF", "DodgeRightF")
    goto See
  Death:
  	USFI H 5 A_Scream
    USFI I 5 A_NoBlocking
    USFI J 5  
    USFI K 5 
    USFI L 5 A_Playsound ("FallingBodyLight", CHAN_BODY)
    USFI M -1
    stop
 Raise:
    TNT1 A 0 
    TNT1 A 0 A_SpawnItemEx ("NanoResEffect", 0, 0, 15, 0, 0, 0, 0, SXF_NOCHECKPOSITION)
	USFI MLKJI 5
   Goto See 		
 XDeath:
    TNT1 A 0 
    TNT1 A 0 A_SpawnItemEx ("VgavnonahCore", 0, 0, 0, 0, 0, 0, 0, SXF_NOCHECKPOSITION)
    PGIB A 5 A_XScream
    PGIB B 5 A_NoBlocking
    PGIB CD 5
    PGIB E -1
    Stop
	}
}


Actor FistOfLibertySpawner : RandomSpawner
	{
	 DropItem "FistOfLiberty"
	 DropItem "FistOfLibertyHaki"
	 DropItem "FistOfLibertyGrey"
	}
	
	


Actor FistOfLibertyHaki: FistOfLiberty
{
Translation "112:127=8:13"
}

Actor FistOfLibertyGrey: FistOfLiberty
{
Translation "112:127=96:111"
}


 
