Actor IwasaBaron  //BaronOfHell
{


 //-----------------------------------COMPLEX DOOM COMPATIBILITY DROPS----------------------------------------------
  
  DropItem "WeaponUpgradeBox" 88		 
  DropItem "Grenade Launcher", 175

Health 1000
Radius 24
Height 64
Mass 450
Speed 9
PainChance 50
+BOSSDEATH
MinMissileChance 88
Monster
Species "BloodyHeavy"
BloodType "DASBLUT"
seesound "CS/See"
painsound "CS/Pain"
deathsound "CS/Death"
activesound "CS/Active"
Tag "Cyber Soldier Mark 1"
+FLOORCLIP
+DONTHARMSPECIES
scale 1.0
Obituary "%o was blown up by weird cyber-freak with TV-screen instead of face"
DropItem "Clip"
  States
       {
	   Spawn:
	      TNT1 A 0
		  TNT1 A 0 A_JumpIf(ACS_NamedExecuteWithResult("STFUCheck") == 1, "STFU")
	   Spawn2: 	   
	      CBRT A 4 A_Look
		  Loop
	   STFU:
		 TNT1 A 0
		 TNT1 A 0 ACS_NamedExecute ("STFUCS")
		 Goto Spawn+2	   
	   See:
	      CBRT AABBCCDD 4 A_Chase
		  Loop
	   Missile:
	      CBRT E 8 A_FaceTarget
		  TNT1 A 0 A_JumpIfCloser (550, "GrenadeBurst")
		  TNT1 A 0 A_PlaySound ("RLF")
		  CBRT F 10 Bright A_CustomMissile ("CSMiniMissile", 32, 15)
		  CBRT E 7 A_Playsound ("RLRLD")
		  Goto See
	   GrenadeBurst:
	      TNT1 A 0 A_PlaySound ("GRENLF")
	      CBRT F 10 Bright A_CustomMissile ("CSGrenade", 32, 15, 0, CMF_OFFSETPITCH, random (0, 15))
		  CBRT E 4 A_FaceTarget
		  TNT1 A 0 A_PlaySound ("GRENLF")
		  CBRT F 10 Bright A_CustomMissile ("CSGrenade", 32, 15, 0, CMF_OFFSETPITCH, random (0, 15))
		  CBRT E 4 A_FaceTarget
		  TNT1 A 0 A_PlaySound ("GRENLF")
		  CBRT F 10 Bright A_CustomMissile ("CSGrenade", 32, 15, 0, CMF_OFFSETPITCH, random (0, 15))
		  CBRT E 4 A_FaceTarget
		  TNT1 A 0 A_PlaySound ("GRENLF")
		  CBRT F 10 Bright A_CustomMissile ("CSGrenade", 32, 15, 0, CMF_OFFSETPITCH, random (0, 15))
		  CBRT E 4 A_FaceTarget
		  TNT1 A 0 A_PlaySound ("GRENLF")
		  CBRT F 10 Bright A_CustomMissile ("CSGrenade", 32, 15, 0, CMF_OFFSETPITCH, random (0, 15))
		  CBRT E 4 A_FaceTarget
		  TNT1 A 0 A_PlaySound ("GRENLF")
		  CBRT F 10 Bright A_CustomMissile ("CSGrenade", 32, 15, 0, CMF_OFFSETPITCH, random (0, 15))
		  Goto See
	   Pain:
	      CBRT J 4
		  CBRT J 4 A_Pain
		  Goto See
	   Death:
	      CBRD AB 8 A_Scream
		  CBRD C 6 A_NoBlocking
		  CBRD D 7
		  CBRD E -1
		  Stop
	   Raise:
	     TNT1 A 0 
		 TNT1 A 0 A_SpawnItemEx ("NanoResEffect", 0, 0, 15, 0, 0, 0, 0, SXF_NOCHECKPOSITION)
	     CBRD EDCBA 5
		Goto See  
		  }	   
}


actor CSMiniMissile  
{
projectile
+MISSILE
+BLOODSPLATTER
Species "BloodyHeavy"
+DONTHARMSPECIES
radius 3
height 3
missiletype "CSMiniMissileTrail"
missileheight 8
scale 0.45
speed 28
damage (35)
Obituary "%o is now a rocket-man!"
states
{
Spawn:
TNT1 A 0 A_SpawnItemEx("CSMiniMissileTrail",0,0,0,0,0,0,0,SXF_NOCHECKPOSITION)
TNT1 A 0 A_SpawnItemEx("LesserRocketTrail",-10,0,0,0,0,0,0,SXF_NOCHECKPOSITION) 
MISL A 1 Bright A_Playsound ("rockfly",7,1.0,true)
loop
Death:
TNT1 A 0
TNT1 A 0 A_PlaySound("misc/boom",0)
TNT1 A 0 A_PlaySound("misc/distanceboom",6,1.0,0,0)
TNT1 A 0 A_Explode((45),90, 0 ,0,40)
TNT1 AAAAA 0 A_CustomMissile ("CSMiniMissileExplosionFlame", 0, 0, random (0, 360), 2, random (0, 360))
TNT1 AAA 0 A_CustomMissile ("CSMiniMissileBoomSmoke", 0, 0, random (0, 360), 2, random (0, 360))
TNT1 A 0 A_SpawnItemEx("CSMiniMissileShockwave",0,0,0,0,0,0,0,SXF_NOCHECKPOSITION)
TNT1 A 1 Radius_Quake (2,4,0,7,0)
TNT1 A 0 A_StopSound (7)
TNT1 A 20
stop
}
}

actor CSMiniMissileTrail
{
radius 0
height 0
+NOINTERACTION 
+CLIENTSIDEONLY
renderstyle add
alpha 0.9
scale 0.3
states
{
Spawn:
PUF2 ABCDEFGHIJKLMNOPQRSTUWXYZ 1 A_FadeOut(0.05)
stop
}
}

actor CSMiniMissileExplosionFlame
{
renderstyle add
alpha 0.9
scale 0.8
projectile 
radius 1
height 1
speed 3
damage 0
+NOINTERACTION
+CLIENTSIDEONLY
states
{
Spawn:
EXP1 ABCDEFGH 1 Bright
stop
}
}

actor CSMiniMissileBoomSmoke
{
PROJECTILE
	+CLIENTSIDEONLY
	+NOINTERACTION	
	+MISSILE
	+THRUACTORS
	+DOOMBOUNCE
	Radius 1
	Height 1
	Scale 4.0
	Speed 0.69
	Renderstyle Translucent
	Alpha 0.4
	States
    {
    Spawn:  
	    TNT1 A 0
		TNT1 A 0 A_Jump(128, 2)
		TNT1 A 0 A_SetScale(-1.2, 1.2)
		TNT1 A 0
        NSMK ABCDEFGHIJKLMNOPQR 2
		Stop
		}
} 



actor CSMiniMissileShockwave
{
renderstyle add
alpha 0.5
scale 0.2
+NOINTERACTION
+CLIENTSIDEONLY
states
{
Spawn:
BFS7 A 1 bright A_FadeOut(0.05,1)
TNT1 A 0 A_SetScale(scalex+0.05,scaley+0.05)
loop
}
}


actor CSGrenade
{
projectile
+MISSILE
-NOGRAVITY
+BLOODSPLATTER
+CANBOUNCEWATER
+DONTHARMSPECIES
Species "BloodyHeavy" 
bouncetype "Doom"
gravity 0.7
bouncecount 5
radius 5
height 5
speed 30
scale 0.4
damage (10)
bouncesound "OGRBNC"
Obituary "%o was blown up by weird-looking tin can"
states
{
Spawn:
QGRP ABCDEFGHIJK 1 A_SpawnItemEx("CSMiniMissileTrail",0,0,0,0,0,0,0,SXF_NOCHECKPOSITION)
loop
Death:
TNT1 A 0
TNT1 A 0 A_PlaySound("misc/boom",0)
TNT1 A 0 A_PlaySound("misc/distanceboom",6,1.0,0,0)
TNT1 A 0 A_Explode((25),69, 0 ,0,60)
TNT1 AAAAA 0 A_CustomMissile ("CSMiniMissileExplosionFlame", 0, 0, random (0, 360), 2, random (0, 360))
TNT1 AAAA 0 A_CustomMissile ("CSMiniMissileBoomSmoke", 0, 0, random (0, 360), 2, random (0, 360))
TNT1 A 0 A_SpawnItemEx("CSMiniMissileShockwave",0,0,0,0,0,0,0,SXF_NOCHECKPOSITION)
TNT1 A 1 Radius_Quake (2,4,0,7,0)
TNT1 A 20
stop
}
}
