actor MP5Gopness : GenericFeHumanScum 
{
  scale 1.0
  obituary "%o was shocked by unculural behaviour of the Gopness with MP5"
  health 40
  radius 15
  height 54
  mass 100
  speed 11
  Damage 1
  Species "IMP"
+DONTHARMSPECIES
  painchance 180
  SeeSound "FemBydlo4/See"
  PainSound "FemBydlo4/pain"
  DeathSound "Fembydlo/Death"
  ActiveSound "FemBydlo4/Active"
  Tag "MP5 Gopness"
  Translation "112:127=5:8", "192:207=80:111"
  MONSTER
  +FLOORCLIP
  states
  {
  Spawn:
    TNT1 A 0
	TNT1 A 0 A_JumpIf(ACS_NamedExecuteWithResult("STFUCheck") == 1, "STFU")
	TNT1 A 0 A_JumpIf(ACS_NamedExecuteWithResult ("VanJumpCheck") == 1, "VanJump")
    TNT1 A 0 A_SetScale (scaleX+frandom(-0.02, 0.02), scaleY+frandom(-0.08,0.08)) 
	TNT1 A 0 A_SpawnItemEx ("HumanTrails", 0, 0, 0)
	TNT1 A 0 A_SpawnItemEx ("BydloWRITER", 0, 0, 0, 0, 0, 0, 0, SXF_NOCHECKPOSITION, 69)
  Spawn2:
    ER2A T 10 A_Look
    loop
  STFU:
     TNT1 A 0
	 TNT1 A 0 ACS_NamedExecute ("STFUFemBydlo4")
	 Goto Spawn+2
  VanJump:
	 TNT1 A 0
	 TNT1 A 0  NODELAY ACS_NamedExecuteAlways ("VanillaHeights")
	Goto Spawn+3	 
  See:
     "####" A random(1,4)
	 TNT1 A 0 A_Jump (70, "DodgeLeft", "DodgeRight", "DodgeLeftF", "DodgeLeftB", "DodgeRightF", "DodgeRightB")
	 TNT1 A 0 A_Jump (180, "MissileCheck")
  SeeLoop:
	TNT1 A 0 A_CheckSight ("CheckReload")
	TNT1 A 0 A_Jump (170, "DodgeLeft", "DodgeRight", "DodgeLeftF", "DodgeLeftB", "DodgeRightF", "DodgeRightB")
	TNT1 A 0 A_JumpIfInventory ("SMGShotCounter", 15, "Reload")
    ER2A AABBCCDD 3 A_Chase
    loop
  MissileCheck:
    TNT1 A 0
	TNT1 A 0 A_JumpIfInventory ("GrenadeCoolDown", 1, 2)
    TNT1 A 0 A_Jump (75, "PipeBombCheck")	
	TNT1 A 0 A_JumpIfTargetInLos ("Missile", 50, JLOSF_DEADNOJUMP)
	Goto SeeLoop
    CheckReload:
    TNT1 A 0 A_Jump (150, "CheckReload2")
 	Goto SeeLoop+1
  CheckReload2:
    TNT1 A 0 A_JumpIfInventory ("SMGShotCounter", 15, "Reload")
	Goto SeeLoop+1
  DodgeLeft:
        TNT1 A 0 A_FaceTarget
	    ER2A AABBCCDD 2 ThrustThing(angle*256/360+192, 1, 0, 0)
		TNT1 A 0 A_Jump (120, "MissileCheck2")
		TNT1 A 0 A_Jump (50, "DodgeRight")
		Goto SeeLoop+1
	DodgeLeftF:
	    TNT1 A 0 A_FaceTarget
	    TNT1 A 0 ThrustThingZ (0, 15, 0, 0)
	    TNT1 A 0 A_Recoil (random (-8,-3))
	    ER2A AABBCCDD 2 ThrustThing(angle*256/360+192, 1, 0, 0)
		TNT1 A 0 A_Jump (120, "MissileCheck2")
		Goto SeeLoop+1
    DodgeLeftB:
	    TNT1 A 0 A_FaceTarget
	    TNT1 A 0 ThrustThingZ (0, 15, 0, 0)
	    TNT1 A 0 A_Recoil (random (3,8))
	    ER2A AABBCCDD 2 ThrustThing(angle*256/360+192, 1, 0, 0)
		TNT1 A 0 A_Jump (120, "MissileCheck2")
		Goto SeeLoop+1
	DodgeRight:
	    TNT1 A 0 A_FaceTarget
	    ER2A AABBCCDD 2 ThrustThing(angle*256/360+64, 1, 0, 0)
		TNT1 A 0 A_Jump (100, "MissileCheck2")
		Goto SeeLoop+1
	DodgeRightF:
	    TNT1 A 0 A_FaceTarget
	    TNT1 A 0 ThrustThingZ (0, 15, 0, 0)
	    TNT1 A 0 A_Recoil ( random (-8,-3)) 
	    ER2A AABBCCDD 2 ThrustThing(angle*256/360+64, 1, 0, 0)
		TNT1 A 0 A_Jump (100, "MissileCheck2")
		Goto SeeLoop+1
	DodgeRightB:
	    TNT1 A 0 A_FaceTarget
	    TNT1 A 0 ThrustThingZ (0, 15, 0, 0)
	    TNT1 A 0 A_Recoil ( random (3,8)) 
	    ER2A AABBCCDD 2 ThrustThing(angle*256/360+64, 1, 0, 0)
		TNT1 A 0 A_Jump (100, "MissileCheck2")
		Goto SeeLoop+1			
   Retreat:
    TNT1 A 0 A_Changeflag ("FRIGHTENED", 1)
	TNT1 A 0 A_ChangeFlag ("Missilemore", 1)
	TNT1 A 0 A_ChangeFlag ("MissileEvenMore", 1)  
	Goto SeeLoop+1	
  Missile:
	TNT1 A 0 A_TakeInventory ("GrenadeCoolDown", 1)
    TNT1 A 0 A_TakeInventory ("AccuracyCounter", 5)
    TNT1 A 0 A_JumpIfInventory ("SMGShotCounter", 15, "Reload")
	TNT1 A 0 A_JumpIfTargetInLos ("Accuracy", 0, JLOSF_CLOSENOJUMP | JLOSF_DEADNOJUMP, 0, 800) 
    ER2A EF 6 A_FaceTarget
  MissileLoop:
    ER2A F 2 A_FaceTarget
	TNT1 A 0 A_JumpIfTargetInLos ("Accuracy", 0, JLOSF_CLOSENOJUMP | JLOSF_DEADNOJUMP, 0, 800)
	TNT1 A 0 A_JumpIfInventory ("SMGShotCounter", 15, "Reload")
	TNT1 A 0 A_PlaySound ("MP5")
	TNT1 A 0 A_PlaySound ("MP5FF", 6, 0.5, 0)
	ER2A G 1 BRIGHT A_CustomMissile ("SMGTracer",42,9,random (-3,3))
	TNT1 A 0 A_GiveInventory ("SMGShotCounter", 1)
    ER2A F 2 A_MonsterRefire (40, "SeeLoop")
	goto MissileLoop+1
  Accuracy:
    TNT1 A 0
    TNT1 A 0 A_JumpIfInventory ("AccuracyCounter", 5, "SeeLoop")
	TNT1 A 0 A_JumpIfInventory ("SMGShotCounter", 15, "Reload")
    ER2A F 4 A_FaceTarget
	TNT1 A 0 A_PlaySound ("MP5")
	TNT1 A 0 A_PlaySound ("MP5FF", 6, 0.5, 0)
	ER2A G 1 Bright A_CustomMissile ("SMGTracer",42,9,random (-1,1))
	TNT1 A 0 A_JumpIfInventory ("AccuracyCounter", 5, "SeeLoop")
	TNT1 A 0 A_GiveInventory ("SMGShotCounter", 1)
	TNT1 A 0 A_GiveInventory ("AccuracyCounter", 1)
	//ER2A F 1 A_MonsterRefire (40, "SeeLoop")
	Loop
  PipeBombCheck:
	TNT1 A 0
    TNT1 A 0 A_JumpIfTargetInLos ("PipeBomb", 0, JLOSF_CLOSENOJUMP | JLOSF_DEADNOJUMP, 700, 300)
	Goto MissileCheck+2
  PipeBomb:
    //TNT1 A 0 A_Print ("Granata")
	TNT1 A 0 A_Playsound ("PIZ1GR01", CHAN_VOICE)
    ER2A E 12 A_FaceTarget
	TNT1 A 0 A_PlaySound ("GRNTOSS", CHAN_WEAPON)
	ER2A F 3 A_CustomMissile ("PipeBomb", 42, 0, random (-3,3), CMF_OFFSETPITCH, random (8, 12))
	TNT1 A 0 A_GiveInventory ("GrenadeCoolDown", 3)
	Goto SeeLoop			
  Reload:
    TNT1 A 0 A_JumpIfCloser (350, "Retreating")
    ER2A F 10 A_PlaySound ("SMGOUT")
	TNT1 A 0 A_TakeInventory ("SMGShotCounter", 15)
	ER2A E 42 A_PlaySound ("SMGIN")
	ER2A F 24 A_PlaySound ("SMGCOCK")
	TNT1 A 0 A_JumpIfCloser (450, "MissileCheck2")	
	Goto SeeLoop
  MissileCheck2:
    TNT1 A 0 A_JumpIfTargetInLos ("Missile")
	Goto SeeLoop
  Retreating:
    TNT1 A 0 A_ChangeFlag ("FRIGHTENED", true) 
    ER2A ABCDABCDABCDABCDABCDABCDABCDABCD 2 A_Chase
	TNT1 A 0 A_CheckSight ("ReloadReady")	
 ReloadReady:
    TNT1 A 0 A_ChangeFlag ("FRIGHTENED", false)
	Goto ReloadBrave
 ReloadBrave:
    ER2A F 10 A_PlaySound ("SMGOUT")
	TNT1 A 0 A_TakeInventory ("SMGShotCounter", 15)
	ER2A E 42 A_PlaySound ("SMGIN")
	ER2A F 24 A_PlaySound ("SMGCOCK")
	TNT1 A 0 A_JumpIfCloser (450, "MissileCheck2")	
	Goto SeeLoop	
  Pain:
    ER2A H 3
    ER2A H 3 A_Pain
    goto SeeLoop
  Death:
    ER2A I 5 A_Scream
    ER2A J 5
    ER2A K 5 A_NoBlocking
    ER2A L 5 A_Playsound ("FallingBodyLight", CHAN_BODY)
    ER2A M -1
    stop
  Death.WEAK:
    ER2A N 5
    ER2A O 5 A_PlaySound("Baddy/pain")
    ER2A P 5 A_NoBlocking
    ER2A Q 5
    ER2A R -1
    stop
  XDeath:
    TNT1 A 0
    TNT1 A 0 A_SpawnItemEx ("VgavnonahCore", 0, 0, 0, 0, 0, 0, 0, SXF_NOCHECKPOSITION)
    ER2A U 5 A_XScream
    ER2A V 5 
    PGIB A 5 A_NoBlocking
    PGIB BCD 5
    PGIB E -1
    Stop
  Raise:
    TNT1 A 0 
	TNT1 A 0 A_SpawnItemEx ("NanoResEffect", 0, 0, 15, 0, 0, 0, 0, SXF_NOCHECKPOSITION)
	ER2A MLKJI 5
   Goto See	
  Idle:
    ER2A AA 4 A_Wander
    ER2A A 0 A_Look
    ER2A BB 4 A_Wander
    ER2A A 0 A_Look
    ER2A CC 4 A_Wander
    ER2A A 0 A_Look
    ER2A DD 4 A_Wander
    ER2A A 0 A_Look
    loop
  }
}


	Actor MP5GopnessSpawner : RandomSpawner 
		{
		 DropItem MP5Gopness
		 DropItem MP5GopnessGreyNavy
		 DropItem MP5GopnessNavyGreen
		 DropItem MP5GopnessWhiteNavy
		 DropItem MP5GopnessBrownBlack
		}


	Actor MP5GopnessGreyNavy : MP5Gopness
		{
		 Translation "112:127=96:111", "192:207=240:247"
		}
		
	Actor MP5GopnessNavyGreen : MP5Gopness
		{
		 Translation "112:127=240:247", "192:207=119:127"
		}
		
	Actor MP5GopnessWhiteNavy : MP5Gopness
		{
		 Translation "112:127=80:100", "192:207=240:247"
		}
		
	Actor MP5GopnessBrownBlack : MP5Gopness
		{	
		 Translation "112:127=64:79", "192:207=5:8"
		} 
		
		
		
		

