actor ScorchWheelBoss : BaseMM8BDMWep_CBM
{
tag "$TAGC_7H"
dropitem "ScorchWheelWepCDropped"
Weapon.AmmoUse 21
Weapon.AmmoGive 0
Obituary "$OB_SCORCHWHEEL"
weapon.ammotype "DieselJuiceAmmo"
weapon.ammotype2 "CrashDriveAmmo"
States
{
Spawn:
C_07 H 1
loop
Ready:
TUCA A 0 ACS_ExecuteAlways(998,0,DYE_TURBOMAN)
goto Ready0
Ready0:
TUCA A 0 A_JumpIfInventory("TurboAltDelay",1,"Ready1")
goto Ready1a
Ready1:
TUCA A 0 A_JumpIfInventory("DieselJuiceAmmo",21,"Ready2")
TUCA A 4 A_WeaponReady(12)
TUCA A 0 A_GiveInventory("DieselJuiceAmmo",3)
TUCA A 0 A_JumpIfInventory("TurboAltDelay",1,"Ready1")
Goto Ready1a
Ready1a:
TUCA A 0 A_JumpIfInventory("DieselJuiceAmmo",21,"ReadyX")
TUCA A 4 A_WeaponReady(4)
TUCA A 0 A_GiveInventory("DieselJuiceAmmo",3)
loop
Ready2:
TUCA A 4 A_WeaponReady(8)
TUCA A 0 A_GiveInventory("DieselJuiceAmmo",3)
TUCA A 0 A_JumpIfInventory("TurboAltDelay",1,"Ready2")
goto ReadyX
ReadyX:
TUCA A 4 A_WeaponReady
TUCA A 0 A_GiveInventory("DieselJuiceAmmo",3)
loop
Deselect:
TNT1 AAAAAAAAAAAAAAAAAAAAAA 0 A_Lower
TUCA A 1 A_Lower
Loop
Select:
TNT1 AAAAAAAAAAAAAAAAAAAAAA 0 A_Raise
TUCA A 1 A_Raise
Loop
Fire:
TUCA A 0 A_JumpIfInventory("TurboCarFlag",1,"AltfireHonk")
//TUCA BCDEF 2 //10
TUCA A 0 A_PlaySoundEx("weapon/wheelgogogo","Weapon")
TUCA A 1 Offset(0,60)
TUCA A 1 Offset(0,90)
TNT1 A 1 A_WeaponReady(14)
TUCA CB 2 Offset(0,60)
TUCA IF 1 A_WeaponReady(14)
TNT1 A 0 A_GiveInventory("ShieldCheck",1)
TNT1 A 0 A_SpawnItemEx("TurbomanWheelWarper",0,0,0,0,0,0,0,1)
TNT1 A 0 ACS_ExecuteAlways(CORE_ACS_191,0,APROP_Speed,140,100)//145
Goto FireH
FireH2:
TNT1 A 0 ACS_ExecuteAlways(CORE_ACS_191,0,APROP_Speed,1,1)
TNT1 A 0
goto FireH3
FireH:
TNT1 A 0 A_JumpIfInventory("TurboWheelCount",45,"FireH2")
TNT1 A 0 A_GiveInventory("TurboWheelCount",1)
TNT1 A 1 Offset(0,120)
TNT1 A 0 A_Refire(1)
Goto FireT
TNT1 A 1 Offset(0,120) A_JumpIfInventory("PowerRage_ST",1,"FireH")
TNT1 A 0 A_Refire("FireH")
Goto FireT
FireH3:
TNT1 A 1 Offset(0,120) A_RailWait
TNT1 A 0 A_Refire("FireH3")
Goto FireT

FireT:
TNT1 A 0 ACS_ExecuteAlways(CORE_ACS_191,0,APROP_Speed,1,1)
TNT1 A 0 A_TakeInventory("WheelFrameCheck",99)
TNT1 A 0 A_TakeInventory("ShieldCheck",99)
TNT1 A 0 A_JumpIfInventory("TurboWheelCount",45,"FireT1")
TNT1 A 0 A_TakeInventory("TurboWheelCount",99)
TNT1 A 0 A_PlaySoundEx("weapon/solarshoot","Weapon")
TNT1 A 0 A_GiveInventory("TurbomanMain_CI",1)
//TUCA GH 2 A_ClearRefire
TNT1 A 2 A_ClearRefire
TUCA H 1 Offset(0,80)
TUCA G 1 Offset(0,40)
TUCA A 0 ACS_ExecuteAlways(CORE_ACS_191,0,APROP_Speed,1,1)
Goto Ready0
FireT1:
TNT1 A 0 A_TakeInventory("TurboWheelCount",99)
TNT1 A 0 A_PlaySoundEx("weapon/turbomanthrow","SoundSlot7")
TNT1 A 0 A_GiveInventory("TurbomanMain1_CI",1)
//TUCA GH 2 A_ClearRefire
TNT1 A 2 A_ClearRefire
TUCA H 1 Offset(0,80)
TUCA G 1 Offset(0,40)
TUCA A 0 ACS_ExecuteAlways(CORE_ACS_191,0,APROP_Speed,1,1)
Goto Ready0

Altfire:
TUCA C 0 A_JumpIfInventory("TurboCarFlag",1,"AltfireStop")
//TUCA C 0 A_JumpIf(z-floorz==0,"Altfire2")
//TUCA C 0 SetPlayerProperty(0,0,0)
//Goto Ready0
Altfire2:
//TUCA X 0 A_Stop
TUCA X 0 SetPlayerProperty(0,1,0)
TUCA X 0 A_TakeInventory("TurboNoCarFlag",9)
TUCA X 0 A_GiveInventory("TurboCarFlag",1)
TUCA X 0 ACS_ExecuteAlways(CORE_ACS_191,0,APROP_JumpZ,0,1)
TUCA X 0 A_Refire("Altfire3")
goto Altfire3
Altfire3:
TUCA X 0 A_GiveInventory("CrashDriveAmmo_P",1)
TUCA X 0 A_SpawnItemEx("TurboCarDust_Helper",0,0,0,0,0,0,0,1)
TUCA X 2 A_PlaySoundEx("classes/CarCharge","Weapon")
TUCA X 0 A_Refire(1)
goto AltfireGo
TUCA Y 0 A_GiveInventory("DieselJuiceAmmo",1)
TUCA X 0 A_GiveInventory("CrashDriveAmmo_P",1)
TUCA Y 0 A_SpawnItemEx("TurboCarDust_Helper",0,0,0,0,0,0,0,1)
TUCA Y 2 A_PlaySoundEx("classes/CarCharge","Weapon")
TUCA Y 0 A_Refire("Altfire3")
goto AltfireGo

AltfireGo:
//TNT1 A 0 A_GiveInventory("SelfTotallyUnfrozen",1)
TNT1 A 0 ACS_ExecuteAlways(CORE_ACS_191,0,APROP_JumpZ,7,1)
TNT1 A 0 A_GiveInventory("TurboGoDelay",1)
TNT1 A 0 A_PlaySoundEx("classes/CarGoGo","Body")
TNT1 A 0 A_ChangeVelocity(23,0,momz,3)
TNT1 A 0 A_JumpIfInventory("CrashDriveAmmo",28,"AltfireDrive")
TNT1 A 0 A_GiveInventory("TurboHonkDelayX",1)
goto AltfireDrive
AltfireHonk:
TNT1 A 0 A_GiveInventory("TurboHonkDelay",34)
TNT1 A 0 A_GiveInventory("TurbomanAltX_CI",1)
TNT1 A 0 A_PlaySound("classes/CarHonk",6,0.5)
goto AltfireDrive1
AltfireDrive:
TNT1 A 0 A_GiveInventory("TurbomanBoost",1)
TNT1 A 0 A_TakeInventory("CrashDriveAmmo",2)
TNT1 A 0 A_GiveInventory("TurboCarRadius_Pickup",1)
TNT1 A 0 A_JumpIfInventory("TurboHonkDelayX",1,"AltfireDrive1")
TNT1 A 0 A_JumpIfInventory("TurboHonkDelay",1,"AltfireDrive1")
TNT1 A 0 A_JumpIfInventory("TurboGoDelay",1,"AltfireDrive2")
TUCA X 1 A_WeaponReady(2)
TNT1 A 0 A_GiveInventory("TurboCarRadius_Pickup",1)
TUCA Y 1 A_WeaponReady(2)
TNT1 A 0 A_JumpIfInventory("CrashDriveAmmo",1,"AltfireDrive")
goto AltfireStop
AltfireDrive1://Main
TNT1 A 0 A_JumpIfInventory("TurboGoDelay",1,"AltfireDrive3")
TUCA X 1 A_WeaponReady(6)
TNT1 A 0 A_GiveInventory("TurboCarRadius_Pickup",1)
TUCA Y 1 A_WeaponReady(6)
TNT1 A 0 A_JumpIfInventory("CrashDriveAmmo",1,"AltfireDrive")
goto AltfireStop
AltfireDrive2://Alt
TUCA X 1 A_WeaponReady(10)
TNT1 A 0 A_GiveInventory("TurboCarRadius_Pickup",1)
TUCA Y 1 A_WeaponReady(10)
TNT1 A 0 A_JumpIfInventory("CrashDriveAmmo",1,"AltfireDrive")
goto AltfireStop
AltfireDrive3://Both
TUCA X 1 A_WeaponReady(14)
TNT1 A 0 A_GiveInventory("TurboCarRadius_Pickup",1)
TUCA Y 1 A_WeaponReady(14)
TNT1 A 0 A_JumpIfInventory("CrashDriveAmmo",1,"AltfireDrive")
goto AltfireStop
AltfireStop:
TNT1 A 0 A_GiveInventory("TurboCarEndPickup",1)
TNT1 A 0 ACS_ExecuteAlways(CORE_ACS_191,0,APROP_JumpZ,14,1)
TNT1 A 0 SetPlayerProperty(0,0,0)
//TUCA G 6
//TUCA GG 2 //A_TakeInventory("TurboHonkDelay",999)
//TUCA H 2 A_GiveInventory("TurboNoCarFlag",1)
TNT1 A 6 Offset(0,120)
TNT1 A 4 A_GiveInventory("TurboNoCarFlag",1)
TUCA H 1 Offset(0,80)
TUCA G 1 Offset(0,40)
TUCA H 0 A_GiveInventory("TurboAltDelay",1)
Goto Ready0

NoAmmo:
TUCA A 0
Goto Ready0
}
}

actor DieselJuiceAmmo : Ammo
{
inventory.amount 1
inventory.maxamount 84
+INVENTORY.IGNORESKILL
}

actor CrashDriveAmmo : Ammo
{
inventory.amount 1
inventory.maxamount 112
+INVENTORY.IGNORESKILL
}


actor TurboWheelCount : Inventory
{
inventory.amount 1
inventory.maxamount 45
}

actor TurboCarFlag : Inventory
{
inventory.amount 1
inventory.maxamount 6
}

actor TurboNoCarFlag : OnceC {}

actor TurboCarCount : Inventory
{
inventory.amount 1
inventory.maxamount 56
}

actor TurboHonkDelay : Inventory
{
inventory.amount 1
inventory.maxamount 34
}
actor TurboHonkDelayX : Powerup
{
Powerup.Duration 9
}

actor TurboGoDelay : Powerup
{
Powerup.Duration 10
}
actor TurboAltDelay : Powerup
{
Powerup.Duration 55
}

actor TurboCarRadiusDelay : Powerup
{
+INVENTORY.ADDITIVETIME
Powerup.Duration 2
}

actor TurbomanBoost : CustomInventory
{
States
{
Pickup:
TNT1 A 0 A_JumpIf(z-floorz==0,"Ground")
TNT1 A 0 A_Recoil(-3.15)
stop
Ground:
TNT1 A 0 A_Recoil(-7.5)
stop
}
}

actor CrashDriveAmmo_P : CustomInventory
{
States
{
Pickup:
TNT1 A 0 A_JumpIf(z-floorz==0,"Ground")
TNT1 A 0 A_GiveInventory("CrashDriveAmmo",1)
stop
Ground:
TNT1 A 0 A_GiveInventory("CrashDriveAmmo",2)
TNT1 A 0 A_Stop
stop
}
}

actor TurboCarRadius_Pickup : CustomInventory
{
States
{
Pickup:
TNT1 A 0 A_JumpIfInventory("TurboCarRadiusDelay",1,"No")
TNT1 A 0 A_JumpIfInventory("TurboHonkDelay",1,"Pickup2")
TNT1 A 0 A_SpawnItemEx("TurboCarRadius",0,0,28,momx,momy,momz,0,8)
TNT1 A 0 A_JumpIfInventory("PowerSpread_ST",1,"Pickup_S")
goto End
Pickup_S:
TNT1 AA 0 A_SpawnItemEx("TurboCarRadius",0,0,28,momx,momy,momz,0,8)
goto End

Pickup2:
TNT1 A 0 A_SpawnItemEx("TurboCarRadiusW",0,0,28,momx,momy,momz,0,8)
TNT1 A 0 A_JumpIfInventory("PowerSpread_ST",1,"Pickup2_S")
goto End
Pickup2_S:
TNT1 AA 0 A_SpawnItemEx("TurboCarRadius",0,0,28,momx,momy,momz,0,8)
goto End
End:
TNT1 A 0 A_JumpIfInventory("PowerRage_ST",1,"EndR")
TNT1 A 0 A_GiveInventory("TurboCarRadiusDelay",1)
goto EndR
EndR:
TNT1 A 0 A_GiveInventory("TurboCarRadiusDelay",1)
goto End2
End2:
TNT1 A 0 A_JumpIf(z-floorz==0,"EndX")
goto No
EndX:
TNT1 A 0 A_SpawnItemEx("ScorchWheelB2_BitX",-8,-16,0,0,0,0,0,1)
TNT1 A 0 A_SpawnItemEx("ScorchWheelB2_BitX",-8,16,0,0,0,0,0,1)
TNT1 A 0 A_JumpIfInventory("PowerSpread_ST",1,"EndX_S")
goto No
EndX_S:
TNT1 A 0 A_SpawnItemEx("ScorchWheelB2_BitX",0,0,0,0,0,0,0,1)
TNT1 A 0 A_SpawnItemEx("ScorchWheelB2_BitX",-16,-32,0,0,0,0,0,1)
TNT1 A 0 A_SpawnItemEx("ScorchWheelB2_BitX",-16,32,0,0,0,0,0,1)
goto No

No:
TNT1 A 0 A_TakeInventory("TurboHonkDelay",1)
stop
}
}

actor TurboCarEndPickup : CustomInventory//Fix desync online
{
States
{
Pickup:
TNT1 A 0 A_TakeInventory("CrashDriveAmmo",999)
TNT1 A 0 A_TakeInventory("TurboHonkDelay",999)
TNT1 A 0 A_TakeInventory("TurboCarFlag",999)
TNT1 A 0 A_TakeInventory("TurboCarCount",999)
TNT1 A 0 A_GiveInventory("TurboNoCarFlag",1)
stop
}
}


actor TurbomanWheelWarper : ShieldWarper_CBM
{
Translation "195:195=183:183","194:194=42:42","202:202=248:248"
+NOTIMEFREEZE
+BRIGHT
States
{
Shield:
SCTU A 0 A_JumpIfInventory("Once",1,2)
SCTU A 0 A_JumpIfInTargetInventory("TurboWheelCount",45,"ShieldScale")

SCTU A 0 A_JumpIfInTargetInventory("PowerRage_ST",1,"ShieldR1")
SCTU AAABBBCCC 1 A_Warp(AAPTR_TARGET,0,0,0,0,24)

SCTU D 0 A_JumpIfInventory("Once",1,2)
SCTU D 0 A_JumpIfInTargetInventory("TurboWheelCount",45,"ShieldScale2")

SCTU D 0 A_JumpIfInTargetInventory("PowerRage_ST",1,"ShieldR2")
SCTU DDDEEEFFF 1 A_Warp(AAPTR_TARGET,0,0,0,0,24)
loop
ShieldR1:
SCTU AABBCC 1 A_Warp(AAPTR_TARGET,0,0,0,0,24)
goto Shield+12
ShieldR2:
SCTU DDEEFF 1 A_Warp(AAPTR_TARGET,0,0,0,0,24)
goto Shield
ShieldScale:
SCTU A 0 A_GiveInventory("Once",1)
SCTU A 0 A_SetScale(3.0,3.0)
goto Shield+2
ShieldScale2:
SCTU A 0 A_GiveInventory("Once",1)
SCTU A 0 A_SetScale(3.0,3.0)
goto Shield+14
}
}

actor ScorchWheelB
{
Translation "195:195=183:183","194:194=42:42","202:202=248:248"
damagetype "TurboM_Wheel"
Obituary "$OB_SCORCHWHEEL"
-SOLID
+MISSILE
+RIPPER
-NOGRAVITY
+NOBLOOD
+BRIGHT
maxstepheight 24
painchance 0
reactiontime 10
damage 0
Radius 18
Height 40
speed 16
scale 2.5
States
{
Spawn:
TNT1 A 0
TNT1 A 0 ACS_NamedExecuteAlways("BULL_Tidifier", 0)
SpawnLOOP:
SCTU A 0 ThrustThingZ(0,20,0,1)
SCTU ABCDEF 2 A_SpawnItemEx("ScorchWheelB_Explo",0,0,18)
Goto SpawnLOOP+1
Death:
//TNT1 A 0 A_CustomMissile("ScorchWheelB2",0,0,0,2,0)
TNT1 AA 0 A_SpawnItemEx("ScorchBitB",0,0,0,random(-10,10),random(-10,10),random(10,15),random(0,360),1)
TNT1 A 0 A_SpawnItemEx("ScorchWheelB3",0,0,0,18,0,0,0,1)
TNT1 A 1 A_SpawnItemEx("OilPitIgnite",0,0,8)
stop
}
}

actor ScorchWheelBB : ScorchWheelB{translation "194:194=205:205","195:195=74:74","202:202=196:196"}
actor ScorchWheelBR : ScorchWheelB{translation "194:194=171:171","195:195=41:41","202:202=169:169"}
actor ScorchWheelBO : ScorchWheelB{translation "194:194=104:104","195:195=128:128","202:202=104:104"}
actor ScorchWheelBP : ScorchWheelB{translation "194:194=229:229","195:195=232:232","202:202=229:229"}

actor ScorchWheelB_Explo : BasicExplosion
{
damagetype "TurboM_Wheel"
Obituary "$OB_SCORCHWHEEL"
+EXPLODEONDEATH
Mass 8
States
{
Spawn:
TNT1 A 0
TNT1 A 2 A_Explode(Mass,56,0,0,24)
stop
}
}
actor ScorchWheelB_Explo2 : ScorchWheelB_Explo
{
Mass 9
}
actor ScorchWheelB_Explo3 : ScorchWheelB_Explo
{
Mass 10
}


actor ScorchWheelB1 : ScorchWheelB
{
Speed 22
States
{
Death:
TNT1 A 0 A_PlaySoundEx("weapon/wheeltrail","Body")
TNT1 AA 0 A_SpawnItemEx("ScorchBitB",0,0,0,random(-10,10),random(-10,10),random(10,15),random(0,360),1)
TNT1 A 0 A_SpawnItemEx("ScorchWheelB2",0,0,0,24.75,0,0,0,1)
TNT1 A 1 A_SpawnItemEx("OilPitIgnite",0,0,8)
stop
}
}

actor ScorchWheelB1B : ScorchWheelB1{translation "194:194=205:205","195:195=74:74","202:202=196:196"}
actor ScorchWheelB1R : ScorchWheelB1{translation "194:194=171:171","195:195=41:41","202:202=169:169"}
actor ScorchWheelB1O : ScorchWheelB1{translation "194:194=104:104","195:195=128:128","202:202=104:104"}
actor ScorchWheelB1P : ScorchWheelB1{translation "194:194=229:229","195:195=232:232","202:202=229:229"}

actor ScorchWheelB2 : ScorchWheelB
{
Bouncetype Classic
-BOUNCEONWALLS
-BOUNCEONFLOORS
-BOUNCEONCEILINGS
-ALLOWBOUNCEONACTORS
+DONTSPLASH
+NOEXPLODEFLOOR
+BRIGHT
+STEPMISSILE
BounceFactor 1.0
WallBounceFactor 0.0
States
{
Spawn:
TNT1 A 0
TNT1 A 0 ACS_NamedExecuteAlways("BULL_Tidifier", 0)
SpawnLOOP:
SCTU A 0
SCTU A 0 A_GiveInventory("ResyncPickup",1)
SCTU A 0 A_GiveInventory("ScorchWheelB2Pickup",1)
TNT1 A 0 A_PlaySoundEx("weapon/wheeltrail","Body")
SCTU AA 1 A_CheckFlag("BLASTED","NewShotX")
SCTU B 0 A_GiveInventory("ScorchWheelB2Pickup",1)
SCTU BB 1 A_CheckFlag("BLASTED","NewShotX")
SCTU C 0 A_GiveInventory("ScorchWheelB2Pickup",1)
TNT1 A 0 A_PlaySoundEx("weapon/wheeltrail","Body")
SCTU CC 1 A_CheckFlag("BLASTED","NewShotX")
SCTU D 0 A_GiveInventory("ScorchWheelB2Pickup",1)
SCTU DD 1 A_CheckFlag("BLASTED","NewShotX")
SCTU E 0 A_GiveInventory("ScorchWheelB2Pickup",1)
TNT1 A 0 A_PlaySoundEx("weapon/wheeltrail","Body")
SCTU EE 1 A_CheckFlag("BLASTED","NewShotX")
SCTU F 0 A_GiveInventory("ScorchWheelB2Pickup",1)
SCTU FF 1 A_CheckFlag("BLASTED","NewShotX")
goto SpawnLOOP+2
NewShotX:
TNT1 A 0 A_SpawnItemEx("ScorchWheelB2",0,0,0,momx,momy,momz,0,9)
stop

Death:
TNT1 A 0 A_PlaySoundEx("weapon/wheelbreak","SoundSlot6")
TNT1 AAAA 0 A_SpawnItemEx("ScorchBitB",0,0,0,random(-10,10),random(-10,10),random(10,15),random(0,360),1)
TNT1 A 1 A_SpawnItemEx("OilPitIgnite",0,0,8)
stop
}
}

actor ScorchWheelB3 : ScorchWheelB2
{
States
{
Spawn:
TNT1 A 0
TNT1 A 0 ACS_NamedExecuteAlways("BULL_Tidifier", 0)
SpawnLOOP:
SCTU A 0
SCTU A 0 A_GiveInventory("ResyncPickup",1)
SCTU A 0 A_SpawnItemEx("ScorchWheelB_Explo3",0,0,18)//A_Explode(11,96,0)
TNT1 A 0 A_PlaySoundEx("weapon/wheeltrail","Body")
SCTU AA 1 A_CheckFlag("BLASTED","NewShotX")
SCTU B 0 A_SpawnItemEx("ScorchWheelB_Explo3",0,0,18)
SCTU BB 1 A_CheckFlag("BLASTED","NewShotX")
SCTU C 0 A_SpawnItemEx("ScorchWheelB_Explo3",0,0,18)
SCTU CC 1 A_CheckFlag("BLASTED","NewShotX")
SCTU D 0 A_SpawnItemEx("ScorchWheelB_Explo3",0,0,18)
TNT1 A 0 A_PlaySoundEx("weapon/wheeltrail","Body")
SCTU DD 1 A_CheckFlag("BLASTED","NewShotX")
SCTU E 0 A_SpawnItemEx("ScorchWheelB_Explo3",0,0,18)
SCTU EE 1 A_CheckFlag("BLASTED","NewShotX")
SCTU F 0 A_SpawnItemEx("ScorchWheelB_Explo3",0,0,18)
SCTU FF 1 A_CheckFlag("BLASTED","NewShotX")
goto SpawnLOOP+2
NewShotX:
TNT1 A 0 A_SpawnItemEx("ScorchWheelB3",0,0,0,momx,momy,momz,0,9)
stop
Death:
TNT1 A 0 A_PlaySoundEx("weapon/wheelbreak","SoundSlot6")
TNT1 AAAA 0 A_SpawnItemEx("ScorchBitB",0,0,0,random(-10,10),random(-10,10),random(10,15),random(0,360),1)
TNT1 A 1 A_SpawnItemEx("OilPitIgnite",0,0,8)
stop
}
}


actor ScorchWheelB2Pickup : CustomInventory
{
States
{
Pickup:
TNT1 A 0 A_SpawnItemEx("ScorchWheelB_Explo2",0,0,18)
TNT1 A 0 A_JumpIf(z-floorz==0,"Pickup2")
stop
Pickup2:
TNT1 A 0 A_SpawnItemEx("ScorchWheelB2_Bit",0,0,0,0,0,0,0,1)
stop
}
}

actor ScorchWheelB2_Bit
{
PROJECTILE
damagetype "TurboM_WheelBit"
Obituary "$OB_TURBOSKID"
+DONTBLAST
+FLOORHUGGER
+BRIGHT
reactiontime 10
Damage (5)
Height 16
Radius 18
Speed 0
Scale 2.0
States
{
Spawn:
TNT1 A 0
TNT1 A 0 ACS_NamedExecuteAlways("BULL_Tidifier", 0)
SpawnLOOP:
TNT1 A 0
TNT1 A 0 A_SpawnItemEx("OilPitIgnite",0,0,8)
TUCA RSTU 3
TUCA R 0 A_CountDown
goto SpawnLOOP+2
}
}

actor ScorchWheelB2_BitX : ScorchWheelB2_Bit
{
-FLOORHUGGER
reactiontime 6
Height 12
Radius 12
Scale 1.5
}

actor ScorchBitB : ScorchBit
{
States
{
Spawn:
SCTU O 1
TNT1 A 1
SCTU O 1
TNT1 A 1
SCTU O 1
TNT1 A 1
SCTU O 1
TNT1 A 1
SCTU O 1
TNT1 A 1
SCTU O 1
TNT1 A 1
SCTU O 1
TNT1 A 1
SCTU O 1
TNT1 A 1
SCTU O 1
TNT1 A 1
SCTU O 1
TNT1 A 1
stop
}
}


actor TurboCarDust_Helper : BasicHelper
{
States
{
Spawn:
TNT1 A 0
TNT1 A 0 A_SpawnItemEx("TurboCarDustFX",-2, 24,0,-2,0,0,0,129)
TNT1 A 0 A_SpawnItemEx("TurboCarDustFX",-2,-24,0,-2,0,0,0,129)
TNT1 A 1
stop
}
}

actor TurboCarDustFX : BasicClientSide
{
Scale 1.0
States
{
Spawn:
HSHH P 0
HSHH PQR 5
stop
}
}

actor TurboCarRadius : BasicExplosion
{
Obituary "$OB_TURBORAM"
Damagetype "TurboM_Ram"
States
{
Spawn:
TNT1 A 0
TNT1 A 1 A_Explode(4,128,0,0,24)//8 160
stop
}
}

actor TurboCarRadiusW : BasicExplosion
{
States
{
Spawn:
TNT1 A 0
TNT1 A 1 A_Explode(2,128,0,0,24)
stop
}
}

actor TurboHonkBlast : BasicExplosion
{
Translation "192:192=4:4", "198:198=73:73"
damagetype "TurboM_Honk"
Obituary "$OB_TURBOHONK"
scale 2.5
States
{
Spawn:
TNT1 A 0
TNT1 A 0 A_SpawnItemEx("TurboHonkBlastFX1",0,0,0,0,0,0,0,1)
TNT1 A 0 A_SpawnItemEx("TurboHonkBlastFX2",0,0,0,0,0,0,0,1)
TNT1 A 0 A_Explode(12,272,0,0,64)
X_1G EFGHI 1
TNT1 A 0 A_Explode(12,272,0,0,64)
X_1G JKLMN 1
stop
}
}


actor TurboHonkBlastB : TurboHonkBlast{translation "192:192=205:205", "198:198=74:74"}
actor TurboHonkBlastR : TurboHonkBlast{translation "192:192=171:171", "198:198=41:41"}
actor TurboHonkBlastO : TurboHonkBlast{translation "192:192=104:104", "198:198=128:128"}
actor TurboHonkBlastP : TurboHonkBlast{translation "192:192=229:229", "198:198=232:232"}

actor TurboM_HonkProtect : PowerProtection
{
Powerup.Duration 8
DamageFactor "TurboM_Honk", 0.0
}

actor TurboHonkBlastFX1 : BasicClientSide
{
Scale 2.0
States
{
Spawn:
TNT1 A 1
X_1G EFGHIJKLMN 1
stop
}
}

actor TurboHonkBlastFX2 : BasicClientSide
{
Scale 1.5
States
{
Spawn:
TNT1 A 1
X_1G EFGHIJKLMN 1
stop
}
}


actor TurbomanMain_CI : TeamColor_CI
{
states
{
FireX:
TNT1 A 0 A_FireCustomMissile("ScorchWheelB",0,1,0,0)
goto Done
FireB:
TNT1 A 0 A_FireCustomMissile("ScorchWheelBB",0,1,0,0)
goto Done
FireR:
TNT1 A 0 A_FireCustomMissile("ScorchWheelBR",0,1,0,0)
goto Done
FireO:
TNT1 A 0 A_FireCustomMissile("ScorchWheelBO",0,1,0,0)
goto Done
FireP:
TNT1 A 0 A_FireCustomMissile("ScorchWheelBP",0,1,0,0)
goto Done
}
}

actor TurbomanMain1_CI : TeamColor_CI
{
states
{
FireX:
TNT1 A 0 A_FireCustomMissile("ScorchWheelB1",0,1,0,0)
goto Done
FireB:
TNT1 A 0 A_FireCustomMissile("ScorchWheelB1B",0,1,0,0)
goto Done
FireR:
TNT1 A 0 A_FireCustomMissile("ScorchWheelB1R",0,1,0,0)
goto Done
FireO:
TNT1 A 0 A_FireCustomMissile("ScorchWheelB1O",0,1,0,0)
goto Done
FireP:
TNT1 A 0 A_FireCustomMissile("ScorchWheelB1P",0,1,0,0)
goto Done
}
}

actor TurbomanAltX_CI : TeamColor_CI
{
states
{
FireX:
TNT1 A 0 A_FireCustomMissile("TurboHonkBlast",0,0,0,8)
goto Done
FireB:
TNT1 A 0 A_FireCustomMissile("TurboHonkBlastB",0,0,0,8)
goto Done
FireR:
TNT1 A 0 A_FireCustomMissile("TurboHonkBlastR",0,0,0,8)
goto Done
FireO:
TNT1 A 0 A_FireCustomMissile("TurboHonkBlastO",0,0,0,8)
goto Done
FireP:
TNT1 A 0 A_FireCustomMissile("TurboHonkBlastP",0,0,0,8)
goto Done
}
}