   actor MafiaRevolver : GenericHumanScum 
{
  scale 1.0
  obituary "%o wasn't the fastest hand in the Wild Sycilia"
  health 50
  radius 15
  height 54
    Species "IMP"
  +DONTHARMSPECIES
  mass 100
  speed 10
  painchance 185
  SeeSound "Mafia/see"
  PainSound "GTS/pain"
  DeathSound "GTS/Death"
  ActiveSound "Mafia/active" 
  dropitem "Clip", 1
  Tag "Revolver Mobster"
  MONSTER
  +FLOORCLIP
  states
  {
  Spawn:
    TNT1 A 0
	TNT1 A 0 A_JumpIf(ACS_NamedExecuteWithResult("STFUCheck") == 1, "STFU")
	TNT1 A 0 A_JumpIf(ACS_NamedExecuteWithResult ("VanJumpCheck") == 1, "VanJump")
	TNT1 A 0 A_SetScale (scaleX+frandom(-0.02, 0.02), scaleY+frandom(-0.04,0.04))
	TNT1 A 0 A_SpawnItemEx ("HumanTrails", 0, 0, 0)
  Spawn2:	
    MBA2 T 10 A_Look
    loop
  STFU:
     TNT1 A 0
	 TNT1 A 0 ACS_NamedExecute ("STFUMafia")
	 Goto Spawn+2  
  VanJump:
	 TNT1 A 0
	 TNT1 A 0  NODELAY ACS_NamedExecuteAlways ("VanillaHeights")
	Goto Spawn+3	 
  See:
    "####" A random(1,4)
    TNT1 A 0 A_Jump (70, "DodgeLeft", "DodgeRight", "DodgeLeftF", "DodgeLeftB", "DodgeRightF", "DodgeRightB")
	TNT1 A 0 A_Jump (30, "MissileCheck")
    MBA2 EF 5
SeeLoop:
    TNT1 A 0 A_JumpIfCloser (450, "CheckDodge")
	TNT1 A 0 A_Jump (100, "DodgeLeft", "DodgeRight", "DodgeLeftF", "DodgeLeftB", "DodgeRightF", "DodgeRightB")
    MBA4 AABBCCDD 3 A_Chase
	TNT1 A 0 A_CheckSight ("CheckReload")
    loop
CheckReload:
    TNT1 A 0 A_Jump (50, "CheckReload2")
 	Goto SeeLoop
CheckReload2:
    TNT1 A 0 A_JumpIfInventory ("RevolverShotCounter", 6, "Reload")
	Goto SeeLoop
CheckDodge:
    TNT1 A 0 A_Jump (221, "DodgeLeft", "DodgeRight", "DodgeLeftF", "DodgeLeftB", "DodgeRightF", "DodgeRightB")
	Goto SeeLoop+1
    DodgeLeft:
	    TNT1 A 0 A_FaceTarget
	    MBA4 AABBCCDD 2 ThrustThing(angle*256/360+192, 1, 0, 0)
		TNT1 A 0 A_Jump (20, "MissileCheck")
		TNT1 A 0 A_Jump (50, "DodgeRight")
		Goto SeeLoop+1
	DodgeLeftF:
	    TNT1 A 0 A_FaceTarget
	     TNT1 A 0 ThrustThingZ (0, 15, 0, 0)
	    TNT1 A 0 A_Recoil (random (-8,-3))
	    MBA4 AABBCCDD 2 ThrustThing(angle*256/360+192, 1, 0, 0)
		TNT1 A 0 A_Jump (20, "MissileCheck")
		Goto SeeLoop+1
    DodgeLeftB:
	    TNT1 A 0 A_FaceTarget
	     TNT1 A 0 ThrustThingZ (0, 15, 0, 0)
	    TNT1 A 0 A_Recoil (random (3,8))
	    MBA4 AABBCCDD 2 ThrustThing(angle*256/360+192, 1, 0, 0)
		TNT1 A 0 A_Jump (20, "MissileCheck")
		Goto SeeLoop+1
	DodgeRight:
	    TNT1 A 0 A_FaceTarget
	    MBA4 AABBCCDD 2 ThrustThing(angle*256/360+64, 1, 0, 0)
		TNT1 A 0 A_Jump (100, "MissileCheck")
		Goto SeeLoop+1
	DodgeRightF:
	    TNT1 A 0 A_FaceTarget
	     TNT1 A 0 ThrustThingZ (0, 15, 0, 0)
	    TNT1 A 0 A_Recoil ( random (-8,-3)) 
	    MBA4 AABBCCDD 2 ThrustThing(angle*256/360+64, 1, 0, 0)
		TNT1 A 0 A_Jump (100, "MissileCheck")
		Goto SeeLoop+1
	DodgeRightB:
	    TNT1 A 0 A_FaceTarget
	     TNT1 A 0 ThrustThingZ (0, 15, 0, 0)
	    TNT1 A 0 A_Recoil ( random (3,8)) 
	    MBA4 AABBCCDD 2 ThrustThing(angle*256/360+64, 1, 0, 0)
		TNT1 A 0 A_Jump (100, "MissileCheck")
		Goto SeeLoop+1
  MissileCheck:
    TNT1 A 0 A_JumpIfTargetInLos ("Missile")
    Goto SeeLoop+1
  Missile:
    TNT1 A 0 A_JumpIfInventory ("RevolverShotCounter", 6, "Reload")
    MBA2 F 7 A_FaceTarget
	TNT1 A 0 A_JumpIfTargetInLOS ("FullDrum", 0, JLOSF_CLOSENOJUMP | JLOSF_DEADNOJUMP, 0, 600)
	TNT1 A 0 A_Playsound ("REVFIR")
	TNT1 A 0 A_PlaySound ("BPFIRF", 6, 0.5, 0)
	MBA2 G 3 BRIGHT A_CustomMissile ("RevolverTracer",45,0,random (-4,4))
	TNT1 A 0 A_GiveInventory ("RevolverShotCounter", 1)
    MBA2 F 7 A_FaceTarget
	TNT1 A 0 A_JumpIfInventory ("RevolverShotCounter", 6, "Reload")
	TNT1 A 0 A_Playsound ("REVFIR")
	TNT1 A 0 A_PlaySound ("BPFIRF", 6, 0.5, 0)
	MBA2 G 3 BRIGHT A_CustomMissile ("RevolverTracer",45,0,random (-5,5))
	TNT1 A 0 A_GiveInventory ("RevolverShotCounter", 1)
    goto SeeLoop
  FullDrum:
    MBA2 F 12 A_FaceTarget
    TNT1 A 0 A_JumpIfInventory ("RevolverShotCounter", 6, "Reload")
	TNT1 A 0 A_Playsound ("REVFIR")
	TNT1 A 0 A_PlaySound ("BPFIRF", 6, 0.5, 0)
	MBA2 G 2 BRIGHT A_CustomMissile ("RevolverTracer",45,0,random (-3,3))
	TNT1 A 0 A_GiveInventory ("RevolverShotCounter", 1)
	TNT1 A 0 A_JumpIfInventory ("RevolverShotCounter", 6, "Reload")
	TNT1 A 0 A_MonsterRefire (40, "SeeLoop")
	MBA2 F 8 A_FaceTarget
   Loop
  Reload:
	MBA4 D 15 A_PlaySound ("REVOUT")
	TNT1 A 0 A_TakeInventory ("RevolverShotCounter", 6)
	MBA2 F 25 A_PlaySound ("REVLOAD")
	MBA2 D 14 A_PlaySound ("REVIN")
	Goto SeeLoop
  Pain:
    MBA4 H 3
    MBA4 H 3 A_Pain
    goto SeeLoop
  Death:
	//TNT1 A 0 A_Jump(40, "Suren")
    MBA2 J 5
    MBA2 K 5 A_Scream
	TNT1 A 0 A_Playsound ("FallingBodyLight", CHAN_BODY)
    MBA2 L 5 A_NoBlocking
    MBA2 M -1
    stop
  XDeath:
    TNT1 A 0 A_SpawnItemEx ("VgavnonahCore", 0, 0, 0, 0, 0, 0, 0, SXF_NOCHECKPOSITION)
    MBA2 U 5 A_XScream
    MBA2 V 5
    PGIB A 5 A_NoBlocking
    PGIB BCD 5
    PGIB E -1
    Stop
  Idle:
    MBA4 AA 4 A_Wander
    MBA4 A 0 A_Look
    MBA4 BB 4 A_Wander
    MBA4 A 0 A_Look
    MBA4 CC 4 A_Wander
    MBA4 A 0 A_Look
    MBA4 DD 4 A_Wander
    MBA4 A 0 A_Look
    loop
  Raise:
    TNT1 A 0 
	TNT1 A 0 A_SpawnItemEx ("NanoResEffect", 0, 0, 15, 0, 0, 0, 0, SXF_NOCHECKPOSITION)
	MBA2 MLKJ 5
   Goto See	
  }
}


	Actor RevolverTracer 
{
	Projectile
	Damage (7) 
	+FORCEXYBILLBOARD
	+DONTSPLASH
	+BLOODSPLATTER 
	+NOEXTREMEDEATH
	radius 2
	height 2
	speed 20
	renderstyle Add
	alpha 0.9
	scale .15
	 States
		 {
		  Spawn:
			TRAC A 1 Bright A_PlaySound ("Bullet/Fly", 0, 1.0, true)
			Loop
		  Death:
			TNT1 A 0 A_Playsound ("Bullet/Impact")
			TNT1 A 0 A_Jump (100, "D2")
			FX57 CDEFGHI 1 BRIGHT
			Stop
		  D2:
			FX58 CDEFGHI 1 BRIGHT
			Stop
		  XDeath:
			TNT1 A 1
			Stop
		 }
}



	Actor RevolverShotCounter : Inventory
{
Inventory.maxamount 8
}	