actor G2_Candlestick : G2_BaseTorch replaces Candlestick {
	radius 5
	height 13
	
	States {
		Ignite_Client:
			CAND A 0 A_PlaySound("vile/firestrt", CHAN_7)
		Spawn_Client:
			CAND A 0 A_JumpIf(ACS_NamedExecuteWithResult("g2_torchQuality") == 0, "Spawn_ClientPotato")
			CAND ABAB 8 A_SpawnItemEx("G2_CandleStickFlame", frandom(-0.5, 0.5), frandom(-0.5, 0.5), random(19,20),0,0, 0.25,0, SXF_CLIENTSIDE | SXF_NOCHECKPOSITION | SXF_SETMASTER)
		Spawn_ClientLoop:
			CAND AB 8
			loop
		Spawn_ClientPotato:
			CAND A 0 A_RemoveChildren(true)
		Spawn_ClientPotatoLoop:
			CAND AB 8
			loop
		SpawnDistant_Client:
			CAND A 0 A_RemoveChildren(true)
			CAND A 0 bright A_StopSound(CHAN_6)
			CAND A 0 bright A_StopSound(CHAN_7)
			Goto Spawn_ClientPotato

		Flicker_Client:
			CAND A 0 A_RemoveChildren(true)
			CAND ABCABACABCACABCBACBABCACBCA 1
			loop

		Break_Client:
		Off_Client:
			CAND C 0 A_RemoveChildren(true)
			CAND C 0 A_StopSound(CHAN_6)
			CAND C 0 A_PlaySound("vile/firestrt", CHAN_7)
			CAND C -1
			loop

		On_Client:
			CAND A 0
			goto On_Finish
	}
}

actor G2_CandleStickFlame : G2_RedTorchFlame {
	yscale 0.04
	xscale 0.03
}