ACTOR StrafeGunner
{
	Game Doom
	Health 1200
	Radius 28
	Height 68
	Mass 100
	Speed 18
	Scale 1.3
	PainChance 30
	Monster
	MaxStepHeight 36
	MaxDropOffHeight 168
	+FLOORCLIP
	+DONTHARMSPECIES
	+NOINFIGHTING
	Species "Enemy"
	DeathSound "UCHAIN/Death"
	AttackSound "chainguy/attack"
	SeeSound "UCHAIN/Sight"
	ActiveSound "UCHAIN/Idle"
	PainSound "UCHAIN/Pain"
	Obituary "You were annihilated by the Strafe Gunner."
	DropItem "AutoRifle"
	Dropitem "ClipBox"
	Dropitem "ClipBox"
	Dropitem "ClipBox"
	Dropitem "5CreditDrop"
	DropItem "Medikit"
	DropItem "Medikit"
	DropItem "SuperArmorBonus"
	DropItem "SuperArmorBonus"
	DropItem "RandomPowerup"
	States
	{
	Spawn:
		UCHW AABB 6 A_Look
		Loop
	See:
		UCHW AAABBBCCCDDD 2 A_Chase
		Loop
	Missile:
		UCHF A 3 A_FaceTarget
		UCHF B 3 BRIGHT A_PlaySound("chainguy/attack", CHAN_WEAPON)
		TNT1 A 0 A_CustomBulletAttack(15.0, 1, 1, random(1,5)*3, "BulletPuff", 0, CBAF_NORANDOM)
		TNT1 A 0 ThrustThing((angle*random(128,256)/180), 10, 0, 0)
		UCHF A 1 A_CPosRefire
		Goto Missile+1
	Pain:
		UCHH A 2 A_Pain
		Goto See
	Death:
		UCD1 A 5 A_Print("The Strafe Gunner anomaly has been slain.")
		UCD1 B 5 A_Scream
		UCD1 C 5 A_NoBlocking
		UCD1 DE 5
		UCD1 F 5000
		Stop
	}
}
ACTOR HOEStrafeGunner : StrafeGunner
{
	DropItem "AutoRifle",128,1
	Dropitem "ClipBox",128,1
	Dropitem "ClipBox",128,1
	Dropitem "ClipBox",128,1
	Dropitem "5CreditDrop"
	DropItem "Medikit",128,1
	DropItem "Medikit",128,1
	DropItem "SuperArmorBonus"
	DropItem "SuperArmorBonus"
	DropItem "RandomPowerup",10,1
	States
	{
	Death:
		UCD1 A 5
		UCD1 B 5 A_Scream
		UCD1 C 5 A_NoBlocking
		UCD1 DE 5
		UCD1 F 5000
		Stop
	}
}
///////REPLACED
ACTOR Chaser
{
	Game Doom
	Health 800
	Radius 24
	Height 64
	Scale 1.2
	Speed 8
	PainChance 50
	Monster
	+FLOORCLIP
	+DONTHARMSPECIES
	+NOINFIGHTING
	Species "Enemy"
	MaxStepHeight 36
	MaxDropOffHeight 180
	MeleeRange 400
	SeeSound "grunt/sight"
	AttackSound "grunt/attack"
	PainSound "grunt/pain"
	DeathSound "grunt/death"
	ActiveSound "grunt/active"
	Obituary "You were gunned down by the Chaser."
	DropItem "AutoRifle"
	Dropitem "ClipBox"
	Dropitem "ClipBox"
	Dropitem "ClipBox"
	Dropitem "5CreditDrop"
	DropItem "Medikit"
	DropItem "Medikit"
	DropItem "SuperHealthBonus"
	DropItem "SuperHealthBonus"
	DropItem "RandomPowerup"
	States
	{
	Spawn:
		STOR AB 10 A_Look
		Loop
	See:
		STOR AABBCCDD 2 A_Chase
		Loop
	Missile:
		STOR E 2 A_FaceTarget
		STOR F 2 A_PosAttack
		STOR E 2 A_JumpIfTargetOutsideMeleeRange("Thrust")
		TNT1 A 0 A_MonsterRefire(128,"Strafe")
		Goto Missile+1
	Strafe:
		TNT1 A 0 ThrustThing((angle*random(128,256)/180), 10, 0, 0)
		Goto See
	Thrust:
		TNT1 A 0 ThrustThing((angle*256/360), 8, 0, 0)
		Goto Missile+3
	Pain:
		STOR G 3
		STOR G 3 A_Pain
		Goto See
	Death:
		STOR H 5 A_Print("The Chaser anomaly has been slain.")
		STOR I 5 A_Scream
		STOR J 5 A_NoBlocking
		STOR K 5
		STOR L 5000
		Stop
	}
}
ACTOR HOEChaser : Chaser
{
	DropItem "AutoRifle"
	Dropitem "ClipBox"
	Dropitem "ClipBox"
	Dropitem "ClipBox"
	Dropitem "5CreditDrop"
	DropItem "Medikit"
	DropItem "Medikit"
	DropItem "SuperHealthBonus"
	DropItem "SuperHealthBonus"
	DropItem "RandomPowerup",10,1
	States
	{
	Death:
		STOR H 5
		STOR I 5 A_Scream
		STOR J 5 A_NoBlocking
		STOR K 5
		STOR L 5000
		Stop
	}
}

ACTOR AutoShotgunner
{
    Health 1000
    Radius 22
    Height 60
	Scale 1.3
    Speed 10
    PainChance 64
    MONSTER
    +FLOORCLIP
	+DONTHARMSPECIES
	+NOINFIGHTING
	Species "Enemy"
	MaxStepHeight 36
	MaxDropOffHeight 180
	+MISSILEMORE
    SeeSound "grunt/sight"
    AttackSound "JACKFIR"
    PainSound "grunt/pain"
    DeathSound "grunt/death"
    ActiveSound "grunt/active"
    Obituary "%o was blasted apart by the Auto Shotgunner."
    DropItem "AutoShotgun"
	Dropitem "ShellBox"
	Dropitem "ShellBox"
	Dropitem "ShellBox"
	Dropitem "5CreditDrop"
	DropItem "Medikit"
	DropItem "Medikit"
	DropItem "RandomPowerup"
    States
    {
    Spawn:
        ASGZ AB 6 A_Look
        Loop
    See:
        ASGZ AABBCCDD 3 A_Chase
        Loop
    Missile:
		ASGZ E 4 A_FaceTarget
		ASGZ E 4 A_FaceTarget
    	TNT1 A 0 Bright A_PlayWeaponSound("JACKFIR")
		ASGZ F 4 Bright A_CustomBulletAttack(10, 0, 7, 5, "Bulletpuff")
		TNT1 A 0 A_Recoil(-2)
		ASGZ E 1 A_CPosRefire
        Goto Missile+1
    Pain:
        ASGZ G 3
        ASGZ G 3 A_Pain
        Goto See
    Death:
        ASGZ H 5 A_Print("The Auto Shotgunner anomaly has been slain.")
        ASGZ I 5 A_Scream
        ASGZ J 5 A_Fall
        ASGZ KLM 5
        ASGZ N 5000
        Stop
    Raise:
        ASGZ NMLKJIH 5
        Goto See
    }
}

ACTOR HOEAutoShotgunner : AutoShotgunner
{
	DropItem "AutoShotgun",128,1
	Dropitem "ShellBox",128,1
	Dropitem "ShellBox",128,1
	Dropitem "ShellBox",128,1
	Dropitem "5CreditDrop"
	DropItem "Medikit",128,1
	DropItem "Medikit",128,1
	DropItem "RandomPowerup",10,1
	States
	{
	Death:
		ASGZ H 5
        ASGZ I 5 A_Scream
        ASGZ J 5 A_Fall
        ASGZ KLM 5
        ASGZ N 5000
        Stop
	}
}

ACTOR CrimsonKnight
{
	Game Doom
	Health 2000
	Radius 30
	Height 50
	Scale 1.25
	Mass 175
	Speed 13
	Painchance 45
	PainThreshold 3
	Monster
	MeleeRange 120
	+FLOORCLIP
	+NoIceDeath
	+DONTHARMSPECIES
	+NOINFIGHTING
	Species "Enemy"
	SeeSound "hknight/sight"
	AttackSound "hknight/attack"
	PainSound "hknight/pain"
	DeathSound "hknight/death"
	ActiveSound "hknight/active"
	Obituary "You were cut down by a crimson knight."
	DropItem "Soulsphere"
	DropItem "SuperArmorBonus"
	DropItem "SuperArmorBonus"
	DropItem "SuperArmorBonus"
	DropItem "SuperArmorBonus"
	Dropitem "5CreditDrop"
	DropItem "RandomPowerup",3,128
	MaxStepHeight 36
	States
	{
	Spawn:
		CRMK AB 10 A_Look
		Loop
	See:
		CRMK A 4 A_Chase
		TNT1 A 0 A_SpawnItem("CrimBlur")
		CRMK B 4 A_Chase
		CRMK C 4 A_Chase
		TNT1 A 0 A_SpawnItem("CrimBlur")
		CRMK D 4 A_Chase
		Loop
	Missile:
		TNT1 A 0 A_JumpIfTargetInsideMeleeRange("Melee")
		CRMK E 0 A_Jump(20,"Missile2")
		CRMK E 0 A_Jump(19,"Missile3")
		CRMK E 0 A_Jump(19,"Missile4")
		CRMK E 0 A_Jump(19,"Distraction")
		CRMK E 11 A_FaceTarget
		CRMK F 9 A_FaceTarget
		CRMK G 9 A_CustomMissile("CrimsonAxeProj",50,15,0,0)
		Goto See
	Missile2:
		CRMK E 8 A_FaceTarget
		CRMK F 6
		CRMK G 6 A_CustomMissile("CrimsonAxeProj",50,15,0,0)
		CRMK G 0 A_CustomMissile("CrimsonAxeProj",50,15,5,5)
		CRMK G 0 A_CustomMissile("CrimsonAxeProj",50,15,10,10)
		Goto See
	Missile3:
		CRMK E 32 A_FaceTarget
		CRMK F 14 A_FaceTarget
		TNT1 A 0 A_CustomMissile("CrimsonAxeProj3",50,15,20,0)
		TNT1 A 0 A_CustomMissile("CrimsonAxeProj3",50,15,-20,0)
		CRMK G 5 A_CustomMissile("CrimsonAxeProj3",50,15,0,0)
		Goto See
	Missile4:
		CRMK E 8 A_FaceTarget
		CRMK F 6
		CRMK G 6 A_CustomMissile("CrimsonAxeProj",50,15,0,0)
		CRMK E 8 A_FaceTarget
		CRMK F 6
		CRMK G 6 A_CustomMissile("CrimsonAxeProj",50,15,-2,0)
		CRMK E 8 A_FaceTarget
		CRMK F 6
		CRMK G 6 A_CustomMissile("CrimsonAxeProj",50,15,1,0)
		Goto See
	Melee:
		CRMK E 8 A_FaceTarget
		CRMK F 6 A_FaceTarget
		CRMK G 6 A_CustomMeleeAttack(25,"FighterAxeHitThing","FighterHammerMiss")
		Goto See
	Pain:
		CRMK H 3 A_TossGib
		CRMK H 3 A_Pain
		TNT1 A 0 A_Jump(84,"Distraction")
		Goto See
	Distraction:
		TNT1 A 0 A_Jump(64,"Distraction2")
		TNT1 A 0 A_Jump(64,"Distraction3")
		TNT1 A 0 A_Jump(64,"Distraction4")
		TNT1 A 0 ThrustThing((angle*256/180), 25, 0, 0)
		TNT1 A 0 A_SpawnItemEx("CrimBlur2",0,0,0,25)
		TNT1 A 0 A_SpawnItemEx("CrimBlur2",0,0,0,-25)
		TNT1 A 0 A_SpawnItemEx("CrimBlur3",0,0,0,0,25)
		TNT1 A 0 A_SpawnItemEx("CrimBlur2",0,0,0,0,-25)
		TNT1 A 0 A_Jump(64,"Distraction")
		Goto See
	Distraction2:
		TNT1 A 0 ThrustThing((angle*256/360), 25, 0, 0)
		TNT1 A 0 A_SpawnItemEx("CrimBlur2",0,0,0,25)
		TNT1 A 0 A_SpawnItemEx("CrimBlur3",0,0,0,-25)
		TNT1 A 0 A_SpawnItemEx("CrimBlur2",0,0,0,0,25)
		TNT1 A 0 A_SpawnItemEx("CrimBlur2",0,0,0,0,-25)
		TNT1 A 0 A_Jump(64,"Distraction")
		Goto See
	Distraction3:
		TNT1 A 0 ThrustThing((angle*256/90), 25, 0, 0)
		TNT1 A 0 A_SpawnItemEx("CrimBlur3",0,0,0,25)
		TNT1 A 0 A_SpawnItemEx("CrimBlur2",0,0,0,-25)
		TNT1 A 0 A_SpawnItemEx("CrimBlur3",0,0,0,0,25)
		TNT1 A 0 A_SpawnItemEx("CrimBlur2",0,0,0,0,-25)
		TNT1 A 0 A_Jump(64,"Distraction")
		Goto See
	Distraction4:
		TNT1 A 0 ThrustThing((angle*256/270), 25, 0, 0)
		TNT1 A 0 A_SpawnItemEx("CrimBlur3",0,0,0,25)
		TNT1 A 0 A_SpawnItemEx("CrimBlur2",0,0,0,-25)
		TNT1 A 0 A_SpawnItemEx("CrimBlur2",0,0,0,0,25)
		TNT1 A 0 A_SpawnItemEx("CrimBlur3",0,0,0,0,-25)
		TNT1 A 0 A_Jump(64,"Distraction")
		Goto See
	Death:
		TNT1 A 0 A_Print("A Crimson Knight has been slain. +82 XP")
		CRMK I 6 A_GiveInventory("XP",82,AAPTR_PLAYER1)
		CRMK J 6 A_Scream
		CRMK K 6
		CRMK L 6 A_NoBlocking
		CRMK MN 6
		CRMK O 5000
		Stop
	Death.NoXp:
		TNT1 A 0
		Stop
	}
}

ACTOR CrimsonAxeProj
{
	Game Heretic
	Radius 10
	Height 8
	Speed 16
	FastSpeed 32
	Damage 11
	Projectile
	-NOBLOCKMAP
	-ACTIVATEIMPACT
	-ACTIVATEPCROSS
	+WINDTHRUST
	+THRUGHOST
	DeathSound "hknight/hit"
	States
	{
	Spawn:
		SPAX A 3 BRIGHT A_PlaySound("hknight/axewhoosh")
		SPAX BC 3 BRIGHT
		SPAX A 3 BRIGHT A_PlaySound("hknight/axewhoosh")
		SPAX BC 3 BRIGHT
		TNT1 A 0 A_CustomMissile("CrimsonAxeProj2",0,0,random(0,360),0)
		Loop
	Death:
		SPAX DEF 6 BRIGHT
		Stop
	}
}

ACTOR CrimsonAxeProj2
{
	Game Heretic
	Radius 10
	Height 8
	Speed 16
	FastSpeed 32
	Damage 10
	Projectile
	Scale 1.0
	-NOBLOCKMAP
	-ACTIVATEIMPACT
	-ACTIVATEPCROSS
	+WINDTHRUST
	+THRUGHOST
	DeathSound "hknight/hit"
	States
	{
	Spawn:
		SPAX A 3 BRIGHT A_PlaySound("hknight/axewhoosh")
		SPAX BC 3 BRIGHT
		Loop
	Death:
		SPAX DEF 6 BRIGHT
		Stop
	}
}

ACTOR CrimsonAxeProj3
{
	Game Heretic
	Radius 10
	Height 8
	Speed 16
	FastSpeed 32
	Damage 3
	Projectile
	-NOBLOCKMAP
	-ACTIVATEIMPACT
	-ACTIVATEPCROSS
	+WINDTHRUST
	+THRUGHOST
	DeathSound "hknight/hit"
	States
	{
	Spawn:
		SPAX A 3 BRIGHT A_PlaySound("hknight/axewhoosh")
		SPAX BC 3 BRIGHT
		SPAX A 3 BRIGHT A_PlaySound("hknight/axewhoosh")
		SPAX BC 3 BRIGHT
		TNT1 A 0 A_CustomMissile("CrimsonOrb",0,0,random(0,360),0)
		Loop
	Death:
		SPAX DEF 6 BRIGHT
		Stop
	}
}

ACTOR CrimBlur
{
	Game Doom
	Scale 1.25
	States
	{
	Spawn:
		CRMK A 1 A_SetTranslucent(0.90, 0)
		CRMK A 1 A_SetTranslucent(0.80, 0)
		CRMK A 1 A_SetTranslucent(0.70, 0)
		CRMK A 1 A_SetTranslucent(0.60, 0)
		CRMK A 1 A_SetTranslucent(0.50, 0)
		CRMK A 1 A_SetTranslucent(0.40, 0)
		CRMK A 1 A_SetTranslucent(0.30, 0)
		CRMK A 1 A_SetTranslucent(0.20, 0)
		CRMK A 1 A_SetTranslucent(0.10, 0)
		CRMK A 1 A_SetTranslucent(0.05, 0)
		Stop
	}
}

ACTOR CrimBlur2
{
	Game Doom
	Scale 1.25
	States
	{
	Spawn:
		CRMK A 32 A_SetTranslucent(0.90, 0)
		CRMK A 6 A_SetTranslucent(0.80, 0)
		CRMK A 6 A_SetTranslucent(0.70, 0)
		CRMK A 6 A_SetTranslucent(0.60, 0)
		CRMK A 6 A_SetTranslucent(0.50, 0)
		CRMK A 6 A_SetTranslucent(0.40, 0)
		CRMK A 6 A_SetTranslucent(0.30, 0)
		CRMK A 6 A_SetTranslucent(0.20, 0)
		CRMK A 6 A_SetTranslucent(0.10, 0)
		CRMK A 6 A_SetTranslucent(0.05, 0)
		Stop
	}
}


ACTOR CrimBlur3
{
	Game Doom
	Scale 1.25
	States
	{
	Spawn:
		CRMK A 32 A_SetTranslucent(0.90, 0)
		CRMK B 6 A_SetTranslucent(0.80, 0)
		CRMK C 6 A_SetTranslucent(0.70, 0)
		CRMK D 6 A_SetTranslucent(0.60, 0)
		CRMK A 6 A_SetTranslucent(0.50, 0)
		CRMK B 6 A_SetTranslucent(0.40, 0)
		CRMK C 6 A_SetTranslucent(0.30, 0)
		CRMK D 6 A_SetTranslucent(0.20, 0)
		CRMK A 6 A_SetTranslucent(0.10, 0)
		CRMK B 6 A_SetTranslucent(0.05, 0)
		Stop
	}
}

ACTOR Apperatus : CyberBaron
{
  obituary "%o was splayed by the Apperatus"
  hitobituary "%o was ripped to shreds by the Apperatus"
  health 3000
  radius 28
  height 56
  Scale 1.2
  mass 1000
  Speed 5
  MaxStepHeight 36
  MaxDropOffHeight 168
  painchance 10
  MeleeDamage 40
  +NOINFIGHTING
	Species "Enemy"
	+DONTHARMSPECIES
  BloodColor "Yellow"
  seesound "cbaron/sight"
  painsound "cbaron/pain"
  deathsound "cbaron/death"
  activesound "cbaron/active"
  Dropitem "GrenadeLauncher"
  Dropitem "RocketBox"
  Dropitem "CellPack"
  Dropitem "5CreditDrop"
  Dropitem "5CreditDrop"
  DropItem "RandomPowerup"
  MONSTER
  +NORADIUSDMG
  +DONTHURTSPECIES
  +BOSS
  states
  {
  Spawn:
    APRT AB 10 A_Look
    loop
  See:
    APRT A 4 A_chase
    APRT A 4 A_chase   
    APRT BB 4 A_chase
    APRT CC 4 A_chase    
    APRT D 4 A_chase
    APRT D 4 A_hoof
    loop
  Melee:
    APRT PQ 3 A_FaceTarget
    APRT R 3 A_BruisAttack
     Goto See
  Missile:
    APRT E 0 A_Jump(80,"Missile2")
    APRT E 5 A_FaceTarget
    APRT F 0 Bright A_CustomMissile("Rocket",32,16,5)
	APRT F 10 Bright A_CustomMissile("Rocket",32,16,-5)
    APRT E 10 A_FaceTarget
	APRT F 0 Bright A_CustomMissile("Rocket",32,16,-0)
	APRT F 10 Bright A_CustomMissile("Rocket",32,16,-15)
    APRT E 10 A_FaceTarget
	APRT F 0 Bright A_CustomMissile("Rocket",32,16,0)
	APRT F 10 Bright A_CustomMissile("Rocket",32,16,15)
    APRT E 10 A_FaceTarget
    Goto See
Missile2:
	APRT PQ 2 A_FaceTarget
    APRT R 5 Bright A_CustomMissile("LOHBall",32,-16,0)
	APRT PQ 5 A_FaceTarget
    APRT R 0 Bright A_CustomMissile("LOHBall",32,-16,0)
	APRT R 0 Bright A_CustomMissile("LOHBall",32,-16,15)
	APRT R 5 Bright A_CustomMissile("LOHBall",32,-16,-15)
    APRT PQ 5 A_FaceTarget
    APRT R 0 Bright A_CustomMissile("LOHBall",32,-16,0)
	APRT R 0 Bright A_CustomMissile("LOHBall",32,-16,15)
	APRT R 0 Bright A_CustomMissile("LOHBall",32,-16,30)
	APRT R 0 Bright A_CustomMissile("LOHBall",32,-16,-30)
	APRT R 5 Bright A_CustomMissile("LOHBall",32,-16,-15)
      Goto See 
	Missile3:
    APRT E 0 A_Jump(80,"Missile2")
    APRT E 5 A_FaceTarget
	APRT F 0 Bright A_CustomMissile("STGrenade",32,16,10)
	APRT F 0 Bright A_CustomMissile("STGrenade",32,16,-10)
    APRT F 0 Bright A_CustomMissile("STGrenade",32,16,5)
	APRT F 5 Bright A_CustomMissile("STGrenade",32,16,-5)
    APRT E 5 A_FaceTarget
	APRT F 0 Bright A_CustomMissile("STGrenade",32,16,-0)
	APRT F 5 Bright A_CustomMissile("STGrenade",32,16,-7.5)
	APRT F 5 Bright A_CustomMissile("STGrenade",32,16,-15)
    APRT E 5 A_FaceTarget
	APRT F 0 Bright A_CustomMissile("STGrenade",32,16,0)
	APRT F 5 Bright A_CustomMissile("STGrenade",32,16,7.5)
	APRT F 5 Bright A_CustomMissile("STGrenade",32,16,15)
    APRT E 5 A_FaceTarget
    Goto See
 Pain:
    APRT H 2
    APRT H 2 A_Pain
    goto See
  Death:
    APRT I 8 A_Print("The Apperatus anomaly has been slain.")
    APRT J 8 A_Scream
    APRT K 8 bright A_Playsound("world/barrelx")
	TNT1 A 0 A_Explode(20,64)
    APRT L 8 bright A_NoBlocking
    APRT M 8 bright
    APRT N 8 bright
    APRT O 10000
    Stop
   }
}   

ACTOR HOEApperatus : Apperatus
{
	DropItem "GrenadeLauncher",128,1
	DropItem "RocketBox"
	DropItem "CellPack"
	DropItem "5CreditDrop"
	DropItem "5CreditDrop"
	DropItem "RandomPowerup",10,1
	States
	{
	Death:
		APRT I 8
		APRT J 8 A_Scream
		APRT K 8 bright A_Playsound("world/barrelx")
		TNT1 A 0 A_Explode(20,64)
		APRT L 8 bright A_NoBlocking
		APRT M 8 bright
		APRT N 8 bright
		APRT O 10000
		Stop
	}
}

Actor Afrit
{
	  Health 3000
	  Speed 6
	  Radius 24
	  Height 72
	  PainChance 50
	  Mass 500
	  SeeSound "AFRTWAKE"
	  PainSound "Baron/Pain"
	  DeathSound "AFRTDIE"
	  ActiveSound "Baron/Active"
		Monster
		+NoGravity
		+NoBlood
		+Float 
		+BOSS
		+NOINFIGHTING
		Species "Enemy"
		+DONTHARMSPECIES
	  Obituary "%o was scorched by an Afrit"
	  HitObituary "%o found the Afrit too hot to handle."
	  Damagefactor "HellFire", 0.0
	  DropItem "5CreditDrop"
	  DropItem "5CreditDrop"
	  DropItem "SuperArmorBonus"
	  DropItem "SuperArmorBonus"
	  DropItem "CellPack"
	  DropItem "SoulSphere"
	  DropItem "RandomPowerup"
  States
  {
  Spawn:
    FRIT A 0
    FRIT A 0 A_CustomMissile("OrbitComet", 44, 0, 0, 2, 0)
    FRIT A 0 A_CustomMissile("OrbitComet2", 44, 0, 180, 2, 0)
    FRIT AABB 3 Bright A_Look
    Goto Spawn+3
  Idle:
    FRIT ABCD 3 Bright A_Look
    Loop
  See:
    FRIT AABBCCDD 2 Bright A_Chase
    Loop
  Melee:
    TNT1 A 0 A_Jump(64, "Melee2")
    FRIT ST 6 Bright A_FaceTarget
	TNT1 A 0 A_Custommissile ("ImmolatorBall", 44, 0, 20)
	TNT1 A 0 A_Custommissile ("ImmolatorBall", 44, 0, -20)
	TNT1 A 0 A_Custommissile ("ImmolatorBall", 84, 0, 0)
	TNT1 A 0 A_Custommissile ("ImmolatorBall", 4, 0, 0)
    FRIT U 6 Bright A_CustomComboAttack("ImmolatorBall", 44, 20, "Baron/Melee")
    Goto See
  Melee2:
    FRIT E 6 Bright A_FaceTarget
    FRIT F 6 Bright A_CustomMissile("HellFire", 44)
    FRIT G 6 Bright A_FaceTarget
    Goto See
  Missile:
    TNT1 A 0 A_Jump(64, "Missile3")
    TNT1 A 0 A_Jump(128, "Missile2")
    FRIT ST 6 Bright A_FaceTarget
    TNT1 A 0 A_Custommissile ("ImmolatorBall", 44, 0, 20)
	TNT1 A 0 A_Custommissile ("ImmolatorBall", 44, 0, -20)
	TNT1 A 0 A_Custommissile ("ImmolatorBall", 84, 0, 0)
	TNT1 A 0 A_Custommissile ("ImmolatorBall", 4, 0, 0)
    FRIT U 6 Bright A_CustomComboAttack("ImmolatorBall", 44, 20, "Baron/Melee")
    Goto See
  Missile2:
    FRIT EF 6 Bright A_FaceTarget
    FRIT G 6 Bright A_CustomMissile("Comet", 44)
    Goto See
  Missile3:
    FRIT E 6 Bright A_FaceTarget
    FRIT F 6 Bright A_CustomMissile("Hellfire", 44)
    FRIT G 6 Bright A_FaceTarget
    Goto See
  Pain:
    FRIT H 4 Bright
    FRIT H 4 Bright A_Pain
    Goto See
  Death:
    TNT1 A 0 A_NoGravity
	TNT1 A 0 A_Print("The Afrit anomaly has been slain.")
    FRIT I 6 Bright A_Scream
    FRIT J 5 Bright A_NoBlocking
    FRIT KLMNOPQR 4 Bright
    Stop
  }
}

ACTOR HOEAfrit : Afrit
{
	DropItem "5CreditDrop"
	DropItem "5CreditDrop"
	DropItem "SuperArmorBonus"
	DropItem "SuperArmorBonus"
	DropItem "CellPack"
	DropItem "SoulSphere"
	DropItem "RandomPowerup",10,1
	States
	{
	Death:
		TNT1 A 0 A_NoGravity
		FRIT I 6 Bright A_Scream
		FRIT J 5 Bright A_NoBlocking
		FRIT KLMNOPQR 4 Bright
		Stop
	}
}

Actor AfritBall
{
  Radius 6
  Height 8
  Speed 20
  Damage 8
  Projectile
  RenderStyle Add
  Alpha 0.8
  SeeSound "Imp/Attack"
  DeathSound "Imp/ShotX"
  Decal BaronScorch
  States
  {
  Spawn:
    FRTM AB 5 Bright
    Loop
  Death:
    FRTM CDE 6 Bright
    Stop
  }
}

Actor Comet
{
  Radius 6
  Height 8
  Speed 20
  Damage 10
  SpawnID 250
  Scale 0.55
  Projectile
  SeeSound "Afrit/CometFire"
  DeathSound "Afrit/CometHit"
  Decal Scorch
  States
  {
  Spawn:
    COMT AAAABBBBCCCC 1 Bright A_SpawnItemEx("CometTail", 0, 0, 0, 0, 0, 0, 0, 128)
    Loop
  Death:
    COMT D 3 Bright A_SpawnItemEx("CometDeathGlow", 0, 0, 0, 0, 0, 0, 0, 128)
    COMT E 3 Bright A_Explode(80, 80, 0)
    TNT1 A 0 A_SpawnItemEx("CometDeath", 0, 0, 0, 0, 0, 0, 0, 128)
    Stop
  }
}

Actor CometTail
{
  Projectile
  +NoClip
  RenderStyle Add
  Alpha 0.4
  States
  {
  Spawn:
    FRTB ABCDEFGHI 1 Bright
    Stop
  }
}

Actor CometDeathGlow : CometTail
{
  Scale 2.0
  Alpha 0.6
  States
  {
  Spawn:
    FRTB ABCDEFGHI 3 Bright
    Stop
  }
}

Actor CometDeath
{
  Projectile
  RenderStyle Add
  +NoClip
  Alpha 0.7
  States
  {
  Spawn:
    COMT FGHI 3 Bright
    Stop
  }
}

Actor OrbitComet : Comet
{
  SeeSound ""
  +NoClip
  Scale 0.28
  Speed 5
  States
  {
  Spawn:
    COMT AABBCC 1 Bright A_SpawnItemEx("OrbitCometTail", 0, 0, 0, 0, 0, 0, 0, 128)
    TNT1 A 0 A_CustomMissile("OrbitComet", 0, 0, 75)
    TNT1 A 0 A_SpawnItemEx("OrbitCometTail", 0, 0, 0, 0, 0, 0, 0, 128)
    Stop
  }
}

Actor OrbitComet2 : OrbitComet
{
  States
  {
  Spawn:
    COMT AABBCC 1 Bright A_SpawnItemEx("OrbitCometTail", 0, 0, 0, 0, 0, 0, 0, 128)
    TNT1 A 0 A_CustomMissile("OrbitComet2", 0, 0, -75)
    TNT1 A 0 A_SpawnItemEx("OrbitCometTail", 0, 0, 0, 0, 0, 0, 0, 128)
    Stop
  }
}

Actor OrbitCometTail : CometTail
{
  Scale 0.5
}

Actor HellFire
{
  +NoBlockMap
  +Painless
  +BloodlessImpact
  +Missile
  +DropOff
  +NOINFIGHTING
  Species "Enemy"
  +DONTHARMSPECIES
  States
  {
  Spawn:
    TNT1 A 1
    Loop
  Death:
    TNT1 A 0 Bright A_CustomMissile("HellFire1", 0, 0, -180)
    TNT1 A 0 Bright A_CustomMissile("HellFire1", 0, 16, -175)
    TNT1 A 0 Bright A_CustomMissile("HellFire1", 0, 32, -170)
    TNT1 A 0 Bright A_CustomMissile("HellFire1", 0, -16, -185)
    TNT1 A 0 Bright A_CustomMissile("HellFire1", 0, -32, -190)
    TNT1 A 10 Bright A_PlaySound("Afrit/Hellfire")
    Stop
  }
}

Actor HellFire1
{
  +Ripper
  +NoExplodeFloor
  +Painless
  +BloodlessImpact
  +Missile
  +DropOff
  Speed 2
  States
  {
  Spawn:
     TNT1 A 10 A_CustomMissile("HellFire2", 0, 0, 0)
     TNT1 A 10 A_CustomMissile("HellFire2", 0, 16, 0)
     TNT1 A 10 A_CustomMissile("HellFire2", 0, -16, 0)
     TNT1 A 10 A_CustomMissile("HellFire2", 0, 0, 0)
     TNT1 A 10 A_CustomMissile("HellFire2", 0, 16, 0)
     TNT1 A 10 A_CustomMissile("HellFire2", 0, -16, 0)
     TNT1 A 10 A_CustomMissile("HellFire2", 0, 0, 0)
     TNT1 A 10 A_CustomMissile("HellFire2", 0, 16, 0)
     TNT1 A 10 A_CustomMissile("HellFire2", 0, -16, 0)
     TNT1 A 10 A_CustomMissile("HellFire2", 0, 0, 0)
     TNT1 A 10 A_CustomMissile("HellFire2", 0, 16, 0)
     TNT1 A 10 A_CustomMissile("HellFire2", 0, -16, 0)
     TNT1 A 10 A_CustomMissile("HellFire2", 0, 0, 0)
     TNT1 A 10 A_CustomMissile("HellFire2", 0, 16, 0)
     TNT1 A 10 A_CustomMissile("HellFire2", 0, -16, 0)
     Stop
  }
}

Actor HellFire2
{
  +Ripper
  +NoExplodeFloor
  +BloodlessImpact
  +DropOff
  +Randomize
  Scale 1.5
  Speed 1
  RenderStyle Add
  Alpha 0.67
  Damagetype "HellFire"
  Obituary "%o was scorched by an Afrit"
  States
  {
  Spawn:
    TNT1 A 8
    FRTF A 3 Bright
    FRTF BC 3 Bright A_Explode(3, 64)
    TNT1 A 0 A_Explode(3, 64)
    TNT1 A 0 A_Jump(191, 4)
    TNT1 A 0 A_CustomMissile("HellFire2", 0, 24, 0)
    TNT1 A 0 A_CustomMissile("HellFire2", 0, 0, 0)
    TNT1 A 0 A_CustomMissile("HellFire2", 0, -24, 0)
    FRTF DEFGHIJKLMNO 3 Bright
    Stop
  }
}

Actor Diabloist : Archvile
{
  Obituary "%o was set ablaze by a Diabloist."
  Health 2000
  Radius 20
  Height 56
  Mass 500
  Speed 15
  PainChance 10
  BloodColor "08 08 08"
  Monster
  +FireResist
  +FloorClip
  +NoTarget
  +NoRadiusDmg
  +MissileMore
  +Boss
  +NOINFIGHTING
	Species "Enemy"
	+DONTHARMSPECIES
	Damagefactor "HellFire", 0.0
	Damagefactor "Enemy", 0.0
  SeeSound "Monster/diasit"
  PainSound "Monster/diapai"
  DeathSound "Monster/diadth"
  ActiveSound "Monster/diaact"
  DropItem "5CreditDrop"
  DropItem "5CreditDrop"
  DropItem "SoulSphere"
  DropItem "SuperHealthBonus"
  DropItem "RandomPowerup"
  States
  {
  Spawn:
    DIAB AB 10 A_Look
    Loop
  See:
    DIAB AABBCCDDEEFF 2 A_Chase
    Loop
  Missile:
    DIAB G 0 Bright A_Jump(128, "Missile2")
    DIAB G 0 Bright A_FaceTarget
    DIAB G 3 Bright A_FaceTarget
    DIAB H 3 Bright A_FaceTarget
    DIAB I 3 A_CustomMissile("DFire", 32, 0, 0)
    DIAB H 3 Bright A_FaceTarget
    DIAB G 3 Bright A_FaceTarget
    DIAB H 3 Bright A_FaceTarget
    DIAB I 3 Bright A_FaceTarget
    DIAB H 3 Bright A_FaceTarget
    DIAB G 3 Bright A_FaceTarget
    DIAB H 3 Bright A_FaceTarget
    DIAB I 3 Bright A_FaceTarget
    DIAB H 3 Bright A_FaceTarget
    DIAB G 3 Bright A_FaceTarget
    DIAB H 3 Bright A_FaceTarget
    DIAB I 3 Bright A_FaceTarget
    DIAB G 3 Bright A_FaceTarget
    DIAB H 3 Bright A_FaceTarget
    DIAB I 3 Bright A_FaceTarget
    DIAB G 0 Bright A_Jump(128, "Missile3")
    Goto See
  Missile2:
    DIAB N 5 Bright A_FaceTarget
    DIAB O 5 Bright A_CustomMissile("DFlare", 40, 0, Random(-4, 4))
    DIAB P 0 Bright A_FaceTarget
    DIAB P 5 Bright A_CustomMissile("DFlare", 40, 0, Random(-4, 4))
    DIAB N 0 Bright A_FaceTarget
    DIAB N 5 Bright A_CustomMissile("DFlare", 40, 0, Random(-4, 4))
    DIAB O 0 Bright A_FaceTarget
    DIAB O 5 Bright A_CustomMissile("DFlare", 40, 0, Random(-4, 4))
    DIAB P 0 Bright A_FaceTarget
    DIAB P 5 Bright A_CustomMissile("DFlare", 40, 0, Random(-4, 4))
    DIAB N 0 Bright A_FaceTarget
    DIAB N 5 Bright A_CustomMissile("DFlare", 40, 0, Random(-4, 4))
    DIAB O 0 Bright A_FaceTarget
    DIAB O 5 Bright A_CustomMissile("DFlare", 40, 0, Random(-4, 4))
    DIAB P 0 Bright A_FaceTarget
    DIAB P 5 Bright A_CustomMissile("DFlare", 40, 0, Random(-4, 4))
    DIAB N 0 Bright A_FaceTarget
    DIAB N 5 Bright A_CustomMissile("DFlare", 40, 0, Random(-4, 4))
    DIAB O 0 Bright A_FaceTarget
    DIAB O 5 Bright A_CustomMissile("DFlare", 40, 0, Random(-4, 4))
    DIAB P 0 Bright A_FaceTarget
    DIAB P 5 Bright A_CustomMissile("DFlare", 40, 0, Random(-4, 4))
    DIAB N 0 Bright A_FaceTarget
    DIAB N 5 Bright A_CustomMissile("DFlare", 40, 0, Random(-4, 4))
    DIAB O 0 Bright A_FaceTarget
    DIAB P 5 Bright
    DIAB P 0 Bright A_Jump(64, "Missile3")
    DIAB P 0 Bright A_Jump(128, "Missile4")
    Goto See
  Missile3:
    DIAB GHIJKLM 5 Bright A_FaceTarget
    DIAB N 5 Bright A_FaceTarget
    DIAB O 1 Bright A_Playsound ("weapons/firbfi")
    DIAB O 4 Bright A_CustomMissile ("DMissile",32,0,0)
    DIAB P 5 Bright
    DIAB P 0 Bright A_Jump (128,1)
    Goto See
  Missile4:
    DIA2 A 8 Bright A_FaceTarget
    DIA2 B 8 Bright A_FaceTarget
    DIA2 C 0 Bright A_CustomMissile ("DTracer",0,-40,0)
    DIA2 C 8 Bright A_CustomMissile ("DTracer",0,40,0)
    Goto See
  Pain:
    DIAB Q 5
    DIAB Q 5 A_Pain
    Goto See
  Death:
    DIAB Q 7 A_Print("The Diabloist anomaly has been slain.")
    DIAB R 7 A_Scream
    DIAB S 7 A_NoBlocking
    DIAB TUVW 7
    DIAB XY 5
    DIAB Z 5000
    Stop
  }
}

ACTOR HOEDiabloist : Diabloist
{
	DropItem "5CreditDrop"
	DropItem "5CreditDrop"
	DropItem "SoulSphere"
	DropItem "SuperHealthBonus"
	DropItem "RandomPowerup",10,1
	States
	{
	Death:
		DIAB Q 7
		DIAB R 7 A_Scream
		DIAB S 7 A_NoBlocking
		DIAB TUVW 7
		DIAB XY 5
		DIAB Z 5
		Stop
	}
}

Actor DFire
{
  Obituary "%o was set ablaze by a Diabloist."
  Radius 0
  Height 1
  Speed 0
  RenderStyle Add
  DamageType Fire
  ALPHA 1.00
  +NoGravity
  +SeekerMissile
  +NoTarget
  +NoDamageThrust
  States
  {
  Spawn:
    HLFR A 2 Bright A_StartFire
    TNT1 A 0 Bright A_Explode(4, 32)
    HLFR B 2 Bright A_Fire
    TNT1 A 0 Bright A_Explode(4, 32)
    HLFR A 2 Bright A_Fire
    TNT1 A 0 Bright A_Explode(4, 32)
    HLFR B 2 Bright A_Fire
    TNT1 A 0 Bright A_Explode(4, 32)
    HLFR C 2 Bright A_FireCrackle
    TNT1 A 0 Bright A_Explode(4, 32)
    HLFR B 2 Bright A_Fire
    TNT1 A 0 Bright A_Explode(5, 32)
    HLFR C 2 Bright A_Fire
    TNT1 A 0 Bright A_Explode(5, 32)
    HLFR B 2 Bright A_Fire
    TNT1 A 0 Bright A_Explode(5, 32)
    HLFR C 2 Bright A_Fire
    TNT1 A 0 Bright A_Explode(5, 32)
    HLFR D 2 Bright A_Fire
    TNT1 A 0 Bright A_Explode(5, 32)
    HLFR C 2 Bright A_Fire
    TNT1 A 0 Bright A_Explode(5, 32)
    HLFR D 2 Bright A_Fire
    TNT1 A 0 Bright A_Explode(5, 32)
    HLFR C 2 Bright A_Fire
    TNT1 A 0 Bright A_Explode(5, 32)
    HLFR D 2 Bright A_Fire
    TNT1 A 0 Bright A_Explode(5, 32)
    HLFR E 2 Bright A_Fire
    TNT1 A 0 Bright A_Explode(5, 32)
    HLFR D 2 Bright A_Fire
    TNT1 A 0 Bright A_Explode(5, 32)
    HLFR E 2 Bright A_Fire
    TNT1 A 0 Bright A_Explode(5, 32)
    HLFR D 2 Bright A_Fire
    TNT1 A 0 Bright A_Explode(4, 32)
    HLFR E 2 Bright A_FireCrackle
    TNT1 A 0 Bright A_Explode(4, 32)
    HLFR F 2 Bright A_Fire
    TNT1 A 0 Bright A_Explode(3, 32)
    HLFR E 2 Bright A_Fire
    TNT1 A 0 Bright A_Explode(3, 32)
    HLFR F 2 Bright A_Fire
    TNT1 A 0 Bright A_Explode(3, 32)
    HLFR E 2 Bright A_Fire
    TNT1 A 0 Bright A_Explode(2, 32)
    HLFR F 2 Bright A_Fire
    TNT1 A 0 Bright A_Explode(2, 32)
    HLFR G 2 Bright A_Fire
    TNT1 A 0 Bright A_Explode(2, 32)
    HLFR H 2 Bright A_Fire
    TNT1 A 0 Bright A_Explode(1, 32)
    HLFR G 2 Bright A_Fire
    TNT1 A 0 Bright A_Explode(1, 32)
    HLFR H 2 Bright A_Fire
    TNT1 A 0 Bright A_Explode(1, 32)
    HLFR G 2 Bright A_Fire
    TNT1 A 0 Bright A_Explode(1, 32)
    HLFR H 2 Bright A_Fire
    Stop
  }
}

ACTOR DFlare
{
  Radius 5
  Height 5
  Speed 25
  Damage 4
  SpawnID 252
  RenderStyle Add
  DamageType Fire
  Alpha 0.85
  Projectile
  +ThruGhost
  Obituary "%o was set ablaze by a Diabloist."
  Seesound "weapons/firmfi"
  DeathSound "weapons/firex4"
  States
  {
  Spawn:
    VBAL AB 3 Bright A_SpawnItemEx("MFlareFX", 0, 0, 0, 0, 0, 0, 0, 128)
    Loop
  Death:
    CBAL CDEFG 3 Bright
    Stop
  }
}

Actor DMissile : CFlameMissile
{
  +ThruGhost
}

Actor DTracer
{
  Radius 5
  Height 5
  Speed 15
  ReactionTime 175
  Damage 10
  DamageType Fire
  RenderStyle Add
  Alpha 0.67
  Projectile
  +SeekerMissile
  +FloorHugger
  +ThruGhost
  -NoGravity
  Obituary "%o was set ablaze by a Diabloist."
  Seesound "weapons/diasht"
  DeathSound "weapons/firex3"
  States
  {
  Spawn:
    TNT1 A 1 Bright A_SeekerMissile(10, 15)
    TNT1 A 0 Bright A_Countdown
    TNT1 A 0 Bright A_SpawnItemEx("DTracerPuff", 0, 0, 0, 0, 0, 0, 0, 128)
    Loop
  Death:
    FTRA K 4 Bright
    FTRA L 4 Bright A_Explode(64, 64)
    FTRA MNO 3 Bright
    Stop
  }
}

Actor MFlareFX
{
  Radius 0
  Height 1
  Speed 0
  Projectile
  RenderStyle Add
  Alpha 0.67
  States
  {
  Spawn:
    FDFX ABCDEF 4 Bright
    Stop
  }
}

Actor DTracerPuff
{
  Radius 1
  Height 1
  Speed 0
  RenderStyle Add
  DamageType Fire
  Alpha 0.67
  Projectile
  +FloorHugger
  -NoGravity
  States
  {
  Spawn:
    FTRA ABCDEFGHIJ 3 Bright A_Explode(4, 8)
    stop
  }
}

Actor DMissileTrail : CFlameFloor
{
  +ThruGhost
}

Actor DMissileCircle : CircleFlame
{
 +ThruGhost
}

//The Overlord
actor OverLord 30134
{
	//$Category Monsters
	Health 4000
	Radius 43
	Height 90
	Mass 1000
	Speed 13
	PainChance 20
	DamageType normal
	MONSTER
	DamageFactor lightning, 0.0
	Obituary "%o was smote by the Overlord."
	HitObituary "The Overlord ate %o for lunch."
	+NOINFIGHTING
	Species "Enemy"
	+DONTHARMSPECIES
	Damagefactor "HellFire", 0.0
	+FLOORCLIP
	+NORADIUSDMG
	+BOSS
	+NOTARGET
	+MISSILEEVENMORE
	+FLOAT
	+NOGRAVITY
	+DONTFALL
	MeleeDamage 20
	MeleeRange 68
	SeeSound "monster/ovlsit"
	PainSound "monster/ovlpai"
	DeathSound "monster/ovldth"
	ActiveSound "monster/ovlact"
	MeleeSound "caco/melee"
	DropItem "5CreditDrop"
	  DropItem "5CreditDrop"
	  DropItem "SoulSphere"
	  DropItem "RandomPowerup",10,1
	  States
  {
  Spawn:
    OVER A 10 A_Look
    loop
  See:
    OVER A 0 A_UnSetInvulnerable
    OVER AABBAACC 3 A_Chase
    OVER A 0 A_Jump(32,"Teleport")
    goto See+1
  Missile:
    OVER D 0 A_Jump(256,"Missile1","Missile2","Missile3")
  Missile1:
    OVER DE 8 A_FaceTarget
    OVER FFFFF 4 bright A_PainAttack("HS")
    goto See
  Missile2:
    OVER GH 8 Bright A_FaceTarget
    OVER H 0 Bright A_JumpIfHealthLower(1500,3)
    OVER H 1 Bright A_PlaySound("weapons/shock")
    OVER H 7 Bright A_CustomMissile("StormShot1",43,0,0,0,0)
    goto See
    OVER H 1 Bright A_PlaySound("weapons/shock")
    OVER H 7 Bright A_CustomMissile("StormShot2",43,0,0,0,0)
    goto See
  Missile3:
    OVER JJJJJJJJ 1 A_FaceTarget
    OVER K 0 Bright A_CustomMissile("HadesBall",92,-40,random(-3,3),0,random(-3,3))
    OVER K 0 Bright A_CustomMissile("HadesBall",8,-40,random(-3,3),0,random(-3,3))
    OVER K 0 Bright A_CustomMissile("HadesBall",92,40,random(-3,3),0,random(-3,3))
    OVER K 0 Bright A_CustomMissile("HadesBall",8,40,random(-3,3),0,random(-3,3))
    OVER K 0 Bright A_CustomMissile("OverBall",54,-50,random(-3,3),0,random(-3,3))
    OVER K 4 Bright A_CustomMissile("OverBall",54,50,random(-3,3),0,random(-3,3))
    OVER J 4 A_SpidRefire
    OVER J 0 A_Jump(32,"See")
    goto Missile3+8
  Melee:
    OVER ADF 5 A_FaceTarget
    OVER E 5 A_MeleeAttack
    goto See
  Pain:
    OVER L 6
    OVER L 6 A_Pain
    OVER L 0 A_Jump(40,"Teleport")
    goto See
  Teleport:
    OVER F 0 A_SetInvulnerable
    OVER F 1 A_PlaySound("monster/heltel")
    OVER F 1 A_SetTranslucent(0.90)
    OVER F 1 A_SetTranslucent(0.80)
    OVER F 1 A_SetTranslucent(0.70)
    OVER F 1 A_SetTranslucent(0.60)
    OVER F 1 A_SetTranslucent(0.50)
    OVER F 1 A_SetTranslucent(0.40)
    OVER F 1 A_SetTranslucent(0.30)
    OVER F 1 A_SetTranslucent(0.20)
    OVER F 1 A_SetTranslucent(0.10)
    OVER F 0 A_Jump(128,25)
    TNT1 AAAAAAAAAAAAAAAAAAAAAAAA 0 A_ExtChase(0,0,1,1)
    TNT1 A 0 A_Jump(128,25)
    TNT1 AAAAAAAAAAAAAAAAAAAAAAAA 0 A_ExtChase(0,0,1,1)
    OVER F 1 A_PlaySound("monster/heltel")
    OVER F 1 A_SetTranslucent(0.10)
    OVER F 1 A_SetTranslucent(0.20)
    OVER F 1 A_SetTranslucent(0.30)
    OVER F 1 A_SetTranslucent(0.40)
    OVER F 1 A_SetTranslucent(0.50)
    OVER F 1 A_SetTranslucent(0.60)
    OVER F 1 A_SetTranslucent(0.70)
    OVER F 1 A_SetTranslucent(0.80)
    OVER F 1 A_SetTranslucent(0.90)
    OVER F 1 A_SetTranslucent(1.0)
    OVER F 0 A_UnSetInvulnerable
    goto See
  Death:
    OVER M 0 bright A_Facetarget
    OVER M 8 bright A_Scream
    OVER NO 8 bright
    OVER PPPPP 0 bright A_CustomMissile("OverFlesh1",random(0,90),random(0,40),random(-180,180),2,random(-15,15))
    OVER PPPPP 0 bright A_CustomMissile("OverFlesh2",random(0,90),random(0,40),random(-180,180),2,random(-15,15))
    OVER PPPPPPPPPP 0 A_CustomMissile("OverFlesh3",random(0,90),random(0,40),random(-180,180),2,random(-15,15))
    OVER PPPPPPPPPP 0 A_CustomMissile("OverFlesh4",random(0,90),random(0,40),random(-180,180),2,random(-15,15))
    OVER PPPPPPPPPP 0 A_CustomMissile("OverFlesh5",random(0,90),random(0,40),random(-180,180),2,random(-15,15))
    OVER PPPPPPPPPP 0 A_CustomMissile("OverFlesh6",random(0,90),random(0,40),random(-180,180),2,random(-15,15))
    OVER P 0 bright A_CustomMissile("OverBigArm1",40,-40,-90,2,random(-1,1))
    OVER P 0 bright A_CustomMissile("OverBigArm2",40,40,90,2,random(-1,1))
    OVER P 0 bright A_CustomMissile("OverSmallArm1",100,-30,-90,2,random(-15,15))
    OVER P 0 bright A_CustomMissile("OverSmallArm1",100,30,90,2,random(-15,15))
    OVER P 0 bright A_CustomMissile("OverSmallArm2",100,-30,-90,2,random(-15,15))
    OVER P 0 bright A_CustomMissile("OverSmallArm2",100,30,90,2,random(-15,15))
    OVER P 0 bright A_CustomMissile("OverHorn1",110,-16,-90,2,random(-15,15))
    OVER P 0 bright A_CustomMissile("OverHorn2",110,16,90,2,random(-15,15))
    OVER PQRSTUV 8 bright
    stop
  }
}

ACTOR OverFlesh1
{
   Speed 8
   Mass 100
   Radius 1
   Height 1
   PROJECTILE
   +THRUGHOST
   +LOWGRAVITY
   -NOGRAVITY
   States
   {
   Spawn:
      OVF1 ACEGIKM 5
      loop
   Death:
      OVF1 O 3
      OVF1 Q 5000
      stop
   }
}

ACTOR OverFlesh2 : OverFlesh1
{
   States
   {
   Spawn:
      OVF1 BDFHJLN 5
      loop
   Death:
      OVF1 P 3
      OVF1 R 5000
      stop
   }
}

ACTOR OverFlesh3 : OverFlesh1
{
   States
   {
   Spawn:
      OVF2 ACEG 5
      loop
   Death:
      OVF2 I 5000
      loop
   }
}

ACTOR OverFlesh4 : OverFlesh1
{
   States
   {
   Spawn:
      OVF2 BDFH 5
      loop
   Death:
      OVF2 J 5000
      loop
   }
}

ACTOR OverFlesh5 : OverFlesh1
{
   States
   {
   Spawn:
      OVF3 ACEGI 5
      loop
   Death:
      OVF3 K 500
      loop
   }
}

ACTOR OverFlesh6 : OverFlesh1
{
   States
   {
   Spawn:
      OVF3 BDFHJ 5
      loop
   Death:
      OVF3 L 5000
      loop
   }
}

ACTOR OverBigArm1 : OverFlesh1
{
   States
   {
   Spawn:
      OVF4 ACEGI 5
      loop
   Death:
      OVF4 K 3
      OVF4 M 5000
      stop
   }
}

ACTOR OverBigArm2 : OverFlesh1
{
   States
   {
   Spawn:
      OVF4 BDFHJ 5
      loop
   Death:
      OVF4 L 3
      OVF4 N 5000
      stop
   }
}

ACTOR OverSmallArm1 : OverFlesh1
{
   States
   {
   Spawn:
      OVF5 ACEG 5
      loop
   Death:
      OVF5 I 5000
      stop
   }
}

ACTOR OverSmallArm2 : OverFlesh1
{
   States
   {
   Spawn:
      OVF5 BDFH 5
      loop
   Death:
      OVF5 J 5000
      stop
   }
}

ACTOR OverHorn1 : OverFlesh1
{
   States
   {
   Spawn:
      OVF6 ACEGI 5
      loop
   Death:
      OVF6 K 5000
      stop
   }
}

ACTOR OverHorn2 : OverFlesh1
{
   States
   {
   Spawn:
      OVF6 BDFHJ 5
      loop
   Death:
      OVF6 L 5000
      stop
   }
}

// [MagicWazard] This projectile is shared with the Hades Elemental
ACTOR HadesBall : CacodemonBall
{
Damage 8
Speed 15
Alpha 0.80
DamageType lightning
+THRUGHOST
+FORCEXYBILLBOARD
SeeSound "Monster/hadtel"
DeathSound "Monster/hadsit"
Decal "CacoScorch"
 states
  {
  Spawn:
    HEFX AB 4 bright
    loop
  Death:
    HEFX CDEEFGH 3 bright
    stop
  }
}

// [MagicWazard] Exploding projectile similar to the HadesBall
ACTOR OverBall
{
   Radius 10
   Height 20
   Speed 15
   Damage 8
   DamageType lightning
   ExplosionDamage 32
   ExplosionRadius 32
   PROJECTILE
   RENDERSTYLE ADD
   ALPHA 0.75
   Translation "192:207=168:191"
   +THRUGHOST
   +FORCEXYBILLBOARD
   DeathSound "weapons/devzap"
   Decal "CacoScorch"
   States
   {
   Spawn:
      AFX1 ABC 1 Bright
      loop
   Death:
      AFX1 DE 4 Bright A_Explode
      AFX1 FGHI 4 bright
      stop
   }
}

// [MagicWazard] Giant ball that spawns smaller projectiles ("StormLite1") from sides
ACTOR StormShot1
{
   Radius 12
   Height 6
   Speed 30
   Damage 50
   PROJECTILE
   RENDERSTYLE ADD
   Alpha 0.80
   Damagetype lightning
   +THRUGHOST
   +NODAMAGETHRUST
   +FORCEXYBILLBOARD
   DeathSound "weapons/devexp"
   States
   {
   Spawn:
      LFX1 STUVW 1 Bright
      LFX1 W 0 Bright A_CustomMissile("StormLite1",0,0,90,6)
      LFX1 W 0 Bright A_CustomMissile("StormLite1",0,0,270,6)
      loop
   Death:
      LFX1 STUVWSTUVWSTUVWSTUVWSTUVWSTUVWSTUVWSTUVWSTUVWSTUVWSTUVWSTUVW 1 Bright A_Explode(16,32,0)
      stop
   }
}

// [MagicWazard] More powerful version of StormShot
ACTOR StormShot2 : StormShot1
{
   Damage 100
   States
   {
   Spawn:
      TNT1 A 2
      LFX2 KLMNO 1 Bright
      LFX2 O 0 Bright A_CustomMissile("StormLite2",0,0,90,6)
      LFX2 O 0 Bright A_CustomMissile("StormLite2",0,0,270,6)
      Goto Spawn+1
   Death:
      LFX2 KLMNO 1 Bright A_Explode(32,64,0)
      LFX2 KKKKKK 0 Bright A_SpawnItemEx("StormBolt",0,0,0,4,0,0,random(0,359),0,0)
      LFX2 LMNO 1 Bright A_Explode(32,64,0)
      stop
   }
}

// [MagicWazard] Note: this actor is unused, though it acts as a parent for the
// "StormBolt" vertical lightning column its sprites do not appear to be used
// anywhere else in the actor...
ACTOR StormStrike1
{
   Radius 16
   Height 1
   Speed 90
   Damage 2
   PROJECTILE
   Damagetype lightning
   RENDERSTYLE ADD
   Alpha 0.75
   +THRUGHOST
   +RIPPER
   +NODAMAGETHRUST
   +STRIFEDAMAGE
   DeathSound "weapons/devzap"
   States
   {
   Spawn:
      LFX1 IJKLM 1 Bright A_Explode(64,64,0)
      loop
   Death:
      LFX1 NOPQR 2 Bright
      stop
   }
}

// [MagicWazard] Vertical lightning column spawned by StormShot2
ACTOR StormBolt : StormStrike1
{
   Speed 4
   Radius 8
   Height 16
   Damage 1
   Damagetype lightning
   SeeSound "weapons/none"
   DeathSound "weapons/gntidl"
   YScale 4.0
   XScale 2.0
   ReactionTime 35
   +FLOORHUGGER
   +HEXENBOUNCE
   -NOGRAVITY
   States
   {
   Spawn:
      LFX2 F 1 Bright A_Explode(16,64,0)
      LFX2 F 0 Bright A_CustomMissile("StormBolt2",16,0,0,6,90)
      LFX2 F 0 ThrustThing(random(0,255),1,0,0)
      LFX2 G 1 Bright A_Explode(16,64,0)
      LFX2 G 0 Bright A_CustomMissile("StormBolt2",16,0,0,6,90)
      LFX2 H 1 Bright A_Explode(16,64,0)
      LFX2 H 0 Bright A_CustomMissile("StormBolt2",16,0,0,6,90)
      LFX2 I 1 Bright A_Explode(16,64,0)
      LFX2 I 0 Bright A_CustomMissile("StormBolt2",16,0,0,6,90)
      LFX2 J 1 Bright A_Explode(16,64,0)
      LFX2 J 0 Bright A_CustomMissile("StormBolt2",16,0,0,6,90)
      LFX2 J 0 Bright A_CountDown
      loop
   Death:
      LFX2 FGHIJ 2 Bright A_Explode(16,64,0)
      stop
   }
}

// [MagicWazard] Invisible sub-projectiles spawned by the lightning column in
// a vertical upwards path
ACTOR StormBolt2 : StormStrike1
{
   Speed 184
   Damage 1
   Height 15
   Radius 8
   Damagetype lightning
   SeeSound "Monster/hadtel"
   DeathSound "Monster/hadsit"
   +RIPPER
   +NOGRAVITY
   States
   {
   Spawn:
      TNT1 A 1 Bright A_Explode(16,64,0)
      loop
   Death:
      TNT1 A 1 Bright
      stop
   }
}

// [MagicWazard] Projectiles spawned from the sides of the large StormShot projectile
ACTOR StormLite1
{
   Radius 6
   Height 12
   Speed 32
   Damage 5
   PROJECTILE
   RENDERSTYLE ADD
   Alpha 0.80
   Damagetype lightning
   DeathSound "weapons/devzap"
   +THRUGHOST
   +RIPPER
   +FORCEXYBILLBOARD
   States
   {
   Spawn:
      DLIT ABC 1 Bright
      Loop
   Death:
      DLIT DEFGHIJKLMNO 1 Bright
      Stop
   }
}

// [MagicWazard] More powerful version of StormLite1
ACTOR StormLite2 : StormLite1
{
   Speed 64
   Damage 10
   States
   {
   Spawn:
      LFX1 XYZ 1 Bright
      Loop
   Death:
      LFX1 STUVW 3 Bright
      Stop
   }
}
//End of Overlord

// [MagicWazard] Notes: some sprites don't appear to be used by any actors. These
// include:
//   LFX1 A - H
//   LFX1 I - R (although they are assigned to an unused actor)
// It looks like you can delete these if you wish and it won't hurt anything.


//Hades Sphere
ACTOR HS 30116
{
  //$Title "Hades Sphere"
  //$Category Monsters
  Health 35
  Radius 24
  Height 48
  Mass 3000
  Speed 10
  Obituary "%o was blown away by a Hades Sphere."
  Monster
  SeeSound "monster/hadsit"
  DeathSound "monster/hadexp"
  +LOOKALLAROUND
  +DONTGIB
  +NOTARGET
  +NOGRAVITY
  +FLOAT
  +DONTFALL
  //+DONTHARMCLASS // [MagicWazard] See "notes" below
  States
  {
  Spawn:
    TNT1 A 1 Bright A_Look
    Loop
  See:
    HADE EFGH 4 Bright
  SeeLoop:
    HADE A 2 Bright A_Playsound("monster/hadwlk")
    HADE ABBCCDD 2 Bright A_GiveInventory("HS_SpecialChase", 1) // [Blue Shadow] Conditional A_Chase
    TNT1 A 0 A_CheckFlag("SKULLFLY", "SeeLoop") // [Blue Shadow] Don't bother trying to teleport out while "skull-flying"
    TNT1 A 0 A_Jump(32, "TeleportOut")
    Loop
  TeleportOut:
    TNT1 A 0 A_UnSetSolid
    TNT1 A 0 A_UnSetShootable
    HADE H 5 Bright A_Playsound("monster/hadtel")
    HADE GFEIJKL 4 Bright
  SeeTeleport:
    TNT1 AAAAAAAA 2 A_Chase(0)
    TNT1 A 0 A_Jump(96, "TeleportIn")
    Loop
  TeleportIn:
    HADE L 3 Bright A_Playsound("monster/hadtel")
    HADE KJIEFG 4 Bright
    TNT1 A 0 A_SetShootable
    TNT1 A 0 A_SetSolid
    Goto SeeLoop
  Melee:
    TNT1 A 0 A_SetInvulnerable
    HADE HGFE 4 Bright
    TNT1 A 0 A_UnSetInvulnerable
    TNT1 A 0 A_SetShootable
    TNT1 A 0 A_Die
    Stop
  Death:
    TNT1 A 0 A_NoBlocking
	TNT1 A 0 A_SetTranslucent(0.9, 1)
	TNT1 A 0 A_Scream
	HADE M 4 Bright A_Explode(112, 112, XF_NOTMISSILE)
    HADE NOPQ 5 Bright
    Stop
  XDeath:
    TNT1 A 0 A_Noblocking
    HADE H 5 Bright A_PlaySound("monster/haddth")
    HADE GFE 4 Bright
    HADE RSTUVWX 4 Bright
    Stop
  Death.Ice:
    "####" "#" 0 A_ChangeFlag("NOGRAVITY", FALSE)
    Goto GenericFreezeDeath
  }
}

// [MagicWazard] NOTES: +DONTHARMCLASS was originally enabled, but HS were still
// able to damage each other with self-destructs due to way the self-destruct
// was coded. Now that the self-destruct code has been changed, they are
// invulnerable to each others' explosions if that flag is enabled. Keep
// +DONTHARMCLASS disabled if you want the HS to be vunlerable to each others'
// explosions! Remove the comments and enable the flag if you want the HS to be
// immune to other HS' self-destruct damage.


// [Blue Shadow] Depending on whether or not the Hades Sphere is currently flying
// (due to A_SkullAttack), choose the appropriate "chase mode".
ACTOR HS_SpecialChase : CustomInventory
{
  States
  {
  Pickup:
    TNT1 A 0 A_CheckFlag("SKULLFLY", "ThrustChase")
    TNT1 A 0 A_Chase
    Stop
  ThrustChase:
    TNT1 A 0 A_Chase("", "")
    Stop
  }
}
//End of Hades Sphere

ACTOR Arachnophyte //Modified by michael9r9r
{
    //$Category monsters
    Health 3000
    Radius 48
    Height 72
    Speed 6
    PainChance 15
    Mass 5000
    MONSTER 
    +NoGravity
    +FloatBob
    +Float
    +NoRadiusDMG
    +FireResist
	+BOSS
	+BOSSDEATH
	+NOINFIGHTING
	Species "Enemy"
	+DONTHARMSPECIES
	Damagefactor "HellFire", 0.0
    SEESOUND "arachnophyte/sight"
    PAINSOUND "arachnophyte/pain"
    DEATHSOUND "arachnophyte/death"
    ATTACKSOUND "JACKFIR"
    OBITUARY "%o was perforated by an Arachnophyte."
    ExplosionDamage 128
    ExplosionRadius 255
    Decal Bulletchip
	DropItem "ClipBox"
	DropItem "ShellBox"
	DropItem "5CreditDrop"
	DropItem "5CreditDrop"
	DropItem "SoulSphere"
	DropItem "RandomPowerup"
    states
    {
    Spawn:
        APYT A 0 A_PlaySound("arachnophyte/engine")
        APYT ABABAB 4 A_Look
        Loop
    See:
        APYT A 0 A_PlaySound("arachnophyte/engine")
        APYT AABBAABBAABB 2 A_Chase
        Loop
    Missile:
        APYT A 0 A_PlaySound("arachnophyte/engine")
        APYT BABAB 2 A_FaceTarget
        APYT A 0 A_PlaySound("arachnophyte/engine")
		APYT C 3 bright A_CustomBulletAttack(10, 0, 5, random(1,5)*3, "BulletPuff", 0, CBAF_NORANDOM)
		APYT D 3 bright A_CustomBulletAttack(10, 0, 5, random(1,5)*3, "BulletPuff", 0, CBAF_NORANDOM)
        APYT D 1 A_SpidRefire
        Goto Missile+6
    Pain:
        APYT A 1 A_Pain
        Goto See
    Death:
        APYT A 0 A_PlaySound("spider/death")
        APYT A 4 A_Scream
        APYT B 4 A_Print("The Arachnophyte anomaly has been slain.")
        APYT E 8 
        APYT F 8
        APYT G 6 A_Explode
        APYT H 6 A_Fall
        APYT I 6
        APYT J 6
        Stop
    }
}

ACTOR HOEArachnophyte : Arachnophyte
{
	DropItem "ClipBox"
	DropItem "ShellBox"
	DropItem "5CreditDrop"
	DropItem "5CreditDrop"
	DropItem "SoulSphere"
	DropItem "RandomPowerup",10,1
	States
	{
	Death:
        APYT A 0 A_PlaySound("spider/death")
        APYT A 4 A_Scream
        APYT B 4 
        APYT E 8 
        APYT F 8
        APYT G 6 A_Explode
        APYT H 6 A_Fall
        APYT I 6
        APYT J 6
        Stop
	}
}

Actor DarkCardinal
{
//$Category Realm667 Monsters
//$Sprite CARDA1
//$Title "Dark Cardinal"
Monster
Health 4000
Speed 10
Radius 24
Height 64
PainChance 50
Mass 700
SeeSound "DarkCardinal/sight" //"cyber/sight"
ActiveSound "DarkCardinal/active" //"cyber/active"
PainSound "DarkCardinal/pain" //"brain/pain"
DeathSound "DarkCardinal/death" //"cyber/death"
+BOSS
+NORADIUSDMG
+NOGRAVITY
+FLOAT
+DONTFALL
+FLOATBOB
+MISSILEMORE
+NOINFIGHTING
Species "Enemy"
+DONTHARMSPECIES
Damagefactor "HellFire", 0.0
Damagefactor "Enemy", 0.0
Bloodcolor "Green"
Obituary "%o was blessed by the Dark Cardinal." 
DropItem "CellPack"
DropItem "CellPack"
DropItem "RocketBox"
DropItem "RocketBox"
DropItem "5CreditDrop"
DropItem "5CreditDrop"
DropItem "SoulSphere"
DropItem "RandomPowerup" 
States 
	{ 
	Spawn:
		CARD AB 4 Bright A_Look
		Loop
	See:
		CARD AABB 2 Bright A_Chase 
		loop
	Missile:
		CARD A 0 A_Jump(80,"GrenadeAttack")
		CARD A 0 A_Jump(80,"PlasmaAttack")
		CARD C 4 Bright A_FaceTarget
		CARD D 5 Bright A_CustomMissile("CardinalRocket",42,-30,0)
		CARD C 4 Bright A_FaceTarget
		CARD D 5 Bright A_CustomMissile("CardinalRocket",42,-30,0)
		CARD C 4 Bright
		Goto See
	GrenadeAttack:
		CARD C 8 Bright A_FaceTarget
		CARD D 6 Bright A_CustomMissile("STGrenade",42,-30,0)
		CARD C 8 Bright A_FaceTarget
		TNT1 A 0 A_CustomMissile("STGrenade",42,-30,-10)
		TNT1 A 0 A_CustomMissile("STGrenade",42,-30,10)
		CARD D 6 Bright A_CustomMissile("STGrenade",42,-30,0)
		CARD A 0 A_Jump(64,"GrenadeAttack")
		CARD C 6 Bright
		Goto See
	PlasmaAttack:
		CARD C 4 Bright A_FaceTarget
		CARD D 5 Bright A_CustomMissile("CardinalPlasma",42,-30,0)
		CARD C 4 Bright A_FaceTarget
		CARD D 5 Bright A_CustomMissile("CardinalPlasma",42,-30,0)
		CARD C 4 Bright A_FaceTarget
		CARD D 5 Bright A_CustomMissile("CardinalPlasma",42,-30,0)
		CARD C 4 Bright A_FaceTarget
		CARD D 5 Bright A_CustomMissile("CardinalPlasma",42,-30,0)
		CARD C 4 Bright A_FaceTarget
		CARD D 5 Bright A_CustomMissile("CardinalPlasma",42,-30,0)
		CARD C 4 Bright A_FaceTarget
		CARD D 5 Bright A_CustomMissile("CardinalPlasma",42,-30,0)
		Goto See
	Pain: 
		CARD P 2 Bright A_Stop
		CARD P 0 A_custommissile("DeathBall",42,0,0,2,0)
		CARD P 0 A_custommissile("DeathBall",42,0,20,2,0)
		CARD P 0 A_custommissile("DeathBall",42,0,40,2,0)
		CARD P 0 A_custommissile("DeathBall",42,0,60,2,0)
		CARD P 0 A_custommissile("DeathBall",42,0,80,2,0)
		CARD P 0 A_custommissile("DeathBall",42,0,100,2,0)
		CARD P 0 A_custommissile("DeathBall",42,0,120,2,0)
		CARD P 0 A_custommissile("DeathBall",42,0,140,2,0)
		CARD P 0 A_custommissile("DeathBall",42,0,160,2,0)
		CARD P 0 A_custommissile("DeathBall",42,0,180,2,0)
		CARD P 0 A_custommissile("DeathBall",42,0,200,2,0)
		CARD P 0 A_custommissile("DeathBall",42,0,220,2,0)
		CARD P 0 A_custommissile("DeathBall",42,0,240,2,0)
		CARD P 0 A_custommissile("DeathBall",42,0,260,2,0)
		CARD P 0 A_custommissile("DeathBall",42,0,280,2,0)
		CARD P 0 A_custommissile("DeathBall",42,0,300,2,0)
		CARD P 0 A_custommissile("DeathBall",42,0,320,2,0)
		CARD P 0 A_custommissile("DeathBall",42,0,340,2,0)
		CARD P 4 Bright A_Pain
		Goto See
	Death: 
		CARD E 8 Bright A_ChangeFlag("FLOATBOB",false)
		CARD F 8 Bright A_Scream
		CARD G 8 Bright A_NoBlocking
		CARD H 8 Bright A_Explode
		CARD IJKL 8 Bright
		Stop 
	} 
}
//====================
Actor CardinalRocket
{
Projectile
Radius 11
Height 8
Speed 20
Damage 24
+RANDOMIZE
+DEHEXPLOSION
+ROCKETTRAIL
SeeSound "weapons/rocklf"
DeathSound "weapons/rocklx"
States
	{
	Spawn:
		CROC AB 4 Bright
		Loop
	Death:
		CROC C 8 Bright A_Explode
		CROC D 6 Bright
		CROC E 4 Bright
		Stop
	}
}
//====================
Actor CardinalPlasma  
{
Projectile
Radius 11
Height 8
Speed 20
Damage 16
+FLOATBOB
SeeSound "imp/attack"
DeathSound ""
States
	{
	Spawn:
		CRTA I 1 Bright A_SpawnItemEx("PlasmaTail")
		Loop
	Death:
		TNT1 ABC 4
		Stop
	}
}
//====================
Actor PlasmaTail
{
+NOINTERACTION
+FLOATBOB
Renderstyle Translucent
States
	{
	Spawn:
		CRTA IHGFEDCBABCDEFGHI 2 Bright A_fadeout(0.08)
		Stop
	}
}
//====================
Actor DeathBall : BaronBall
{
Damage 1
+SEEKERMISSILE 
Scale 0.8
SeeSound "DeathBall/spawn"
States
	{
	Spawn:
		TNT1 A 0 A_SpawnItemEx("BallTail")
		BAL7 A 2 Bright A_Tracer
		BAL7 B 2 Bright A_SpawnItemEx("BallTail")
		Loop
	Death:
		BAL7 CDE 6 Bright
		Stop
	}
}
//====================
Actor BallTail
{
+NOINTERACTION
RenderStyle Translucent
Alpha 0.9
Scale 0.6
States
	{
	Spawn:
		BAL7 AABBAABB 2 Bright A_fadeout(0.1)
		Stop
	}
}
