Actor LightMachineGunDude : GenericHumanScum  
    {
  scale 1.0
  obituary "%o became victim of corrupted PMC soldier"
  health 270
  radius 15
  height 54
  mass 100
  speed 10
  Species "Mancucu"
+DONTHARMSPECIES
  painchance 170
  Translation "112:127=64:79"
  SeeSound "StMerc/See"
  PainSound "StMerc/pain"
  DeathSound "StMerc/Death"
  ActiveSound "StMerc/Active"
  Tag "Light MachineGun Dude"
  +BOSSDEATH
  MONSTER
  +FLOORCLIP
  states
  {
  Spawn:
    TNT1 A 0
	TNT1 A 0 A_JumpIf(ACS_NamedExecuteWithResult("STFUCheck") == 1, "STFU")
	TNT1 A 0 A_JumpIf(ACS_NamedExecuteWithResult ("VanJumpCheck") == 1, "VanJump")
	TNT1 A 0 A_SetScale (scaleX+frandom(-0.02, 0.02), scaleY+frandom(-0.04,0.04))
	TNT1 A 0 A_SpawnItemEx ("HumanTrails", 0, 0, 0)
  Spawn2:
    BMR1 T 10 A_Look
    loop
  STFU:
     TNT1 A 0
	 TNT1 A 0 ACS_NamedExecute ("STFUStMerc")
	 Goto Spawn+2
  VanJump:
	 TNT1 A 0
	 TNT1 A 0  NODELAY ACS_NamedExecuteAlways ("VanillaHeights")
	Goto Spawn+3	 
  See:
   "####" A random(1,5)
    TNT1 A 0 A_Jump (70, "DodgeLeft", "DodgeRight", "DodgeLeftF", "DodgeLeftB", "DodgeRightF", "DodgeRightB")
	TNT1 A 0 A_Jump (180, "MissileCheck")
  SeeLoop:
    TNT1 A 0 A_CheckSight ("CheckReload")
    TNT1 A 0 A_JumpIfInventory ("LMGShotCounter", 100, "Reload")
	TNT1 A 0 A_Jump (199, "DodgeLeft", "DodgeRight", "DodgeLeftF", "DodgeLeftB", "DodgeRightF", "DodgeRightB")
    BMR1 AABBCCDD 3 A_Chase
    loop
  CheckReload:
    TNT1 A 0 A_Jump (150, "CheckReload2")
 	Goto SeeLoop+1
  CheckReload2:
    TNT1 A 0 A_JumpIfInventory ("LMGShotCounter", 100, "Reload")
	Goto SeeLoop+1
  DodgeLeft:
        TNT1 A 0 A_FaceTarget
	    BMR1 AABBCCDD 2 ThrustThing(angle*256/360+192, 1, 0, 0)
		TNT1 A 0 A_Jump (228, "MissileCheck")
		TNT1 A 0 A_Jump (50, "DodgeRight")
		Goto SeeLoop+1
	DodgeLeftF:
	    TNT1 A 0 A_FaceTarget
	    TNT1 A 0 ThrustThingZ (0, 15, 0, 0)
	    TNT1 A 0 A_Recoil (random (-8,-3))
	    BMR1 AABBCCDD 2 ThrustThing(angle*256/360+192, 1, 0, 0)
		TNT1 A 0 A_Jump (228, "MissileCheck")
		Goto SeeLoop+1
    DodgeLeftB:
	    TNT1 A 0 A_FaceTarget
	    TNT1 A 0 ThrustThingZ (0, 15, 0, 0)
	    TNT1 A 0 A_Recoil (random (3,8))
	    BMR1 AABBCCDD 2 ThrustThing(angle*256/360+192, 1, 0, 0)
		TNT1 A 0 A_Jump (228, "MissileCheck")
		Goto SeeLoop+1
	DodgeRight:
	    TNT1 A 0 A_FaceTarget
	    BMR1 AABBCCDD 2 ThrustThing(angle*256/360+64, 1, 0, 0)
		TNT1 A 0 A_Jump (228, "MissileCheck")
		Goto SeeLoop+1
	DodgeRightF:
	    TNT1 A 0 A_FaceTarget
	    TNT1 A 0 ThrustThingZ (0, 15, 0, 0)
	    TNT1 A 0 A_Recoil ( random (-8,-3)) 
	    BMR1 AABBCCDD 2 ThrustThing(angle*256/360+64, 1, 0, 0)
		TNT1 A 0 A_Jump (228, "MissileCheck")
		Goto SeeLoop+1
	DodgeRightB:
	    TNT1 A 0 A_FaceTarget
	    TNT1 A 0 ThrustThingZ (0, 15, 0, 0)
	    TNT1 A 0 A_Recoil ( random (3,8)) 
	    BMR1 AABBCCDD 2 ThrustThing(angle*256/360+64, 1, 0, 0)
		TNT1 A 0 A_Jump (228, "MissileCheck")
		Goto SeeLoop+1
  MissileCheck:
    TNT1 A 0 A_JumpIfTargetInLos ("Missile", 0, JLOSF_DEADNOJUMP)
	Goto SeeLoop
  Missile:
    BMR1 E 8 A_FaceTarget
	TNT1 A 0 A_JumpIfTargetInLos ("40mm", 0, JLOSF_CLOSENOJUMP | JLOSF_DEADNOJUMP, 1200, 400)
	//TNT1 A 0 A_JumpIfTargetInLos ("TriShot", 0, JLOSF_CLOSENOJUMP, 0, 950)
	TNT1 A 0 A_JumpIfTargetInLos ("Accuracy", 0, JLOSF_CLOSENOJUMP | JLOSF_DEADNOJUMP, 0, 1500)
  MissileLoop:
    TNT1 A 0 A_PlaySound ("FC1M249F")
	TNT1 A 0 A_PlaySound ("LMGFF", 6, 0.5, 0)
	BMR1 F 1 BRIGHT A_CustomMissile ("LMGDTracer",32,0,random (-6,6))
	TNT1 A 0 A_GiveInventory ("LMGShotCounter", 1)
	TNT1 A 0 A_JumpIfInventory ("LMGShotCounter", 100, "Reload")
	//TNT1 A 0 A_JumpIfInTargetLos ("DodgeCheck")
    BMR1 E 3 A_MonsterRefire (40, "SeeLoop")
	goto MissileLoop
  40mm:
    BMR1 E 8 A_FaceTarget
	TNT1 A 0 A_PlaySound ("GLFIR", CHAN_WEAPON)
	BMR1 F 2 BRIGHT A_CustomMissile ("Grenade40mm", 32, 0, random (-3,3), CMF_OFFSETPITCH, random (10, 16))
	Goto SeeLoop
  Trishot:
    TNT1 A 0 A_PlaySound ("FC1M249F")
	TNT1 A 0 A_PlaySound ("LMGFF", 6, 0.5, 0)
	BMR1 F 1 BRIGHT A_CustomMissile ("LMGDTracer",32,0,random (-1,0))
	TNT1 A 0 A_GiveInventory ("LMGShotCounter", 1)
	TNT1 A 0 A_JumpIfInventory ("LMGShotCounter", 100, "Reload")
	BMR1 E 2 A_FaceTarget 
	TNT1 A 0 A_PlaySound ("FC1M249F")
	TNT1 A 0 A_PlaySound ("LMGFF", 6, 0.5, 0)
	BMR1 F 1 BRIGHT A_CustomMissile ("LMGDTracer",32,0,random (-1,1))
	TNT1 A 0 A_GiveInventory ("LMGShotCounter", 1)
	TNT1 A 0 A_JumpIfInventory ("LMGShotCounter", 100, "Reload")
	BMR1 E 2 A_FaceTarget
	TNT1 A 0 A_PlaySound ("FC1M249F")
	TNT1 A 0 A_PlaySound ("LMGFF", 6, 0.5, 0)
	BMR1 F 1 BRIGHT A_CustomMissile ("LMGDTracer",32,0,random (-2,2))
	TNT1 A 0 A_GiveInventory ("LMGShotCounter", 1)
	TNT1 A 0 A_JumpIfInventory ("LMGShotCounter", 100, "Reload")
	BMR1 E 1 A_MonsterRefire (40, "SeeLoop")
	Goto SeeLoop
  Accuracy:
    BMR1 E 5 A_FaceTarget
	TNT1 A 0 A_PlaySound ("FC1M249F")
	TNT1 A 0 A_PlaySound ("LMGFF", 6, 0.5, 0)
	BMR1 F 1 BRIGHT A_CustomMissile ("LMGDTracer",32,0, random (-2,2))
	TNT1 A 0 A_GiveInventory ("LMGShotCounter", 1)
	TNT1 A 0 A_JumpIfInventory ("LMGShotCounter", 100, "Reload")
	BMR1 E 3 A_MonsterRefire (40, "SeeLoop")
	Goto MissileLoop
  Reload:
    BMR1 E 18 A_PlaySound ("MGMALOPN")
	TNT1 A 0 A_TakeInventory ("LMGShotCounter", 100)
	BMR1 D 37 A_PlaySound ("MGMAGLOA")
	BMR1 E 16 A_PlaySound ("MGMAGCLS")
	Goto SeeLoop
  Pain:
    BMR1 H 3
    BMR1 H 3 A_Pain
    goto SeeLoop
  Death:
  	//TNT1 A 0 A_Jump(20, "Suren")
    BMR1 I 5 A_Scream
    BMR1 J 5
    BMR1 K 5 A_NoBlocking
    BMR1 L 5 A_Playsound ("FallingBodyGear", CHAN_BODY)
    BMR1 M -1
    stop
  XDeath:
    TNT1 A 0
    TNT1 A 0 A_SpawnItemEx ("VgavnonahCore", 0, 0, 0, 0, 0, 0, 0, SXF_NOCHECKPOSITION)
    BMR1 U 5
    BMR1 VWX 3 A_XScream
    PGIB A 5 A_NoBlocking
    PGIB BCD 5
    PGIB E -1 
    Stop
  Raise:
    TNT1 A 0 
	TNT1 A 0 A_SpawnItemEx ("NanoResEffect", 0, 0, 15, 0, 0, 0, 0, SXF_NOCHECKPOSITION)
	BMR1 MLKJI 5
   Goto See	
  Idle:
    BMR1 AA 4 A_Wander
    BMR1 A 0 A_Look
    BMR1 BB 4 A_Wander
    BMR1 A 0 A_Look
    BMR1 CC 4 A_Wander
    BMR1 A 0 A_Look
    BMR1 DD 4 A_Wander
    BMR1 A 0 A_Look
    loop
  }
}


Actor LMGDTracer 
{
Projectile
Damage (7)
+FORCEXYBILLBOARD
+DONTSPLASH
+BLOODSPLATTER 
+NOEXTREMEDEATH
radius 2
height 2
speed 20
renderstyle Add
alpha 0.9
scale .15
 States
     {
	  Spawn:
	    TNT1 A 0
		TNT1 A 0 NoDelay ACS_NamedExecuteAlways("PotentialProjectileHider", 0,0,0)
	  Spawn2:
	    TRAC A 1 Bright A_PlaySound ("Bullet/Fly", 0, 1.0, true)
		Loop
	  Crash:	
	  Death:
	    TNT1 A 0
		TNT1 A 0 NoDelay ACS_NamedExecuteAlways("ProjectileIsDead", 0,0,0)
	    TNT1 A 0 A_Playsound ("Bullet/Impact")
		TNT1 A 0 A_Jump (100, "D2")
		FX57 CDEFGHI 1 BRIGHT
		Stop
	  D2:
	    TNT1 A 0 NoDelay ACS_NamedExecuteAlways("ProjectileIsDead", 0,0,0)
	    FX58 CDEFGHI 1 BRIGHT
		Stop
	  XDeath:
	    TNT1 A 0
		TNT1 A 0 NoDelay ACS_NamedExecuteAlways("ProjectileIsDead", 0,0,0)
		TNT1 A 1
		Stop	
	 }
}



Actor LMGShotCounter : Inventory
{
 Inventory.Maxamount 150
}




	Actor LMGDudeSpawner : RandomSpawner
		{
		 DropItem LightMachineGunDude
		 DropItem LMGDudeGrey
		 DropItem LMGDudeSwamp
		}
		




Actor LMGDudeGrey : LightMachineGunDude
   {
    Translation "112:127=80:111"
   }
  Actor LMGDudeSwamp : LightMachineGunDude
    {
	 Translation "112:127=152:159"
	}
  