actor MP5GOPNIK : GenericHumanScum 
{
  scale 1.0
  obituary "%o was masleened by the tracksuit guy with MP-5"
  health 40
  radius 15
  height 54
  mass 100
  speed 11
  Damage 1
  Species "IMP"
+DONTHARMSPECIES
  painchance 180
  SeeSound "CBydlo/See"
  PainSound "CBydlo/pain"
  DeathSound "CBydlo/Death"
  ActiveSound "CBydlo/Active"
  Translation "112:127=5:8", "192:207=5:8"
  Tag "SMGAbibasGuy"
  //+DROPOFF
  MONSTER
  +FLOORCLIP
  states
  {
  Spawn:
    TNT1 A 0
	TNT1 A 0 A_JumpIf(ACS_NamedExecuteWithResult("STFUCheck") == 1, "STFU")
	TNT1 A 0 A_JumpIf(ACS_NamedExecuteWithResult ("VanJumpCheck") == 1, "VanJump")
    TNT1 A 0 A_SetScale (scaleX+frandom(-0.02, 0.02), scaleY+frandom(-0.08,0.08)) 
	TNT1 A 0 A_SpawnItemEx ("HumanTrails", 0, 0, 0)
	TNT1 A 0 A_SpawnItemEx ("BydloWRITER", 0, 0, 0, 0, 0, 0, 0, SXF_NOCHECKPOSITION, 69)
  Spawn2:
    GOPO T 10 A_Look
    loop
  STFU:
     TNT1 A 0
	 TNT1 A 0 ACS_NamedExecute ("STFUCBydlo")
	 Goto Spawn+2
  VanJump:
	 TNT1 A 0
	 TNT1 A 0  NODELAY ACS_NamedExecuteAlways ("VanillaHeights")
	Goto Spawn+3	 
  See:
     "####" A random(1,4)
	 TNT1 A 0 A_Jump (70, "DodgeLeft", "DodgeRight", "DodgeLeftF", "DodgeLeftB", "DodgeRightF", "DodgeRightB")
	 TNT1 A 0 A_Jump (180, "MissileCheck")
  SeeLoop:
	TNT1 A 0 A_CheckSight ("CheckReload")
	TNT1 A 0 A_Jump (170, "DodgeLeft", "DodgeRight", "DodgeLeftF", "DodgeLeftB", "DodgeRightF", "DodgeRightB")
	TNT1 A 0 A_JumpIfInventory ("SMGShotCounter", 30, "Reload")
    GOPO AABBCCDD 3 A_Chase
    loop
  MissileCheck:
    TNT1 A 0
	TNT1 A 0 A_JumpIfTargetInLos ("Accuracy", 50, JLOSF_CLOSENOJUMP | JLOSF_DEADNOJUMP, 0, 750)
	Goto SeeLoop
    CheckReload:
    TNT1 A 0 A_Jump (150, "CheckReload2")
 	Goto SeeLoop+1
  CheckReload2:
    TNT1 A 0 A_JumpIfInventory ("SMGShotCounter", 30, "Reload")
	Goto SeeLoop+1
  DodgeLeft:
        TNT1 A 0 A_FaceTarget
	    GOPO AABBCCDD 2 ThrustThing(angle*256/360+192, 1, 0, 0)
		TNT1 A 0 A_Jump (120, "MissileCheck2")
		TNT1 A 0 A_Jump (50, "DodgeRight")
		Goto SeeLoop+1
	DodgeLeftF:
	    TNT1 A 0 A_FaceTarget
	    TNT1 A 0 ThrustThingZ (0, 15, 0, 0)
	    TNT1 A 0 A_Recoil (random (-8,-3))
	    GOPO AABBCCDD 2 ThrustThing(angle*256/360+192, 1, 0, 0)
		TNT1 A 0 A_Jump (120, "MissileCheck2")
		Goto SeeLoop+1
    DodgeLeftB:
	    TNT1 A 0 A_FaceTarget
	    TNT1 A 0 ThrustThingZ (0, 15, 0, 0)
	    TNT1 A 0 A_Recoil (random (3,8))
	    GOPO AABBCCDD 2 ThrustThing(angle*256/360+192, 1, 0, 0)
		TNT1 A 0 A_Jump (120, "MissileCheck2")
		Goto SeeLoop+1
	DodgeRight:
	    TNT1 A 0 A_FaceTarget
	    GOPO AABBCCDD 2 ThrustThing(angle*256/360+64, 1, 0, 0)
		TNT1 A 0 A_Jump (100, "MissileCheck2")
		Goto SeeLoop+1
	DodgeRightF:
	    TNT1 A 0 A_FaceTarget
	    TNT1 A 0 ThrustThingZ (0, 15, 0, 0)
	    TNT1 A 0 A_Recoil ( random (-8,-3)) 
	    GOPO AABBCCDD 2 ThrustThing(angle*256/360+64, 1, 0, 0)
		TNT1 A 0 A_Jump (100, "MissileCheck2")
		Goto SeeLoop+1
	DodgeRightB:
	    TNT1 A 0 A_FaceTarget
	    TNT1 A 0 ThrustThingZ (0, 15, 0, 0)
	    TNT1 A 0 A_Recoil ( random (3,8)) 
	    GOPO AABBCCDD 2 ThrustThing(angle*256/360+64, 1, 0, 0)
		TNT1 A 0 A_Jump (100, "MissileCheck2")
		Goto SeeLoop+1			
   Retreat:
    TNT1 A 0 A_Changeflag ("FRIGHTENED", 1)
	TNT1 A 0 A_ChangeFlag ("Missilemore", 1)
	TNT1 A 0 A_ChangeFlag ("MissileEvenMore", 1)  
	Goto SeeLoop+1	
  Missile:
    TNT1 A 0 A_TakeInventory ("AccuracyCounter", 15)
    TNT1 A 0 A_JumpIfInventory ("SMGShotCounter", 30, "Reload")
	TNT1 A 0 A_JumpIfTargetInLos ("Accuracy", 0, JLOSF_CLOSENOJUMP | JLOSF_DEADNOJUMP, 0, 800) 
    GOPO EF 6 A_FaceTarget
  MissileLoop:
    GOPO F 2 A_FaceTarget
	TNT1 A 0 A_JumpIfTargetInLos ("Accuracy", 0, JLOSF_CLOSENOJUMP | JLOSF_DEADNOJUMP, 0, 800)
	TNT1 A 0 A_JumpIfInventory ("SMGShotCounter", 30, "Reload")
	TNT1 A 0 A_PlaySound ("MP5")
	TNT1 A 0 A_PlaySound ("MP5FF", 6, 0.5, 0)
	GOPO G 1 BRIGHT A_CustomMissile ("SMGTracer",44,9,random (-3,3))
	TNT1 A 0 A_GiveInventory ("SMGShotCounter", 1)
    GOPO F 1 A_MonsterRefire (40, "SeeLoop")
	goto MissileLoop+1
  Accuracy:
    TNT1 A 0
    TNT1 A 0 A_JumpIfInventory ("AccuracyCounter", 15, "SeeLoop")
	TNT1 A 0 A_JumpIfInventory ("SMGShotCounter", 30, "Reload")
    GOPO F 2 A_FaceTarget
	TNT1 A 0 A_PlaySound ("MP5")
	TNT1 A 0 A_PlaySound ("MP5FF", 6, 0.5, 0)
	GOPO G 1 Bright A_CustomMissile ("SMGTracer",44,9,random (-1,1))
	TNT1 A 0 A_JumpIfInventory ("AccuracyCounter", 15, "SeeLoop")
	TNT1 A 0 A_GiveInventory ("SMGShotCounter", 1)
	TNT1 A 0 A_GiveInventory ("AccuracyCounter", 1)
	//GOPO F 1 A_MonsterRefire (40, "SeeLoop")
	Loop
  Reload:
    TNT1 A 0 A_JumpIfCloser (550, "Retreating")
    GOPO F 16 A_PlaySound ("SMGOUT")
	TNT1 A 0 A_TakeInventory ("SMGShotCounter", 30)
	GOPO E 32 A_PlaySound ("SMGIN")
	GOPO F 17 A_PlaySound ("SMGCOCK")
	TNT1 A 0 A_JumpIfCloser (450, "MissileCheck2")	
	Goto SeeLoop
  MissileCheck2:
    TNT1 A 0 A_JumpIfTargetInLos ("Missile")
	Goto SeeLoop
  Retreating:
    TNT1 A 0 A_ChangeFlag ("FRIGHTENED", true) 
    GOPO ABCDABCDABCDABCDABCDABCDABCDABCD 2 A_Chase
	TNT1 A 0 A_CheckSight ("ReloadReady")	
 ReloadReady:
    TNT1 A 0 A_ChangeFlag ("FRIGHTENED", false)
	Goto ReloadBrave
 ReloadBrave:
    GOPO F 16 A_PlaySound ("SMGOUT")
	TNT1 A 0 A_TakeInventory ("SMGShotCounter", 30)
	GOPO E 32 A_PlaySound ("SMGIN")
	GOPO F 17 A_PlaySound ("SMGCOCK")
	TNT1 A 0 A_JumpIfCloser (450, "MissileCheck2")	
	Goto SeeLoop	
  Pain:
    GOPO H 3
    GOPO H 3 A_Pain
    goto SeeLoop
  Death:
    GOPO I 5 A_Scream
    GOPO J 5 
    GOPO K 5 A_NoBlocking
    GOPO L 5
	GOPO M 5 A_Playsound ("FallingBodyLight", CHAN_BODY)
    GOPO M -1
    stop
  XDeath:
    TNT1 A 0
    TNT1 A 0 A_SpawnItemEx ("VgavnonahCore", 0, 0, 0, 0, 0, 0, 0, SXF_NOCHECKPOSITION)
    GOPO N 5 A_XScream
    GOPO O 5
    PGIB A 5 A_NoBlocking
    PGIB BCD 5
    PGIB E -1
    Stop
  Raise:
    TNT1 A 0 
    TNT1 A 0 A_SpawnItemEx ("NanoResEffect", 0, 0, 15, 0, 0, 0, 0, SXF_NOCHECKPOSITION)
	GOPO MLKJI 5
   Goto See  	
  Idle:
    GOPO AA 4 A_Wander
    GOPO A 0 A_Look
    GOPO BB 4 A_Wander
    GOPO A 0 A_Look
    GOPO CC 4 A_Wander
    GOPO A 0 A_Look
    GOPO DD 4 A_Wander
    GOPO A 0 A_Look
    loop
  }
}


	Actor MP5GopnikSpawner : RandomSpawner
	   //$Category Enemies
	   //$EditorSprite GOPO A
		{
		 DropItem MP5Gopnik
		 DropItem Mp5GopnikHaki
		 DropItem Mp5GopnikGrey
		 DropItem Mp5GopnikBlue
		 DropItem Mp5GopnikGreyBlue
		 DropItem Mp5GopnikBlackGrey
		 DropItem Mp5GopnikHakiBlack
		}


 Actor Mp5GopnikHaki : MP5Gopnik
	 {
	  Translation "112:127=240:247", "192:207=240:247"
	 }

 Actor Mp5GopnikGrey : MP5Gopnik
	 {
	  Translation "112:127=80:111", "192:207=80:111"
	 }

 Actor Mp5GopnikBlue : MP5Gopnik
	 {
	  Translation "112:127=192:207", "192:207=192:207"
	 }

Actor Mp5GopnikGreyBlue : MP5Gopnik
	 {
	  Translation "112:127=80:111", "192:207=192:207"
	 }

Actor Mp5GopnikBlackGrey : MP5Gopnik
	 {
	  Translation "112:127=5:8", "192:207=80:111"
	 }

Actor Mp5GopnikHakiBlack : MP5Gopnik
	 {
	  Translation "112:127=240:247", "192:207=5:8"
	 }

