     Actor CrowbarFreak : GenericHumanScum 
{
  scale 1.0
  hitobituary "%o got beaten up by some freak with a crowbar. And a fancy suit."
  health 110
  radius 16
  height 56
  mass 100
  MaxTargetRange 130
  speed 14
  Translation "8:31=0:7"
  painchance 100
  SeeSound "CrowbarFreak/see"
  PainSound "GTS/pain"
  DeathSound "GTS/Death"
  ActiveSound "Crowbar/Active"
  attacksound "melee/hit"
  Tag "Crowbar freak"
  MONSTER
  +FLOORCLIP
  +FASTMELEE
  +JUMPDOWN
  states
  {
  Spawn:
    TNT1 A 0
	TNT1 A 0 A_JumpIf(ACS_NamedExecuteWithResult("STFUCheck") == 1, "STFU")
	TNT1 A 0 A_JumpIf(ACS_NamedExecuteWithResult ("VanJumpCheck") == 1, "VanJump")
	TNT1 A 0 A_SetScale (scaleX+frandom(-0.02, 0.02), scaleY+frandom(-0.08,0.08))	
	TNT1 A 0 A_SpawnItemEx ("HumanTrails", 0, 0, 0)
	TNT1 A 0 A_SpawnItemEx ("BydloWRITER", 0, 0, 0, 0, 0, 0, 0, SXF_NOCHECKPOSITION, 70)
  Spawn2:	 
    SCZC A 10 A_Look
    loop
  STFU:
     TNT1 A 0
	 TNT1 A 0 ACS_NamedExecute ("STFUCrowbarFreak")
	 Goto Spawn+2
   VanJump:
	 TNT1 A 0
	 TNT1 A 0  NODELAY ACS_NamedExecuteAlways ("VanillaHeights")
	Goto Spawn+3	  
  See:
    TNT1 A 0 A_Jump (170, "DodgeLeftF", "DodgeRightF")
    SCZC AABBCCDD 2 A_Chase
    loop
	DodgeLeftF:
	    TNT1 A 0 A_FaceTarget
	    TNT1 A 0 ThrustThingZ (0, 15, 0, 0)
	    TNT1 A 0 A_Recoil (random (-8,-3))
	    SCZC AABBCCDD 2 ThrustThing(angle*256/360+192, 1, 0, 0)
		Goto See+1
	DodgeRightF:
	    TNT1 A 0 A_FaceTarget
	    TNT1 A 0 ThrustThingZ (0, 15, 0, 0)
	    TNT1 A 0 A_Recoil ( random (-8,-3)) 
	    SCZC AABBCCDD 2 ThrustThing(angle*256/360+64, 1, 0, 0)
		Goto See+1	
  Melee:
    SCZC E 6 A_FaceTarget
	TNT1 A 0 A_JumpIfTargetInLos ("DashMelee", 0, JLOSF_DEADNOJUMP | JLOSF_CLOSENOJUMP, 130, 20)
	SCZC F 3 A_PlayWeaponSound("BALDAXSW")
    SCZC F 2 A_CustomMeleeAttack ((10), "BALDAXHT", "BALDAXSW")
	SCZC FE 3
    goto See
  DashMelee:
	TNT1 A 0
	TNT1 A 0 ThrustThingZ (0, 15, 0, 0)	
	TNT1 A 0 A_Recoil (random (-6,-4))
	SCZC E 4 A_FaceTarget
	SCZC F 3 A_PlayWeaponSound("BALDAXSW")
    SCZC F 2 A_CustomMeleeAttack ((10), "BALDAXHT", "BALDAXSW")
	SCZC FE 3
    goto See
   Pain: 
    SCZC G 3
    SCZC G 3 A_Pain
	TNT1 A 0 A_Jump (70, "DodgeLeftF", "DodgeRightF")
    goto See
  Death:
    SCZC G 5
    SCZC H 5 A_Scream
    SCZC I 5 A_NoBlocking
    SCZC JKL 3
	SCZC M 3 A_Playsound ("FallingBodyLight", CHAN_BODY)
    SCZC N -1
    stop	
 XDeath:
    TNT1 A 0
    TNT1 A 0 A_SpawnItemEx ("VgavnonahCore", 0, 0, 0, 0, 0, 0, 0, SXF_NOCHECKPOSITION)
    SCZC OPQ 3 A_NoBlocking
    SCZC RST 3 A_XScream
    SCZC U 3 
    SCZC V 3
    SCZC W -1
    Stop
  Raise:
    TNT1 A 0 
	TNT1 A 0 A_SpawnItemEx ("NanoResEffect", 0, 0, 15, 0, 0, 0, 0, SXF_NOCHECKPOSITION)
	SCZC NMLKJIHG 4
   Goto See	
	}
}


	
	Actor CrowBarFreakSpawner : RandomSpawner
		{
		 DropItem CrowBarFreak
		 DropItem CrowBarFreakBrown
		 DropItem CrowBarFreakChoco
		 DropItem CrowBarFreakHaki
		}
	
	

   Actor CrowBarFreakBrown : CrowBarFreak
       {
	    Translation "8:31=160:175"
	   }
	   
   Actor CrowBarFreakChoco : CrowBarFreak
        {
		 Translation "8:31=32:47"
		}
		
   Actor CrowBarFreakHaki : CrowBarFreak
         {
		   Translation "8:31=96:111"
		 }
		 
//-----Duke Transaltion isn't working if you didn't transalte sprites themselves, bloody hell		 