Actor ZSecPistol
{
  obituary "%o was shot by a possessed soldier."
  health 40
  radius 20
  height 56
  mass 100
  speed 4
  painchance 200
  decal bulletchip
  seesound "grunt/sight"
  painsound "grunt/pain"
  deathsound "grunt/death"
  activesound "grunt/active"
  DropItem "GMIDDualPistol"
  PainChance "Fire", 256
  MONSTER
  +FLOORCLIP
  +MISSILEMORE
  +DONTHURTSPECIES
  Tag "ZSec Soldier (Pistol)"
  states
  {
  Spawn:
    ZSC1 AAAAA 10 A_Look
    ZSC1 A 0 A_Jump(8, 2)
    ZSC1 A 0
    Loop
    ZSC1 A 0 A_PlaySound("ZSec/Idle")
    Loop
  See:
    ZSC1 AAAABBBB 1 A_Chase
	ZSC1 C 0 A_PlaySound("Cyber/Hoof", CHAN_BODY)	
	ZSC1 CCCCDDDD 1 A_Chase
	ZSC1 A 0 A_PlaySound("Cyber/Hoof", CHAN_BODY)	
    Goto See
  Missile:
	ZSC1 E 0 A_PlaySound("grunt/prepare", CHAN_VOICE)
    ZSC1 E 10 A_FaceTarget
    ZSC1 F 0 bright A_PlaySound("ZSec/Pistol")
    ZSC1 F 2 bright A_CustomBulletAttack(3, 3, 1, 3, "XaserPuff_NoTaunt")
    ZSC1 E 10 A_FaceTarget
    ZSC1 E 0 A_Jump(128, 2)
    ZSC1 E 4 A_FaceTarget
    ZSC1 E 0 A_Jump(128, 2)
    ZSC1 E 4 A_FaceTarget
    ZSC1 E 0 A_Jump(128, 2)
    ZSC1 E 4 A_FaceTarget
    ZSC1 E 0 A_Jump(128, 2)
    ZSC1 E 0 A_SpidReFire
    Goto Missile+2
    ZSC1 E 0
    Goto See
  Pain:
    ZSC1 G 3
    ZSC1 G 3 A_Pain
    Goto See
  Death:
    ZSC1 G 5
    ZSC1 H 5 A_Scream
    ZSC1 I 5 A_NoBlocking
    ZSC1 JK 5
	ZSC1 L 0 A_PlaySound("body/hitfloor")
	TNT1 A 0 A_Jump(16, "KillTaunt")
    ZSC1 L -1
	Stop
  KillTaunt:
  	TNT1 A 0 A_PlaySound("player/killtaunt", CHAN_AUTO)
    ZSC1 L -1
	Stop
  XDeath:
	TNT1 A 0 A_XScream
	TNT1 A 0 A_NoBlocking
	TNT1 A 0 A_SpawnDebris("SkullGib")
	TNT1 A 0 A_SpawnDebris("DukeGibs1")
	TNT1 A 0 A_SpawnDebris("DukeGibs2")
	TNT1 A 0 A_SpawnDebris("DukeGibs3")
	TNT1 A 0 A_SpawnDebris("GutsGib")
	TNT1 A 0 A_SpawnDebris("DukeGibs5")
	TNT1 A 0 A_SpawnDebris("BloodSplurt")
	TNT1 A 0 A_Jump(16, "GibTaunt")
    Stop
  GibTaunt:
	TNT1 A 0 A_PlaySound("player/gibtaunt", CHAN_AUTO)
	Stop
  Raise:
    ZSC1 LKJIHG 5
    goto See
  Death.Fire:
	ZSC1 G 0 A_NoBlocking
	ZSC1 G 0 A_SpawnItem("BurningBoi")
	TNT1 A -1
	Stop
  }
}