Actor Daedabus
{
Monster
Health 1000
Radius 48
Height 64
Mass 1000
Speed 8
PainChance 80
BloodColor "73 00 00"
SeeSound "Daedabus/Sight"
PainSound "Daedabus/Pain"
DeathSound "Daedabus/Death"
ActiveSound "Daedabus/Active"
+FLOORCLIP
MaxStepHeight 32
MaxDropOffHeight 168
+DONTHARMSPECIES
+NOINFIGHTING
Damagefactor "HellFire", 0.0
Species "Enemy"
Obituary "%o was torched by a Daedabus."
Dropitem "2CreditDrop"
Dropitem "2CreditDrop"
Dropitem "CreditDrop"
Dropitem "RocketAmmo"
DropItem "RandomPowerup",4,1
States
	{
	Spawn:
		DAED AB 15 A_Look
		Loop
	See:
		DAED AABBCCDDEEFF 4 A_Chase
		Loop
	Pain:
		DAED J 3
		DAED J 3 A_Pain
		Goto See
	Missile:
		DAED F 0 A_Jump(128,"Missile2")
		DAED F 0 A_Jump(255,"Missile3")
	Missile2:
		DAED G 0 A_PlaySound("Daedabus/Attack")
		DAED G 20 A_FaceTarget
		DAED H 0 A_CustomMissile("DaedFire",28,0,frandom(2.75,5.625))
		DAED H 0 A_CustomMissile("DaedFire",28,0,0)
		DAED H 0 A_CustomMissile("DaedFire",28,0,-5.625)
		DAED H 10 Bright
		DAED IG 5 A_FaceTarget
		DAED H 0 A_CustomMissile("DaedFire",28,0,5.625)
		DAED H 0 A_CustomMissile("DaedFire",28,0,0)
		DAED H 0 A_CustomMissile("DaedFire",28,0,frandom(-2.75,-5.625))
		DAED H 10 Bright
		DAED IG 5 A_FaceTarget
		DAED H 0 A_CustomMissile("DaedFire",28,0,11.25)
		DAED H 0 A_CustomMissile("DaedFire",28,0,5.625)
		DAED H 0 A_CustomMissile("DaedFire",28,0,0)
		DAED H 0 A_CustomMissile("DaedFire",28,0,-5.625)
		DAED H 0 A_CustomMissile("DaedFire",28,0,-11.25)
		DAED H 10 Bright
		DAED IG 5 A_FaceTarget
		Goto See
	Missile3:
		DAED G 0 A_PlaySound("Daedabus/Attack")
		DAED G 20 A_FaceTarget
		DAED H 0 A_CustomMissile("DaedFire",28,0,5.625)
		DAED H 0 A_CustomMissile("DaedFire",28,0,0)
		DAED H 0 A_CustomMissile("DaedFire",28,0,frandom(-2.75,-5.625))
		DAED H 10 Bright
		DAED IG 5 A_FaceTarget
		DAED H 0 A_CustomMissile("DaedFire",28,0,frandom(2.75,5.625))
		DAED H 0 A_CustomMissile("DaedFire",28,0,0)
		DAED H 0 A_CustomMissile("DaedFire",28,0,-5.625)
		DAED H 10 Bright
		DAED IG 5 A_FaceTarget
		DAED H 0 A_CustomMissile("DaedFire",28,0,11.25)
		DAED H 0 A_CustomMissile("DaedFire",28,0,5.625)
		DAED H 0 A_CustomMissile("DaedFire",28,0,0)
		DAED H 0 A_CustomMissile("DaedFire",28,0,-5.625)
		DAED H 0 A_CustomMissile("DaedFire",28,0,-11.25)
		DAED H 10 Bright
		DAED IG 5 A_FaceTarget
		Goto See
	Death:
		DAED K 6
		DAED L 6 A_Scream
		DAED M 6 A_NoBlocking
		DAED NOPQRS 6
		DAED T -1 A_BossDeath
		Stop
	Raise:
		DAED RQPONMLK 5
		Goto See
	}
}

ACTOR DaedFire : FatShot
{
Speed 22
Damage 12
Renderstyle Add
Alpha 0.96
Decal Scorch
States
	{
	Spawn:
		DAEF AAAABBBB 1 Bright A_SpawnItemEx("DaedTrail",0,0,0,0,0,0,0,128)
		Loop
	Death:
		DAEF C 8 Bright
		DAEF D 6 Bright
		DAEF E 4 Bright
		Stop
	}
}

Actor DaedTrail
{
+NoInteraction
Scale 0.65
RenderStyle Add
Alpha 0.5
States
	{
	Spawn:
		DAET ABCDE 2 Bright
		Stop
	}
}


Actor Hectebus
{
  Health 1500
  Radius 52
  Height 80
  Scale 1.25
  Speed 12
  PainChance 100
  BloodColor "73 00 00"
  Mass 1500
  SeeSound "Hectebus/Sight"
  PainSound "Hectebus/Pain"
  DeathSound "Hectebus/Death"
  ActiveSound "Hectebus/Active"
  Monster
  MaxStepHeight 32
  MaxDropOffHeight 168
  +DONTHARMSPECIES
  +NOINFIGHTING
  Species "Enemy"
  Damagefactor "HellFire", 0.0
  +FloorClip
  +MissileMore
  Obituary "%o was cremated by a Hectebus."
	Dropitem "2CreditDrop"
	Dropitem "2CreditDrop"
	Dropitem "CreditDrop"
	Dropitem "RocketAmmo"
	DropItem "RandomPowerup",4,1
  States
  {
  Spawn:
    HECT AAAAAAAAAABBBBBBBBBB 1 A_Look
    Loop
  See:
    HECT ABC 6 A_Chase
    HECT D 0 A_PlaySoundEx("Hectebus/Step", "SoundSlot7", 0)
    HECT DEF 6 A_Chase
    HECT A 0 A_PlaySoundEx("Hectebus/Step", "SoundSlot7", 0)
    Loop
  Missile:
    HECT G 0 A_PlaySoundEx("Hectebus/Attack", "SoundSlot6", 0)
    HECT GGGG 4 A_FaceTarget
    HECT G 0 A_Jump(64, "Missile2")
    HECT U 4 Bright A_CustomMissile("Hecteball", 35, 41, 0)
    HECT IGG 4 A_FaceTarget
    HECT K 0 A_SpidReFire
    HECT V 4 Bright A_CustomMissile("Hecteball", 35, -41, 0)
    HECT IGG 4 A_FaceTarget
    HECT K 0 A_Jump(96, 2)
    HECT K 0 A_SpidReFire
    Goto Missile+6
    HECT K 0
    Goto See
  Missile2:
    HECT H 0 Bright A_CustomMissile("Hecteball", 35, 41, Random(-4, 2))
    HECT H 4 Bright A_CustomMissile("Hecteball", 35, -41, Random(-2, 4))
    HECT IGG 4 A_FaceTarget
    HECT H 0 Bright A_CustomMissile("Hecteball", 35, 41, Random(-4, 2))
    HECT H 4 Bright A_CustomMissile("Hecteball", 35, -41, Random(-2, 4))
    HECT IGG 4 A_FaceTarget
    HECT H 0 Bright A_CustomMissile("Hecteball", 35, 41, Random(-4, 2))
    HECT H 4 Bright A_CustomMissile("Hecteball", 35, -41, Random(-2, 4))
    HECT IGG 4 A_FaceTarget
    HECT K 0 A_Jump(200, 2)
    HECT K 0 A_SpidReFire
    Goto Missile2
    HECT K 0
    Goto See
  Pain:
    HECT J 8 A_Pain
    Goto See
  Death:
    HECT K 6 A_Scream
    HECT L 6
    HECT M 6
    HECT N 6 A_Fall
    HECT O 6
    HECT P 6
    HECT Q 6
    HECT R 6
    HECT S 6
    HECT T -1
    Stop
  }
}

Actor Hecteball //Hectebus Fireball
{
  Radius 10
  Height 8
  Speed 20
  Damage 16
  Projectile
  RenderStyle Add
  Alpha 0.97
  SeeSound "Imp/Attack"
  DeathSound "Imp/ShotX"
  Decal Scorch
  States
  {
  Spawn:
    HECF AB 4 Bright
    Loop
  Death:
    HECF CDE 4 Bright
    Stop
  }
}


ACTOR Marrow
{
	Health 600
	Radius 25
	Height 68
	Scale 1.25
	Mass 500
	Speed 10
	PainChance 100
	Monster
	MeleeThreshold 196
	+MISSILEMORE 
	+FLOORCLIP
	+NOINFIGHTING
	Species "Enemy"
	+DONTHARMSPECIES
	MaxStepHeight 36
	MaxDropOffHeight 96
	SeeSound "Skeleton/sight"
	PainSound "Skeleton/pain"
	DeathSound "Skeleton/death"
	ActiveSound "Skeleton/active"
	MeleeSound "Skeleton/melee"
	BloodColor "Black"
	Obituary "%o was spooked by a Marrow."
	Dropitem "2CreditDrop"
	Dropitem "CreditDrop"
	DropItem "RocketAmmo"
	DropItem "RocketAmmo"
	DropItem "RandomPowerup",4,1
	States
	{
	Spawn:
		MARW AB 10 A_Look
		Loop
	See:
		MARW AABBCCDDEEFF 2 A_Chase
		Loop
	Melee:
		MARW G 1 A_FaceTarget
		MARW G 4 A_FaceTarget
		MARW H 4 A_FaceTarget
		MARW I 4 A_CustomMeleeAttack (random (6, 10) * 2,"skeleton/melee","skeleton/swing")
		Goto See
	Missile:
		MARW J 0 BRIGHT A_FaceTarget 
		MARW J 10 BRIGHT A_FaceTarget
		TNT1 A 0 A_CustomMissile("MarrowTracer", 72, 16)
		MARW K 10 A_CustomMissile("MarrowTracer", 72, -16)
		MARW K 10 A_FaceTarget
		Goto See
	Pain:
		MARW L 5
		MARW L 5 A_Pain
		Goto See
	Death:
		MARW LM 7
		MARW N 7 A_Scream
		MARW O 7 A_NoBlocking
		MARW P 7
		MARW Q 5000
		Stop
	Raise:
		MARW Q 5
		MARW PONML 5
		Goto See
	}
}

ACTOR MarrowTracer
{
	Radius 11
	Height 8
	Speed 13 //10 > 13
	Damage 16 //10 > 16
	Projectile 
	+SEEKERMISSILE 
	+RANDOMIZE
	SeeSound "Skeleton/attack"
	DeathSound "Skeleton/tracex"
	States
	{
	Spawn:
		MATB AB 2 BRIGHT A_Tracer
		Loop
	Death:
		MBXP A 8 BRIGHT
		MBXP B 6 BRIGHT
		MBXP C 4 BRIGHT
		Stop
	}
}

ACTOR ShadowCrawler
{
	Game Doom
	Health 900
	Radius 48
	Height 64
	Mass 800
	Speed 12
	Scale 1.1
	PainChance 96
	Monster
	+FLOORCLIP
	-BOSSDEATH
	+NOINFIGHTING
	Species "Enemy"
	+DONTHARMSPECIES
	DamageFactor "HellFire",0.0
	MaxStepHeight 36
	MaxDropOffHeight 96
	SeeSound "baby/sight"
	PainSound "baby/pain"
	DeathSound "baby/death"
	ActiveSound "baby/active"
	Obituary "%o was melted by a Shadow Crawler"
	States
	{
	Spawn:
		SCRW AB 10 A_Look
		Loop
	See:
		SCRW A 10
		SCRW A 3 A_BabyMetal
		SCRW ABBCC 3 A_Chase
		SCRW D 3 A_BabyMetal
		SCRW DEEFF 3 A_Chase
		Goto See+1
	Missile:
		SCRW A 10 BRIGHT A_FaceTarget
		TNT1 A 0 A_Jump(64,"Missile2")
		SCRW G 3 BRIGHT A_CustomMissile("CrawlerPlasma", 32)
		SCRW H 4 BRIGHT
		SCRW H 1 BRIGHT A_SpidRefire
		Goto Missile+1
	Missile2:
		TNT1 G 0 BRIGHT A_CustomMissile("CrawlerPlasma", 32,0,10)
		SCRW G 3 BRIGHT A_CustomMissile("CrawlerPlasma", 32,0,-10)
		SCRW H 4 BRIGHT
		SCRW H 1 BRIGHT A_SpidRefire
		Goto Missile+1
	Pain:
		SCRW I 3
		SCRW I 3 A_Pain
		Goto See+1
	Death:
		SCRW J 20 A_Scream
		SCRW K 7 A_NoBlocking
		SCRW LMNO 7
		SCRW P 5000 A_BossDeath
		Stop
	}
}

ACTOR CrawlerPlasma
{
	Game Doom
	Radius 12
	Height 8
	Speed 30
	Damage 7
	Projectile 
	Scale 0.75
	+RANDOMIZE
	RenderStyle Add 
	Alpha 0.75
	SeeSound "baby/attack"
	DeathSound "baby/shotx"
	States
	{
	Spawn:
		CRPL AB 5 BRIGHT
		Loop
	Death:
		APBX BCDE 5 BRIGHT
		Stop
	}
}