actor G2_Ghost {
	MONSTER
	-COUNTKILL
	+GHOST
	+THRUGHOST
	+SLIDESONWALLS
	health 1666
	height 56
	radius 32
	
	species "Ghost"
	+THRUSPECIES

	CameraHeight 46
	
	damagefactor "G2_Weapons", 100.0

	renderstyle translucent
	alpha 1.0

	States {
		Death:
		Death.G2_Weapons:
			TNT1 A 0
			TNT1 A 0 A_NoBlocking
			TNT1 A 0 A_Scream
			TNT1 A 35 A_SpawnItemEx("G2_GoreBlast", 0, 0, 0, velx, vely, velz, 0, SXF_CLIENTSIDE | SXF_ABSOLUTEVELOCITY | SXF_ABSOLUTEANGLE)
			TNT1 A 0 A_GiveToTarget("G2_GhostBuster")
			stop

		Banish:
			TNT1 A 0
			TNT1 A 0 Radius_Quake(4, 8, 0, 2, 0)
			TNT1 A 0 A_PlaySound("Shadow/Teleport", CHAN_7)
			TNT1 A 0 A_PlaySound("Shadow/Teleport", CHAN_6)
			TNT1 A 0 Thing_ChangeTID(0, 0)
			TNT1 AAAAAAAAAAA 0 A_SpawnItemEx("G2_BlackMist", random(-20,20), random(-20,20), random(-5,70), random(-2,2), random(-2,2), random(-2,2))
			TNT1 AAAAAAAAAAA 1 A_SpawnItemEx("G2_BlackMist", random(-20,20), random(-20,20), random(-5,70), random(-2,2), random(-2,2), random(-2,2))
			stop
	}
}

actor G2_BlackMist {
	+CLIENTSIDEONLY
	+NOGRAVITY
	+NOBLOCKMAP
	+THRUACTORS
	+HEXENBOUNCE
	+MISSILE
	damage 0

	renderstyle translucent
	alpha 1.0

	height 2
	radius 2

	States {
		Spawn:
			RSMK BCDC 4 A_FadeOut(0.05)
			loop
	}
}