ACTOR NewRebel : Rebel replaces Rebel
{
  +NODAMAGETHRUST
  Species "Player"
  +THRUSPECIES
  +AVOIDMELEE
  Dropitem "None"
  Tag "Rebel"
  States
  {
  Spawn:
    HMN1 P 0
	HMN1 P 0 ACS_NamedExecuteAlways("WOC Monster Init",0,56,0)
  Idle:
	HMN1 P 0 A_CheckFlag("StandStill",2)
	HMN1 P 0 A_Jump(256,5)
	HMN1 P 0 A_Jump(256,1,2,3)
    HMN1 P 5 A_TurretLook
    Loop
    HMN1 Q 8 A_TurretLook
    Loop
    HMN1 R 8 A_TurretLook
    Loop
    HMN1 AA 3 A_Wander
    HMN1 A 0 A_TurretLook
    HMN1 BB 3 A_Wander
    HMN1 B 0 A_TurretLook
    HMN1 CC 3 A_Wander
    HMN1 C 0 A_TurretLook
    HMN1 DD 3 A_Wander
    HMN1 D 0 A_TurretLook
    loop
  See:
    HMN1 AAB 3 A_Chase
	HMN1 B 3 A_FastChase
	HMN1 CCD 3 A_Chase
	HMN1 D 3 A_FastChase
    Loop
  Missile:
    HMN1 E 8 A_FaceTarget
	HMN1 F 0 A_Facetarget
	HMN1 F 0 A_PlaySound ("monsters/rifle", CHAN_WEAPON)
    HMN1 F 3 Bright A_CustomMissile("RebelTracer", 32, 0, frandom(-4,4))
	HMN1 E 0 A_Facetarget
	HMN1 E 0 A_PlaySound ("monsters/rifle", CHAN_WEAPON)
    HMN1 E 3 A_CustomMissile("RebelTracer", 32, 0, frandom(-4,4))
	HMN1 F 0 A_Facetarget
	HMN1 F 0 A_PlaySound ("monsters/rifle", CHAN_WEAPON)
    HMN1 F 3 Bright A_CustomMissile("RebelTracer", 32, 0, frandom(-4,4))
    Goto See
  Pain:
    HMN1 O 3
    HMN1 O 3 A_Pain
    Goto See
  Death:
    HMN1 G 5
    HMN1 H 5 A_Scream
    HMN1 I 3 A_NoBlocking
    HMN1 J 4
    HMN1 KLM 3
    HMN1 N -1
    Stop
  XDeath:
    RGIB A 1 A_SpawnItemEx ("GIB1", 0, 0, random(0,42), 0, 0, random(2,6), random(0,360), 128)
    RGIB A 1 A_SpawnItemEx ("GIB2", 0, 0, random(0,42), 0, 0, random(2,6), random(0,360), 128)
    RGIB A 1 A_SpawnItemEx ("GIB3", 0, 0, random(0,42), 0, 0, random(2,6), random(0,360), 128)
    RGIB A 1 A_SpawnItemEx ("GIB4", 0, 0, random(0,42), 0, 0, random(2,6), random(0,360), 128)
    RGIB B 0 A_SpawnItemEx ("GIB5", 0, 0, random(0,42), 0, 0, random(2,6), random(0,360), 128)
    RGIB B 0 A_SpawnItemEx ("GIB2", 0, 0, random(0,42), 0, 0, random(2,6), random(0,360), 128)
    RGIB B 0 A_SpawnItemEx ("GIB1", 0, 0, random(0,42), 0, 0, random(2,6), random(0,360), 128)
    RGIB B 1 A_XScream
    RGIB C 1 A_SpawnItemEx ("GIB2", 0, 0, random(0,42), 0, 0, random(2,6), random(0,360), 128)
    RGIB C 1 A_SpawnItemEx ("GIB3", 0, 0, random(0,42), 0, 0, random(2,6), random(0,360), 128)
    RGIB C 1 A_NoBlocking
    RGIB D 1 A_SpawnItemEx ("GIB4", 0, 0, random(0,42), 0, 0, random(2,6), random(0,360), 128)
    RGIB D 1 A_SpawnItemEx ("GIB5", 0, 0, random(0,42), 0, 0, random(2,6), random(0,360), 128)
    RGIB D 3
    RGIB E 1 A_SpawnItemEx ("GIB2", 0, 0, random(0,42), 0, 0, random(2,6), random(0,360), 128)
    RGIB E 2
    RGIB F 3
    RGIB G 3
    RGIB H 1400
    stop
  }
}

ACTOR NewRebel1 : NewRebel replaces Rebel1
{
  Game Strife
  ConversationID 43, 42, 43
}

ACTOR NewRebel2 : NewRebel replaces Rebel2
{
  Game Strife
  ConversationID 44, 43, 44
}

ACTOR NewRebel3 : NewRebel replaces Rebel3
{
  Game Strife
  ConversationID 45, 44, 45
}

ACTOR NewRebel4 : NewRebel replaces Rebel4
{
  Game Strife
  ConversationID 46, 45, 56
}

ACTOR NewRebel5 : NewRebel replaces Rebel5
{
  Game Strife
  ConversationID 47, 46, 47
}

ACTOR NewRebel6 : NewRebel replaces Rebel6
{
  Game Strife
  ConversationID 48, 47, 48
}

ACTOR RebelTracer : FastProjectile
{
   Damage (ACS_NamedExecuteWithResult("WOC Monster Damage Scale",WOCTARGET,FRandom(3,6)))
   Damagetype "Physical"
   Radius 1
   Height 1
   Mass 5
   Speed 80
   PROJECTILE
   +BLOODSPLATTER
   +NODAMAGETHRUST
   +MTHRUSPECIES
   Renderstyle Normal
   Alpha 1.0
   decal BulletChip
   States
   {
   Spawn:
      TNT1 A 0 bright
      TNT1 A 0 bright A_SpawnItemEx("ZombieBulletTracerTrail",-15.0,0,0,0,0,0,0,128,0)
      TNT1 A 0 bright A_SpawnItemEx("ZombieBulletTracerTrail",-12.5,0,0,0,0,0,0,128,0)
      TNT1 A 0 bright A_SpawnItemEx("ZombieBulletTracerTrail",-10.0,0,0,0,0,0,0,128,0)
      TNT1 A 0 bright A_SpawnItemEx("ZombieBulletTracerTrail",-7.5,0,0,0,0,0,0,128,0)
      TNT1 A 0 bright A_SpawnItemEx("ZombieBulletTracerTrail",-5.0,0,0,0,0,0,0,128,0)
      TNT1 A 0 bright A_SpawnItemEx("ZombieBulletTracerTrail",-2.5,0,0,0,0,0,0,128,0)
	  TNT1 A 1 bright A_SpawnItemEx("ZombieBulletTracerTrail",0.0,0,0,0,0,0,0,128,0)
      loop
   XDeath:
      TNT1 A 1 //A_SpawnItem("bulletpuff")
      stop
   Death:
   Crash:
      TNT1 A 1 A_SpawnItem("bulletpuff")
      stop
   }
}

ACTOR NewMacil1 : Macil1 replaces Macil1
{
  +BOSS
  +DONTMORPH
  +AVOIDMELEE
  Game Strife
  ConversationID 49, 48, 49
  Health 6000
  Tag "Macil"
  States
  {
  Spawn:
    LEDR C 0
	LEDR C 0 A_GiveInventory("EnemyInDisguise")
	LEDR C 0 ACS_NamedExecuteAlways("WOC Monster Init",0,56,WOC_BOSS)
  Idle:
	LEDR C 0 A_CheckFlag("StandStill",2)
	LEDR C 0 A_Jump(256,5)
	LEDR C 0 A_Jump(256,1,2,3)
    LEDR C 5 A_TurretLook
    Loop
    LEDR A 8 A_TurretLook
    Loop
    LEDR B 8 A_TurretLook
    Loop
    LEDR AA 3 A_Wander
    LEDR A 0 A_TurretLook
    LEDR BB 3 A_Wander
    LEDR B 0 A_TurretLook
    LEDR CC 3 A_Wander
    LEDR C 0 A_TurretLook
    LEDR DD 3 A_Wander
    LEDR D 0 A_TurretLook
	Loop
  See:
    LEAD AABBCCDD 3 A_Chase
    Loop
  Missile:
  Death:
    LEAD E 2 A_FaceTarget
	LEAD F 0 Bright A_Facetarget
	LEAD F 0 Bright A_PlaySound ("monsters/rifle", CHAN_WEAPON)
    LEAD F 2 Bright A_CustomMissile("AcolyteTracer", 32, 0, Frandom(-8,8))
    LEAD E 2 A_SentinelRefire
    Loop
  Pain:
    LEAD Y 3
    LEAD Y 3 A_Pain
    Goto See
  }
}

ACTOR NewMacil2 : NewMacil1 replaces Macil2
{
  Game Strife
  Health 6000
  ConversationID 50, 49, 50
  PainChance 0
  +COUNTKILL
  +NODROPOFF
  -SPECTRAL
  -NODAMAGE
  -FIRERESIST
  +BOSS
  +DONTMORPH
  +AVOIDMELEE
  Tag "$TAG_MACIL2" // "MACIL"
  DeathSound "macil/slop"
  DropItem "None"
  DamageFactor "SpectralLow", 1
  DamageFactor "Fire", 1
  Tag "Macil"
  States
  {
  Spawn:
    LEDR C 0
	LEDR C 0 A_GiveInventory("EnemyInDisguise")
	LEDR C 0 ACS_NamedExecuteAlways("WOC Monster Init",0,56,WOC_BOSS)
  Idle:
	LEDR C 0 A_CheckFlag("StandStill",2)
	LEDR C 0 A_Jump(256,5)
	LEDR C 0 A_Jump(256,1,2,3)
    LEDR C 5 A_TurretLook
    Loop
    LEDR A 8 A_TurretLook
    Loop
    LEDR B 8 A_TurretLook
    Loop
    LEDR AA 3 A_Wander
    LEDR A 0 A_TurretLook
    LEDR BB 3 A_Wander
    LEDR B 0 A_TurretLook
    LEDR CC 3 A_Wander
    LEDR C 0 A_TurretLook
    LEDR DD 3 A_Wander
    LEDR D 0 A_TurretLook
	Loop
  See:
    LEAD A 0 A_TakeInventory("EnemyInDisguise")
    LEAD AA 3 A_Chase
	LEAD BB 3 A_FastChase
	LEAD CC 3 A_Chase
	LEAD DD 3 A_FastChase
    Loop
  Missile:
	LEAD E 0 A_JumpIfCloser(384,2)
	LEAD E 0 A_Jump(256,2)
	LEAD E 0 A_Jump(128, "MiniMissile", "PoisonBolt", "ElectricBolt", "FlameThrower", "Grenades")
    LEAD E 0 A_Jump(128, "MiniMissile", "PoisonBolt", "ElectricBolt")
    LEAD E 4 A_FaceTarget
    LEAD F 0 Bright A_Facetarget
	LEAD F 0 Bright A_PlaySound ("monsters/rifle", CHAN_WEAPON)
    LEAD F 3 Bright A_CustomMissile("AcolyteTracer", 32, 0, FRandom(-5,5))
	LEAD E 0 Bright A_Facetarget
	LEAD E 0 Bright A_PlaySound ("monsters/rifle", CHAN_WEAPON)
    LEAD E 3 Bright A_CustomMissile("AcolyteTracer", 32, 0, FRandom(-5,5))
	LEAD F 0 Bright A_Facetarget
	LEAD F 0 Bright A_PlaySound ("monsters/rifle", CHAN_WEAPON)
    LEAD F 3 Bright A_CustomMissile("AcolyteTracer", 32, 0, FRandom(-5,5))
    LEAD E 0 A_SentinelRefire
    Goto See
  MiniMissile:
    LEAD E 8 A_FaceTarget
	LEAD F 3 Bright A_CustomMissile ("NewMiniMissile", 32, 0, FRandom(-4,4))
	LEAD E 8
	Goto See
  PoisonBolt:
	LEAD E 8 A_FaceTarget
	LEAD E 0 A_PlaySound ("weapons/xbowshoot")
	LEAD E 3 A_CustomMissile ("NewPoisonBolt", 32, 0, FRandom(-4,4))
	Goto See
  ElectricBolt:
	LEAD E 8 A_FaceTarget
	LEAD E 0 A_PlaySound ("weapons/xbowshoot")
	LEAD E 3 A_CustomMissile ("NewElectricBolt", 32, 0, FRandom(-4,4))
	Goto See
  Grenades:
    LEAD E 8 A_FaceTarget
	LEAD F 5 Bright A_CustomMissile ("NewHEGrenade", 32, 0, FRandom(-4,4))
	LEAD E 0 A_FaceTarget
	LEAD F 5 Bright A_CustomMissile ("NewHEGrenade", 32, 0, FRandom(-4,4))
	LEAD E 8
	Goto See
  PhosGrenades:
    LEAD E 8 A_FaceTarget
	LEAD F 5 Bright A_CustomMissile ("NewPhosphorousGrenade", 32, 0, FRandom(-4,4))
	LEAD E 0 A_FaceTarget
	LEAD F 5 Bright A_CustomMissile ("NewPhosphorousGrenade", 32, 0, FRandom(-4,4))
	LEAD E 8
	Goto See
  Flamethrower:
	LEAD E 8 A_FaceTarget
  FlamethrowerFire:
	LEAD F 0 A_FaceTarget
	LEAD F 1 Bright A_CustomMissile ("NewFlameMissile", 32, 0, FRandom(-4,4))
	LEAD E 1
	LEAD F 0 A_MonsterRefire (0, "See")
	LEAD F 0 A_JumpIfCloser (384, "FlamethrowerFire")
	Goto See
  Death:
    LEAD G 0 A_GiveToTarget ("Coin", random(200,400))
    LEAD G 5
    LEAD H 5 A_Scream
    LEAD IJ 4
    LEAD K 3
    LEAD L 3 A_NoBlocking
    LEAD MN 3
	LEAD O 3 A_SpawnItem("GIBBER")
	LEAD PQRSTUV 3
    LEAD W 4 Bright A_SpawnItemEx("AlienSpectre4", 0, 0, 0, 0, 0, random[spectrespawn](0, 255)*0.0078125, 0, SXF_NOCHECKPOSITION)
    LEAD X -1
    Stop
  }
}

ACTOR NewHEGrenade replaces HEGrenade
{
  Game Strife
  ConversationID 106, -1, -1
  Speed 15
  Radius 13
  Height 13
  Mass 20
  Damage (ACS_NamedExecuteWithResult("WOC Monster Damage Scale",WOCTARGET,FRandom(1,4)))
  ReactionTime 30
  Projectile
  -NOGRAVITY
  -STRIFEDAMAGE
  +NODAMAGETHRUST
  +BOUNCEONACTORS
  +EXPLODEONWATER
  Damagetype "Fire"
  MaxStepHeight 4
  BounceType "Doom"
  BounceFactor 0.5
  BounceCount 2
  SeeSound "weapons/hegrenadeshoot"
  DeathSound "weapons/hegrenadebang"
  States
  {
  Spawn:
    GRAP AB 3 A_Countdown
    Loop
  Death:
    BNG4 A 0 Bright A_NoGravity
    BNG4 A 0 Bright A_SetTranslucent(1, 1)
    BNG4 A 2 Bright A_Explode(ACS_NamedExecuteWithResult("WOC Monster Damage Scale",WOCTARGET,192), 192, 0, 0)
    BNG4 BCDEFGHIJKLMN 3 Bright
    Stop
  }
}

ACTOR NewPhosphorousGrenade replaces PhosphorousGrenade
{
  Game Strife
  ConversationID 107, -1, -1
  Speed 15
  Radius 13
  Height 13
  Mass 20
  Damage (ACS_NamedExecuteWithResult("WOC Monster Damage Scale",WOCTARGET,FRandom(1,4)))
  ReactionTime 40
  Projectile
  -NOGRAVITY
  -STRIFEDAMAGE
  +BOUNCEONACTORS
  +EXPLODEONWATER
  BounceType "Doom"
  MaxStepHeight 4
  BounceFactor 0.5
  BounceCount 2
  SeeSound "weapons/phgrenadeshoot"
  DeathSound "weapons/phgrenadebang"
  Damagetype "Fire"
  States
  {
  Spawn:
    GRIN AB 3 A_Countdown
    Loop
  Death:
    BNG3 A 2 A_SpawnItemEx("NewPhosphorousFire")
    Stop
  }
}

ACTOR NewPhosphorousFire : PhosphorousFire replaces PhosphorousFire
{
  Obituary ""
  Damagetype "Fire"
  States
  {
  Spawn:
    BNG3 B 2 Bright A_Explode(ACS_NamedExecuteWithResult("WOC Monster Damage Scale",WOCTARGET,128),128,0)
    BNG3 C 2 Bright A_Countdown
    FLBE A 2 Bright A_Burnination
    FLBE B 2 Bright A_Countdown
    FLBE C 2 Bright A_Explode(ACS_NamedExecuteWithResult("WOC Monster Damage Scale",WOCTARGET,128),128,0)
    FLBE D 3 Bright A_Countdown
    FLBE E 3 Bright A_Explode(ACS_NamedExecuteWithResult("WOC Monster Damage Scale",WOCTARGET,128),128,0)
    FLBE F 3 Bright A_Countdown
    FLBE G 3 Bright A_Burnination
    Goto Spawn+5
  Death:
    FLBE H 2 Bright
    FLBE I 2 Bright A_Burnination
    FLBE JK 2 Bright
    Stop
  }
}

actor WrathOfCronosOracle: Oracle replaces Oracle
{
    ConversationID 65

    +NOICEDEATH
	Tag "Oracle"
    States
    {
      Spawn:
	    ORCL A 0
		ORCL A 0 ACS_NamedExecuteAlways("WOC ORACLE SCRIPT", 0, 0)
        ORCL A 1 A_JumpIf(ACS_NamedExecuteWithResult("WOC SPECTRE KILL", -3) == 1, "Death")
        loop
      
      Death:
        ORCL BCDEFGHIJK 5
        ORCL L 5 A_NoBlocking
        ORCL M 5
        ORCL N 5 ACS_NamedExecuteWithResult("WOC SPECTRE KILL", -1)
        ORCL OP 5
        ORCL Q -1
        stop
    }
}

Actor ProtectedGodMode : Custominventory
{
	Inventory.MaxAmount 0
	+Inventory.AUTOACTIVATE
	states
	{
		Use:
		TNT1 A 0 A_ChangeFlag("NoDamage", 1)
		Stop
	}
}

Actor RemovedGodMode : Custominventory
{
	Inventory.MaxAmount 0
	+Inventory.AUTOACTIVATE
	states
	{
		Use:
		TNT1 A 0 A_ChangeFlag("NoDamage", 0)
		Stop
	}
}