Actor NewAcolyte : Acolyte replaces Acolyte
{
	PainChance "Convert", 255
	+NODAMAGETHRUST
	+AVOIDMELEE
	DropItem "none"
	Tag "Acolyte"
	DamageFactor "Physical", 0.75
	DamageFactor "PhysicalPlayer", 0.75
	States
	{
	Spawn:
		AGRD A 0
		AGRD A 0 ACS_NamedExecuteAlways("WOC Monster Init",0,64,0)
	Idle:
		AGRD A 0 A_CheckFlag("StandStill",2)
		AGRD A 0 A_Jump(256,2)
		AGRD A 5 A_TurretLook
		Loop
		AGRD A 6 A_Wander
		AGRD A 0 A_TurretLook
		AGRD B 6 A_Wander
		AGRD B 0 A_TurretLook
		AGRD C 6 A_Wander
		AGRD C 0 A_TurretLook
		AGRD D 6 A_Wander
		AGRD D 0 A_TurretLook
		Loop
	See:
		AGRD A 6 A_AcolyteBits
		AGRD BCD 6 A_Chase
		Loop
	Missile:
		AGRD E 8 A_FaceTarget
		AGRD F 0 A_Facetarget
		AGRD F 0 A_PlaySound ("monsters/rifle", CHAN_WEAPON)
		AGRD F 0 A_AlertMonsters(1200)
		AGRD F 3 A_CustomMissile("AcolyteTracer", 40, 10, FRandom(-4,4), 1)
		AGRD E 0 A_Facetarget
		AGRD E 0 A_PlaySound ("monsters/rifle", CHAN_WEAPON)
		AGRD F 0 A_AlertMonsters(1200)
		AGRD E 3 A_CustomMissile("AcolyteTracer", 40, 10, FRandom(-4,4), 1)
		AGRD E 0 A_Facetarget
		AGRD E 0 A_PlaySound ("monsters/rifle", CHAN_WEAPON)
		AGRD F 0 A_AlertMonsters(1200)
		AGRD F 6 A_CustomMissile("AcolyteTracer", 40, 10, FRandom(-4,4), 1)
		Goto See
	Pain:
		AGRD O 8 A_Pain
		Goto See
	Death:
		AGRD G 0 A_GiveToTarget ("Coin", random(3,8))
		AGRD G 4
		AGRD H 4 A_Scream
		AGRD I 4
		AGRD J 3
		AGRD K 3 A_NoBlocking
		AGRD L 3
		AGRD M 3 A_AcolyteDie
		AGRD N -1
		Stop
	XDeath:
		AGRD G 0 A_GiveToTarget ("Coin", random(3,8))
		GIBS A 0 A_NoBlocking
		GIBS A 1 A_SpawnItemEx ("GIB1", 0, 0, random(0,42), 0, 0, random(2,6), random(0,360), 128)
		GIBS A 1 A_SpawnItemEx ("GIB2", 0, 0, random(0,42), 0, 0, random(2,6), random(0,360), 128)
		GIBS A 1 A_SpawnItemEx ("GIB3", 0, 0, random(0,42), 0, 0, random(2,6), random(0,360), 128)
		GIBS A 1 A_SpawnItemEx ("GIB4", 0, 0, random(0,42), 0, 0, random(2,6), random(0,360), 128)
		GIBS A 1 A_SpawnItemEx ("GIB5", 0, 0, random(0,42), 0, 0, random(2,6), random(0,360), 128)
		GIBS B 1 A_SpawnItemEx ("GIB2", 0, 0, random(0,42), 0, 0, random(2,6), random(0,360), 128)
		GIBS B 4 A_TossGib
		GIBS C 5 A_TossGib
		GIBS D 4 A_TossGib
		GIBS E 4 A_XScream
		GIBS F 4 A_TossGib
		GIBS GH 4
		GIBS I 5
		GIBS J 5 A_AcolyteDie
		GIBS K 5
		GIBS L 1400
		Stop
	Ice:
		"----" A 0 A_GiveToTarget ("Coin", random(3,8))
		"----" G 5 A_GenericFreezeDeath
		"----" G 1 A_FreezeDeathChunks
		Wait
	Burn:
		BURN A 0 A_GiveToTarget ("Coin", random(3,8))
		BURN A 3 Bright A_PlaySoundEx("human/imonfire", "Voice")
		BURN B 3 Bright A_DropFire
		BURN C 3 Bright A_Wander
		BURN D 3 Bright A_NoBlocking
		BURN E 5 Bright A_DropFire
		BURN FGH 5 Bright A_Wander
		BURN I 5 Bright A_DropFire
		BURN JKL 5 Bright A_Wander
		BURN M 5 Bright A_DropFire
		BURN NOPQPQ 5 Bright
		BURN RSTU 7 Bright
		BURN V -1
		Stop
	Disintegrate:
		DISR A 0 A_GiveToTarget ("Coin", random(3,8))
		DISR A 5 A_PlaySoundEx("misc/disruptordeath", "Voice")
		DISR BC 5
		DISR D 5 A_NoBlocking
		DISR EF 5
		DISR GHIJ 4
		MEAT D 700
		Stop
	}
}

ACTOR NewAcolyteTan : NewAcolyte replaces AcolyteTan
{
  Game Strife
  ConversationID 53, 52, 53
  +MISSILEMORE
  +MISSILEEVENMORE
}

ACTOR NewAcolyteRed : NewAcolyte replaces AcolyteRed
{
	Game Strife
	ConversationID 54, 53, 54
	+MISSILEMORE
	+MISSILEEVENMORE
	Translation 0
	MaxTargetRange 384
	DamageFactor "Fire", 0.5
	DamageFactor "FirePlayer", 0.5
	DamageFactor "FireTime", 0.5
	States
	{
	Missile:
		AGRD F 0 A_JumpIfCloser (384, "Attack")
		Goto See
	Attack:
		AGRD E 8 A_FaceTarget
	Attack2:
		AGRD F 0 A_FaceTarget
		AGRD F 0 A_AlertMonsters(1200)
		AGRD F 1 A_CustomMissile ("NewFlameMissile", 40, 10, FRandom(-4,4), 1)
		AGRD E 1
		AGRD F 0 A_MonsterRefire (0, "See")
		AGRD F 0 A_JumpIfCloser (384, "Attack2")
		Goto See
	}
}

ACTOR NewFlameMissile : FlameMissile replaces FlameMissile
{
	Damage (ACS_NamedExecuteWithResult("WOC Monster Damage Scale",WOCTARGET,FRandom(1,8)))
	-STRIFEDAMAGE
	Damagetype "Fire"
	Speed 35
}

ACTOR NewAcolyteRust : NewAcolyte replaces AcolyteRust
{
	Game Strife
	ConversationID 55, 54, 55
	+MISSILEMORE
	+MISSILEEVENMORE
	Translation 1
	States
	{
	Missile:
		AGRD E 8 A_FaceTarget
		AGRD F 0 A_SpidRefire
		AGRD F 0 A_PlaySound ("monsters/rifle", CHAN_WEAPON)
		AGRD F 0 A_AlertMonsters(1200)
		AGRD F 3 A_CustomMissile("AcolyteTracer", 40, 10, FRandom(-8,8), 1)
		AGRD E 0 A_SpidRefire
		AGRD E 0 A_PlaySound ("monsters/rifle", CHAN_WEAPON)
		AGRD F 0 A_AlertMonsters(1200)
		AGRD E 3 A_CustomMissile("AcolyteTracer", 40, 10, FRandom(-8,8), 1)
		AGRD E 0 A_SpidRefire
		AGRD E 0 A_PlaySound ("monsters/rifle", CHAN_WEAPON)
		AGRD F 0 A_AlertMonsters(1200)
		AGRD F 3 A_CustomMissile("AcolyteTracer", 40, 10, FRandom(-8,8), 1)
		Goto Missile+1
	}
}

ACTOR NewAcolyteGray : NewAcolyte replaces AcolyteGray
{
	Game Strife
	ConversationID 56, 55, 56
	+MISSILEMORE
	+MISSILEEVENMORE
	Translation 2
	DamageFactor "Lightning", 0.5
	DamageFactor "LightningPlayer", 0.5
	DamageFactor "LightningTime", 0.5
	States
	{
	Missile:
		AGRD E 8 A_FaceTarget
		AGRD E 0 A_PlaySound ("weapons/xbowshoot")
		AGRD E 3 A_CustomMissile ("NewElectricBolt", 40, 10, FRandom(-4,4), 1)
		Goto See
	}
}

ACTOR NewAcolyteDGreen : NewAcolyte replaces AcolyteDGreen
{
  Game Strife
  ConversationID 57, 56, 57
  +MISSILEMORE
  +MISSILEEVENMORE
  Translation 3
  States
  {
  Missile:
	AGRD E 8 A_FaceTarget
	AGRD E 0 A_PlaySound ("weapons/xbowshoot")
	AGRD E 3 A_CustomMissile ("NewPoisonBolt", 40, 10, FRandom(-4,4), 1)
	Goto See
  }
}

ACTOR NewAcolyteGold : NewAcolyte replaces AcolyteGold
{
	Game Strife
	ConversationID 58, 57, 58
	+MISSILEMORE
	+MISSILEEVENMORE
	Translation 4
	DamageFactor "Fire", 0.75
	DamageFactor "FirePlayer", 0.75
	DamageFactor "FireTime", 0.75
	States
	{
	Missile:
		AGRD E 8 A_FaceTarget
		AGRD F 0 A_AlertMonsters(1200)
		AGRD F 3 Bright A_CustomMissile ("NewMiniMissile", 40, 10, FRandom(-4,4), 1)
		AGRD E 8
		Goto See
	}
}

ACTOR NewMiniMissile replaces MiniMissile
{
	Game Strife
	ConversationID 99, -1, -1
	Speed 20
	Radius 10
	Height 14
	Damage (ACS_NamedExecuteWithResult("WOC Monster Damage Scale",WOCTARGET,FRandom(15,30)))
	Projectile
	MaxStepHeight 4
	Damagetype "Fire"
	SeeSound "weapons/minimissile"
	DeathSound "weapons/minimissilehit"
	States
	{
	Spawn:
		MICR A 6 Bright A_RocketInFlight
		Loop
	Death:
		SMIS A 0 Bright A_SetTranslucent(1, 1)
		SMIS A 0 Bright// A_StopSoundEx("Voice")
		SMIS A 5 Bright A_Explode((ACS_NamedExecuteWithResult("WOC Monster Damage Scale",WOCTARGET,64)), 64, 0, 1)
		SMIS B 5 Bright
		SMIS C 4 Bright
		SMIS DEFG 2 Bright
		Stop
	}
}

ACTOR NewAcolyteLGreen : NewAcolyte replaces AcolyteLGreen
{
	Game Strife
	+MISSILEMORE
	+MISSILEEVENMORE
	ConversationID 59, -1, -1
	Translation 5
	States
	{
	Missile:
		AGRD E 8 A_FaceTarget
		AGRD E 0 A_PlaySound ("weapons/xbowshoot")
		AGRD E 3 A_CustomMissile ("NewPoisonBolt", 40, 10, FRandom(-4,4), 1)
		Goto See
	}
}

Actor NewPoisonBolt
{
	Speed 30
	Radius 10
	Height 10
	Damage (ACS_NamedExecuteWithResult("WOC Monster Damage Scale",WOCTARGET,10))
	+NODAMAGETHRUST
	+HITTRACER
	Damagetype "Poison"
	Projectile
	MaxStepHeight 4
	SeeSound "misc/swish"
	ActiveSound "misc/swish"
	States
	{
	Spawn:
		ARWP A 10 A_LoopActiveSound
		Loop
	Death:
		AROW A 0 ACS_NamedExecuteWithResult("WOC DAMAGE OVER TIME", ACS_ExecuteWithResult(WOC_DECORATE,STATS,WOCTID,WOCTRACER), ACS_NamedExecuteWithResult("WOC Monster Damage Scale",WOCTARGET,50), 5, POISONDOT)
		AROW A 1
		Stop
	}
}

ACTOR NewAcolyteBlue : NewAcolyte replaces AcolyteBlue
{
	Game Strife
	+MISSILEMORE
	+MISSILEEVENMORE
	ConversationID 60, -1, -1
	Translation 6
	DamageFactor "Lightning", 0.5
	DamageFactor "LightningPlayer", 0.5
	DamageFactor "LightningTime", 0.5
	States
	{
	Missile:
		AGRD E 8 A_FaceTarget
		AGRD E 0 A_PlaySound ("weapons/xbowshoot")
		AGRD E 3 A_CustomMissile ("NewElectricBolt", 40, 10, FRandom(-4,4), 1)
		Goto See
	}
}

ACTOR NewElectricBolt : ElectricBolt replaces ElectricBolt
{
  ConversationID 102, -1, -1
  Speed 30
  Radius 10
  Height 10
  Damage (ACS_NamedExecuteWithResult("WOC Monster Damage Scale",WOCTARGET,FRandom(15,30)))
  Projectile
  -STRIFEDAMAGE
  MaxStepHeight 4
  SeeSound "misc/swish"
  ActiveSound "misc/swish"
  DeathSound "weapons/xbowhit"
  Damagetype "Lightning"
  States
  {
  Spawn:
    AROW A 10 A_LoopActiveSound
    Loop
  Death:
	ZAP1 A 3
    ZAP1 BCDEFE 3
    ZAP1 DCB 2
    ZAP1 A 1
    Stop
  }
}

ACTOR NewAcolyteShadow : NewAcolyte replaces AcolyteShadow
{
  Game Strife
  ConversationID 61, 58, 59
  +MISSILEMORE
  States
  {
  See:
    AGRD A 6 A_BeShadowyFoe
    Goto Super::See+1
  Pain:
    AGRD O 0 A_SetShadow
    AGRD O 8 A_Pain
    Goto See
  }
}

ACTOR AcolyteTracer : FastProjectile
{
   Damage ((ACS_NamedExecuteWithResult("WOC Monster Damage Scale",WOCTARGET,FRandom(3,6))))
   Damagetype "Physical"
   Radius 1
   Height 1
   Mass 5
   Speed 80
   PROJECTILE
   +BLOODSPLATTER
   Renderstyle Normal
   Alpha 1.0
   decal BulletChip
   States
   {
   Spawn:
      TNT1 A 0 bright
      TNT1 A 0 bright A_SpawnItemEx("ZombieBulletTracerTrail",-15.0,0,0,0,0,0,0,128,0)
      TNT1 A 0 bright A_SpawnItemEx("ZombieBulletTracerTrail",-12.5,0,0,0,0,0,0,128,0)
      TNT1 A 0 bright A_SpawnItemEx("ZombieBulletTracerTrail",-10.0,0,0,0,0,0,0,128,0)
      TNT1 A 0 bright A_SpawnItemEx("ZombieBulletTracerTrail",-7.5,0,0,0,0,0,0,128,0)
      TNT1 A 0 bright A_SpawnItemEx("ZombieBulletTracerTrail",-5.0,0,0,0,0,0,0,128,0)
      TNT1 A 0 bright A_SpawnItemEx("ZombieBulletTracerTrail",-2.5,0,0,0,0,0,0,128,0)
	  TNT1 A 1 bright A_SpawnItemEx("ZombieBulletTracerTrail",0.0,0,0,0,0,0,0,128,0)
      loop
   XDeath:
      TNT1 A 1 //A_SpawnItem("bulletpuff")
      stop
   Death:
   Crash:
      TNT1 A 1 A_SpawnItem("bulletpuff")
      stop
   }
}

//Spectres

ACTOR NewAlienSpectre1 : AlienSpectre1 replaces AlienSpectre1
{
  Game Strife
  ConversationID 67, -1, -1
  Health 7500
  +NOPAIN
  Speed 12
  Radius 64
  Height 64
  FloatSpeed 5
  Mass 1000
  MinMissileChance 150
  RenderStyle Translucent
  Alpha 0.666
  SeeSound "alienspectre/sight"
  AttackSound "alienspectre/blade"
  PainSound "alienspectre/pain"
  DeathSound "alienspectre/death"
  ActiveSound "alienspectre/active"
  DropItem "AccessoryRandomSpawner" 32
  +NOGRAVITY
  +FLOAT
  +SHADOW
  +NOTDMATCH
  +DONTMORPH
  +NOBLOCKMONST
  +INCOMBAT
  +LOOKALLAROUND
  +NOICEDEATH
  +NODAMAGETHRUST
  +BOSS
  -SOLID
  -SPECTRAL
  +AVOIDMELEE
  Dropitem ""
  Args 1
  Damagetype "Shadow"
  Tag "Spectre"
  States
  {
  Spawn:
	ALN1 A 0
	ALN1 A 0 ACS_NamedExecuteAlways("WOC Monster Init",0,70,WOC_BOSS)//increase health on higher difficulties
  Idle:
	ALN1 A 10 A_Look
    ALN1 B 10 A_SentinelBob
    Loop
  See:
    ALN1 AB 4 Bright A_Chase
    ALN1 C 4 Bright A_SentinelBob
    ALN1 DEF 4 Bright A_Chase
    ALN1 G 4 Bright A_SentinelBob
    ALN1 HIJ 4 Bright A_Chase
    ALN1 K 4 Bright A_SentinelBob
    Loop
  Melee:
    ALN1 J 4 Bright A_FaceTarget
    ALN1 I 4 Bright A_CustomMeleeAttack(ACS_NamedExecuteWithResult("WOC Monster Damage Scale",ACTIVATOR,FRandom(15,30)), "alienspectre/blade", "", "Shadow")
    ALN1 H 4 Bright
    Goto See
  Missile:
    ALN1 J 4 Bright A_FaceTarget
    ALN1 I 4 Bright A_SpotLightning
    ALN1 H 4 Bright
    Goto See+10
  Pain:
    ALN1 J 2 A_Pain
    Goto See+6
  Death:
    AL1P A 6 Bright A_SpectreChunkSmall
    AL1P B 6 Bright A_Scream
    AL1P C 6 Bright A_SpectreChunkSmall
    AL1P DE 6 Bright
    AL1P F 6 Bright A_SpectreChunkSmall
    AL1P G 6 Bright
    AL1P H 6 Bright A_SpectreChunkSmall
    AL1P IJK 6 Bright
    AL1P LM 5 Bright
    AL1P N 5 Bright A_SpectreChunkLarge
    AL1P OPQ 5 Bright
    AL1P R 5 Bright ACS_NamedExecuteAlways("WOC SPECTRE KILL", 0, args[0])
    Stop
  }
}

ACTOR NewAlienSpectre2 : NewAlienSpectre1 replaces AlienSpectre2
{
  Game Strife
  ConversationID 70
  Health 10000
  +NOPAIN
  Radius 24
  Args 2
  States
  {
  Spawn:
	ALN1 A 0
	ALN1 A 0 ACS_NamedExecuteAlways("WOC Monster Init",0,70,WOC_BOSS)//increase health on higher difficulties
  Idle:
	ALN1 A 10 A_Look
    ALN1 B 10 A_SentinelBob
    Loop
  Missile:
    ALN1 F 4 A_FaceTarget
    ALN1 I 4 A_CustomMissile("SpectralLightningH3", 32, 0)
    ALN1 E 4
    Goto See+10
  }
}

ACTOR NewAlienSpectre3 : NewAlienSpectre1 replaces AlienSpectre3
{
  Game Strife
  ConversationID 71, -1, -1
  Health 12500
  +NOPAIN
  Radius 24
  +SPAWNCEILING
  +NODAMAGE
  DamageFactor "SpectralLow", 1
  Args 3
  States
  {
  Spawn:
	ALN1 A 0
	ALN1 A 0 ACS_NamedExecuteAlways("WOC Monster Init",0,70,WOC_BOSS)//increase health on higher difficulties
  Idle:
    ALN1 ABCDEFGHIJK 5 ACS_NamedExecuteWithResult("WOC SPECTRE KILL", -2)
    Loop
  See:
    ALN1 A 0 A_ChangeFlag("NODAMAGE", 0)
    ALN1 AB 5 A_Chase
    ALN1 C 5 A_SentinelBob
    ALN1 DEF 5 A_Chase
    ALN1 G 5 A_SentinelBob
    ALN1 HIJ 5 A_Chase
    ALN1 K 5 A_SentinelBob
    Loop
  Melee:
    ALN1 J 4 A_FaceTarget
    ALN1 I 4 A_CustomMeleeAttack(ACS_NamedExecuteWithResult("WOC Monster Damage Scale",ACTIVATOR,FRandom(15,30)), "alienspectre/blade", "", "Shadow")
    ALN1 C 4
    Goto See+2
  Missile:
    ALN1 F 4 A_FaceTarget
    ALN1 I 4 A_Spectre3Attack
    ALN1 E 4
    Goto See+10
  Pain:
    ALN1 J 2 A_Pain
    Goto See+6
  }
}

ACTOR NewAlienSpectre4 : NewAlienSpectre1 replaces AlienSpectre4
{
  Game Strife
  ConversationID 72, -1, -1
  Health 15000
  +NOPAIN
  Radius 24
  Args 4
  States
  {
  Spawn:
	ALN1 A 0
	ALN1 A 0 ACS_NamedExecuteAlways("WOC Monster Init",0,70,WOC_BOSS)//increase health on higher difficulties
  Idle:
	ALN1 A 10 A_Look
    ALN1 B 10 A_SentinelBob
    Loop
  Missile:
    ALN1 F 4 A_FaceTarget
    ALN1 I 4 A_CustomMissile("SpectralLightningBigV2", 32, 0)
    ALN1 E 4
    Goto See+10
  }
}

ACTOR NewAlienSpectre5 : NewAlienSpectre1 replaces AlienSpectre5
{
  Game Strife
  ConversationID 73, -1, -1
  Health 17500
  +NOPAIN
  Radius 24
  Args 5
  States
  {
  Spawn:
	ALN1 A 0
	ALN1 A 0 ACS_NamedExecuteAlways("WOC Monster Init",0,70,WOC_BOSS)//increase health on higher difficulties
  Idle:
	ALN1 A 10 A_Look
    ALN1 B 10 A_SentinelBob
    Loop
  Missile:
    ALN1 F 4 A_FaceTarget
    ALN1 I 4 A_CustomMissile("SpectralLightningBigBall2", 32, 0)
    ALN1 E 4
    Goto See+10
  }
}

Actor NewEntityBoss : EntityBoss replaces EntityBoss
{
	+NOPAIN
	Health 50000
	+BOSS
	+NODAMAGETHRUST
	-SPECTRAL
	+AVOIDMELEE
	ConversationID 74, -1, -1
	Damagetype "Shadow"
	Tag "The Entity"
	States
	{
	Spawn:
		MNAM A 0
		MNAM A 0 ACS_NamedExecuteAlways("WOC Monster Init",0,150,WOC_BOSS)//increase health on higher difficulties
		MNAM A 100
		MNAM B 60 Bright
		MNAM CDEFGHIJKL 4 Bright
		MNAL A 4 Bright A_Look
		MNAL B 4 Bright A_SentinelBob
		Goto Idle
	Idle:
	    MNAL A 4 Bright A_Look
		MNAL B 4 Bright A_SentinelBob
		Loop
	Melee:
		MNAL J 4 Bright A_FaceTarget
		MNAL I 4 Bright A_CustomMeleeAttack(ACS_NamedExecuteWithResult("WOC Monster Damage Scale",ACTIVATOR,FRandom(35,55)), "alienspectre/blade", "", "Shadow")
		MNAL C 4 Bright
		Goto See+2
	Death:
		MNAL L 7 Bright A_SpectreChunkSmall
		MNAL M 7 Bright A_Scream
		MNAL NO 7 Bright A_SpectreChunkSmall
		MNAL P 7 Bright A_SpectreChunkLarge
		MNAL Q 64 Bright A_SpectreChunkSmall
		MNAL Q 6 Bright A_EntityDeath
		Stop
	}
}

ACTOR NewEntitySecond : EntitySecond replaces EntitySecond
{
  ConversationID 75, -1, -1
  Health 10000
  +NOPAIN
  +BOSS
  -SPECTRAL
  +NODAMAGETHRUST
  +AVOIDMELEE
  Damagetype "Shadow"
  Tag "The Entity"
  States
  {
  Spawn:
    MNAL A 0
	MNAL A 0 ACS_NamedExecuteAlways("WOC Monster Init",0,200,WOC_BOSS)
  Idle:
    MNAL R 10 Bright A_Look
    Loop
  See:
    MNAL R 5 Bright A_SentinelBob
    MNAL ST 5 Bright A_Chase
    MNAL U 5 Bright A_SentinelBob
    MNAL V 5 Bright A_Chase
    MNAL W 5 Bright A_SentinelBob
    Loop
  Melee:
    MNAL S 4 Bright A_FaceTarget
    MNAL R 4 Bright A_CustomMeleeAttack(ACS_NamedExecuteWithResult("WOC Monster Damage Scale",ACTIVATOR,FRandom(15,30)), "alienspectre/blade", "", "Shadow")
    MNAL T 4 Bright A_SentinelBob
    Goto See+1
  Death:
    MDTH A 3 Bright A_Scream
    MDTH B 3 Bright A_TossGib
    MDTH C 3 Bright A_NoBlocking
    MDTH DEFGHIJKLMN 3 Bright A_TossGib
    MDTH O 3 Bright A_SubEntityDeath
    Stop
  }
}

Actor NewLoreMaster : LoreMaster replaces LoreMaster
{
	Health 10000
	+NOPAIN
	-FIRERESIST
	+BOSS
	+DONTMORPH
	+AVOIDMELEE
	Damagefactor "Fire", 1
	ConversationID 66, 63, 64
	Damagetype "Physical"
	Tag "The Loremaster"
	States
	{
	Spawn:
		PRST A 0
		PRST A 0 ACS_NamedExecuteAlways("WOC Monster Init",0,56,WOC_BOSS)//increase health on higher difficulties
	Idle:
		PRST A 10 A_Look
		PRST B 10 A_SentinelBob
		Loop
	Melee:
		PRST E 4 A_FaceTarget
		PRST F 4 A_CustomMeleeAttack(ACS_NamedExecuteWithResult("WOC Monster Damage Scale",ACTIVATOR,FRandom(15,30)), "loremaster/attack", "", "Physical")
		PRST E 4 A_SentinelBob
		Goto See
	Missile:
		PRST E 4 A_FaceTarget
		PRST F 4 A_CustomMissile("NewLoreShot", 32, 0)
		PRST E 4 A_SentinelBob
		Goto See
	Death:
	    PDED A 0 A_GiveToTarget ("Coin", random(200,400))
		PDED A 6
		PDED B 6 A_Scream
		PDED C 6
		PDED D 6 A_Fall
		PDED E 6
		PDED FGHIJIJIJKL 5
		PDED MNOP 4
		PDED Q 4 A_SpawnItemEx("AlienSpectre5", 0, 0, 0, 0, 0, random[spectrespawn](0, 255)*0.0078125, 0, SXF_NOCHECKPOSITION)
		PDED RS 4
		PDED T -1
		Stop
	}
}

Actor NewLoreShot : LoreShot replaces LoreShot
{
	-STRIFEDAMAGE
	Damage (ACS_NamedExecuteWithResult("WOC Monster Damage Scale",WOCTARGET,FRandom(1,8)))
	ConversationID 97, -1, -1
	Damagetype "Physical"
}

Actor NewProgrammer : Programmer replaces Programmer
{
	Health 4500
	+NOPAIN
	-FIRERESIST
	+DONTMORPH
	+BOSS
	+AVOIDMELEE
	ConversationID 95, -1, -1
	DamageFactor "Fire", 1
	Damagetype "Physical"
	DropItem "none"
	Args 1
	Tag "The Programmer"
	States
	{
	Spawn:
		PRGR A 0
		PRGR A 0 ACS_NamedExecuteAlways("WOC Monster Init",0,82,WOC_BOSS)
	Idle:
		PRGR A 5 A_Look
		PRGR A 1 A_SentinelBob
		Loop
	See:
		PRGR A 160 A_SentinelBob
		PRGR BCD 5 A_SentinelBob
		PRGR EF 2 A_SentinelBob
		PRGR EF 3 A_Chase
		Goto See+4
	Melee:
		PRGR E 2 A_SentinelBob
		PRGR F 3 A_SentinelBob
		PRGR E 3 A_FaceTarget
		PRGR F 4 A_ProgrammerMelee
		Goto See+4
	Missile:
		PRGR G 5 A_FaceTarget
		PRGR H 5 A_SentinelBob
		PRGR I 5 Bright A_FaceTarget
		PRGR J 5 Bright A_SpotLightning
		Goto See+4
	Pain:
		PRGR K 5 A_Pain
		PRGR L 5 A_SentinelBob
		Goto See+4
	Death:
	    PDED L 0 A_GiveToTarget ("Coin", random(200,400))
		PRGR L 7 Bright A_TossGib
		PRGR M 7 Bright A_Scream
		PRGR N 7 Bright A_TossGib
		//PRGR N 0 Bright A_GiveToTarget("Sigil")
		PRGR N 0 Bright ACS_NamedExecuteAlways("WOC STRIFE GIVESIGIL")
		PRGR N 0 Bright A_GiveToTarget("SigilSplinter1")
		PRGR O 7 Bright A_NoBlocking
		PRGR P 7 Bright A_TossGib
		PRGR Q 7 Bright A_SpawnProgrammerBase
		PRGR R 7 Bright
		PRGR S 6 Bright
		PRGR TUVW 5 Bright
		PRGR X 32 Bright
		PRGR X -1 Bright A_ProgrammerDeath
		Stop
  }
}

Actor NewStrifeBishop : StrifeBishop replaces StrifeBishop
{
	Health 8000
	+NOPAIN
	-FIRERESIST
	+DONTMORPH
	+BOSS
	DamageFactor "Fire", 1
	ConversationID 64, -1, -1
	Damagetype "Fire"
	Tag "The Bishop"
	States
	{
	Spawn:
		MLDR A 0
		MLDR A 0 ACS_NamedExecuteAlways("WOC Monster Init",0,110,WOC_BOSS)//increase health on higher difficulties
	Idle:
		MLDR A 10 A_Look
		Loop
	See:
		MLDR AABBCCDD 3 A_Chase
		Loop
	Missile:
		MLDR E 3 A_FaceTarget
		MLDR F 2 Bright A_CustomMissile("NewBishopMissile", 64, 0, 0, CMF_AIMOFFSET)
		Goto See
	Pain:
		MLDR D 1 A_Pain
		Goto See
	Death:
	    MLDR A 0 A_GiveToTarget ("Coin", random(200,400))
		MLDR G 3 Bright
		MLDR H 5 Bright A_Scream
		MLDR I 4 Bright A_TossGib
		MLDR J 4 Bright A_Explode(ACS_NamedExecuteWithResult("WOC Monster Damage Scale",ACTIVATOR,64), 64, XF_NOTMISSILE, 1)
		MLDR KL 3 Bright
		MLDR M 4 Bright A_NoBlocking
		MLDR N 4 Bright
		MLDR O 4 Bright A_TossGib
		MLDR P 4 Bright
		MLDR Q 4 Bright A_TossGib
		MLDR R 4 Bright
		MLDR S 4 Bright A_TossGib
		MLDR T 4 Bright
		MLDR U 4 Bright A_TossGib
		MLDR V 4 Bright A_SpawnItemEx("AlienSpectre2", 0, 0, 0, 0, 0, random[spectrespawn](0, 255)*0.0078125,
									  0, SXF_NOCHECKPOSITION)
		Stop
	}
}

ACTOR NewBishopMissile : BishopMissile replaces BishopMissile
{
  Damage (ACS_NamedExecuteWithResult("WOC Monster Damage Scale",WOCTARGET,FRandom(15,30)))
  -STRIFEDAMAGE
  Damagetype "Fire"
  States
  {
  Death:
    SMIS A 0 Bright A_SetTranslucent(1, 1)
    SMIS A 0 Bright A_StopSoundEx("Voice")
    SMIS A 5 Bright A_Explode(ACS_NamedExecuteWithResult("WOC Monster Damage Scale",WOCTARGET,64), 64, 0, 1)
    SMIS B 5 Bright
    SMIS C 4 Bright
    SMIS DEFG 2 Bright
    Stop
  }
}

//Robots
ACTOR NewSentinel : Sentinel replaces Sentinel
{
	ConversationID 91,-1,-1
	+AVOIDMELEE
	Tag "Sentinel"
	DamageFactor "Lightning", 1.5
	DamageFactor "LightningPlayer", 1.5
	DamageFactor "LightningTime", 1.5
	DamageFactor "PoisonTime", 0
	DamageFactor "Bleed", 0
	States
	{
	Spawn:
		SEWR A 0
		SEWR A 0 ACS_NamedExecuteAlways("WOC Monster Init",0,53,0)//increase health on higher difficulties
	Idle:
		SEWR A 10 A_Look
		Loop
	Death:
		SEWR D 0 A_GiveToTarget ("Coin", random(4,7))
		SEWR D 7 A_Fall
		SEWR E 8 Bright A_TossGib
		SEWR F 5 Bright A_Scream
		SEWR GH 4 Bright A_TossGib
		SEWR I 4
		SEWR J 5
		Stop
	Ice:
		"----" A 0 A_GiveToTarget ("Coin", random(4,7))
		"----" E 5 A_GenericFreezeDeath
		"----" E 1 A_FreezeDeathChunks
		Wait
	}
}

Actor NewSentinelFX2 : SentinelFX2 replaces SentinelFX2
{
  Damage (ACS_NamedExecuteWithResult("WOC Monster Damage Scale",WOCTARGET,FRandom(1,4)))
  +NODAMAGETHRUST
  -STRIFEDAMAGE
  Damagetype "Lightning"
}

ACTOR NewCrusader : Crusader replaces Crusader
{
	DropItem "None"
	ReactionTime 23
	meleeRange 264
	ConversationID 63, -1, -1
	DropItem "AccessoryRandomSpawner" 8
	Damagetype "Fire"
	Tag "Crusader"
	Health 600
	DamageFactor "Lightning", 1.5
	DamageFactor "LightningPlayer", 1.5
	DamageFactor "LightningTime", 1.5
	DamageFactor "PoisonTime", 0
	DamageFactor "Bleed", 0
	States
	{
	Spawn:
		ROB2 Q 0
		ROB2 Q 0 ACS_NamedExecuteAlways("WOC Monster Init",0,68,0)//increase health on higher difficulties
	Idle:
		ROB2 Q 10 A_Look
		Loop
	Melee:
		ROB2 E 1 A_FaceTarget
		ROB2 F 2 Bright A_CustomMissile("FastFlameMissile",48,0,frandom(-5.6,5.6),0,0)
		Goto See
	Missile:
		ROB2 E 3 A_FaceTarget
		ROB2 F 0 A_CustomMissile("CrusaderMissile",40,0,-1.5,1,0)
		ROB2 F 0 A_CustomMissile("CrusaderMissile",40,0,1.5,1,0)
		ROB2 F 2 Bright A_CustomMissile("CrusaderMissile",56,0,0,1,0)
		ROB2 E 3
		Goto See
	Death:
		ROB2 G 0 A_GiveToTarget ("Coin", random(7,16))
		ROB2 G 3 A_Scream
		ROB2 H 5 A_TossGib
		ROB2 I 4 Bright A_TossGib
		ROB2 J 4 Bright A_Explode(ACS_NamedExecuteWithResult("WOC Monster Damage Scale",ACTIVATOR,64), 64, XF_NOTMISSILE, 1)
		ROB2 K 4 Bright A_Fall
		ROB2 L 4 A_Explode(ACS_NamedExecuteWithResult("WOC Monster Damage Scale",ACTIVATOR,64), 64, XF_NOTMISSILE, 1)
		ROB2 MN 4 A_TossGib
		ROB2 O 4 A_Explode(ACS_NamedExecuteWithResult("WOC Monster Damage Scale",ACTIVATOR,64), 64, XF_NOTMISSILE, 1)
		ROB2 P -1 A_CrusaderDeath
		Stop
	}
}

Actor NewCrusaderMissile : CrusaderMissile replaces CrusaderMissile
{
  Damage (ACS_NamedExecuteWithResult("WOC Monster Damage Scale",WOCTARGET,FRandom(3,24)))
  -STRIFEDAMAGE
  Damagetype "Fire"
  States
  {
  Spawn:
    MICR A 6 Bright A_RocketInFlight
    Loop
  Death:
    SMIS A 0 Bright A_SetTranslucent(1, 1)
    SMIS A 5 Bright
    SMIS B 5 Bright
    SMIS C 4 Bright
    SMIS DEFG 2 Bright
    Stop
  }
}

ACTOR NewFastFlameMissile : FastFlameMissile replaces FastFlameMissile
{
  Damage (ACS_NamedExecuteWithResult("WOC Monster Damage Scale",WOCTARGET,FRandom(1,8)))
  -STRIFEDAMAGE
  Damagetype "Fire"
}

ACTOR NewInquisitor : Inquisitor replaces Inquisitor
{
	-NORADIUSDMG
	+NOICEDEATH
	+DONTMORPH
	Health 2000
	ConversationID 93, -1, -1
	DropItem "AccessoryRandomSpawner" 16
	Damagetype "Fire"
	Tag "Inquisitor"
	DamageFactor "Lightning", 1.5
	DamageFactor "LightningPlayer", 1.5
	DamageFactor "LightningTime", 1.5
	DamageFactor "PoisonTime", 0
	DamageFactor "Bleed", 0
	States
	{
	Spawn:
		ROB3 A 0
		ROB3 A 0 ACS_NamedExecuteAlways("WOC Monster Init",0,110,0)
	Idle:
		ROB3 AB 10 A_Look
		Loop
	Missile:
		ROB3 A 2 A_InquisitorDecide
		ROB3 F 6 A_FaceTarget
		ROB3 G 0 A_PlaySound ("reaver/attack", CHAN_WEAPON)
		ROB3 GG 0 Bright A_CustomMissile("ReaverTracer", 64, -32, random(-600,600)/100.0)
		ROB3 G 8 Bright A_CustomMissile("ReaverTracer", 64, -32, random(-600,600)/100.0)
		ROB3 G 0 A_PlaySound ("reaver/attack", CHAN_WEAPON)
		ROB3 GG 0 A_CustomMissile("ReaverTracer", 64, -32, random(-600,600)/100.0)
		ROB3 G 8 A_ReaverRanged
		Goto See
	Grenade:
		ROB3 K 12 A_FaceTarget
		ROB3 J 6 Bright A_InquisitorAttack
		ROB3 K 12
		Goto See
	Jump:
		ROB3 H 8 Bright A_InquisitorJump
		ROB3 I 4 Bright A_InquisitorCheckLand
		ROB3 H 4 Bright A_InquisitorCheckLand
		Goto Jump+1
	Death:
		ROB3 L 0 A_GiveToTarget ("Coin", random(100,150))
		ROB3 L 0 A_StopSoundEx("Item")
		ROB3 L 4 A_TossGib
		ROB3 M 4 A_Scream
		ROB3 N 4 A_TossGib
		ROB3 O 4 Bright A_Explode(ACS_NamedExecuteWithResult("WOC Monster Damage Scale",ACTIVATOR,128), 128, XF_NOTMISSILE, 1)
		ROB3 P 4 Bright A_TossGib
		ROB3 Q 4 Bright A_NoBlocking
		ROB3 RSTUV 4 A_TossGib
		ROB3 W 4 Bright A_Explode(ACS_NamedExecuteWithResult("WOC Monster Damage Scale",ACTIVATOR,128), 128, XF_NOTMISSILE, 1)
		ROB3 XY 4 Bright A_TossGib
		ROB3 Z 4 A_TossGib
		ROB3 "[" 4 A_TossGib
		ROB3 "\" 3 A_TossGib
		ROB3 "]" 3 Bright A_Explode(ACS_NamedExecuteWithResult("WOC Monster Damage Scale",ACTIVATOR,128), 128, XF_NOTMISSILE, 1)
		RBB3 A 3 Bright A_TossArm
		RBB3 B 3 Bright A_TossGib
		RBB3 CD 3 A_TossGib
		RBB3 E -1
		Stop
	}
}

ACTOR ReaverTracer : AcolyteTracer
{
   Damage (ACS_NamedExecuteWithResult("WOC Monster Damage Scale",WOCTARGET,FRandom(3,24)))
   Damagetype "Physical"
}

ACTOR NewInquisitorShot : InquisitorShot replaces InquisitorShot
{
  -STRIFEDAMAGE
  Damagetype "Fire"
  States
  {
  Death:
    BNG2 A 0 Bright A_SetTranslucent(1, 1)
    BNG2 A 4 Bright A_Explode(ACS_NamedExecuteWithResult("WOC Monster Damage Scale",WOCTARGET,192), 192, 0, 1)
    BNG2 B 4 Bright
    BNG2 C 4 Bright
    BNG2 D 4 Bright
    BNG2 E 4 Bright
    BNG2 F 4 Bright
    BNG2 G 4 Bright
    BNG2 H 4 Bright
    BNG2 I 4 Bright
    Stop
  }
}

ACTOR NewStalker : Stalker replaces Stalker
{
	Meleerange 52
	ConversationID 92, -1, -1
	Damagetype "Physical"
	Tag "Stalker"
	DamageFactor "Lightning", 1.5
	DamageFactor "LightningPlayer", 1.5
	DamageFactor "LightningTime", 1.5
	DamageFactor "PoisonTime", 0
	DamageFactor "Bleed", 0
	States
	{
	Spawn:
		STLK A 0
		STLK A 0 ACS_NamedExecuteAlways("WOC Monster Init",0,31,0)
	Idle:
		STLK A 1 A_StalkerLookInit
		Loop
	LookCeiling:
		STLK A 10 A_Look
		Loop
	LookFloor:
		STLK J 10 A_Look
		Loop
	See:
		STLK A 1 A_StalkerChaseDecide
		STLK ABB 3 A_Chase
		STLK C 3 A_StalkerWalk
		STLK C 3 A_Chase
		Loop
	Melee:
		STLK J 3 A_FaceTarget
		STLK J 0 A_CheckFlag("NoGravity", "Drop")
		STLK K 3 A_CustomMeleeAttack(ACS_NamedExecuteWithResult("WOC Monster Damage Scale",ACTIVATOR,FRandom(1,8)), "stalker/attack", "", "Physical")
	SeeFloor:
		STLK J 3 A_StalkerWalk
		STLK KK 3 A_Chase
		STLK L 3 A_StalkerWalk
		STLK L 3 A_Chase
		Loop
	Pain:
		STLK L 1 A_Pain
		Goto See
	Drop:
		STLK C 2 A_StalkerDrop
		STLK IHGFED 3
		Goto SeeFloor
	Death:
		STLK O 0 A_GiveToTarget ("Coin", random(3,6))
		STLK O 4
		STLK P 4 A_Scream
		STLK QRST 4
		STLK U 4 A_NoBlocking
		STLK VW 4
		STLK "XYZ[" 4 Bright
		Stop
	Ice:
		"----" A 0 A_GiveToTarget ("Coin", random(3,6))
		"----" E 5 A_GenericFreezeDeath
		"----" E 1 A_FreezeDeathChunks
		Wait
	}
}

ACTOR NewCeilingTurret : CeilingTurret replaces CeilingTurret
{
  ConversationID 122, -1, -1
  Tag "Ceiling Turret"
  DamageFactor "Lightning", 1.5
	DamageFactor "LightningPlayer", 1.5
	DamageFactor "LightningTime", 1.5
	DamageFactor "PoisonTime", 0
	DamageFactor "Bleed", 0
  States
  {
  Spawn:
    TURT A 0
	TURT A 0 ACS_NamedExecuteAlways("WOC Monster Init",0,1,0)
  Idle:
    TURT A 5 A_TurretLook
    Loop
  See:
	TURT AAAA 1 A_CheckSight("Clear")
  See2:
    TURT A 2 A_Chase
    Loop
  Clear:
	TURT A 1 A_ClearTarget
	Goto Idle
  Missile:
  Pain:
    TURT B 0 A_Facetarget
	TURT B 0 A_PlaySound ("monsters/rifle", CHAN_WEAPON)
    TURT B 4 A_CustomMissile("AcolyteTracer", 0, 0, random(-8,8))
	TURT D 0 A_Jump(10,"See2")
    TURT D 3 A_MonsterRefire(30, "See2")
	TURT D 0 A_Jump(10,"See2")
    TURT A 4 A_MonsterRefire(30, "See2")
    Loop
  Death:
    BALL O 0 A_GiveToTarget ("Coin", random(4,7))
    BALL O 4
    BALL A 6 Bright A_Scream
    BALL BCDE 6 Bright
    TURT C -1
    Stop
  Ice:
    "----" A 0 A_GiveToTarget ("Coin", random(4,7))
	"----" E 5 A_GenericFreezeDeath
	"----" E 1 A_FreezeDeathChunks
	Wait
  }
}

ACTOR NewTemplar : Templar replaces Templar
{
  Meleerange 72
  ConversationID 62, 61, 62
  DropItem "None"
  Damagetype "Physical"
  Tag "Templar"
  Health 400
  States
  {
  Spawn:
    PGRD A 0
	PGRD A 0 ACS_NamedExecuteAlways("WOC Monster Init",0,60,0)
  Idle:
    PGRD A 0 A_CheckFlag("StandStill",2)
	PGRD A 0 A_Jump(256,2)
    PGRD A 5 A_TurretLook
    Loop
    PGRD AA 3 A_Wander
    PGRD A 0 A_TurretLook
    PGRD BB 3 A_Wander
    PGRD B 0 A_TurretLook
    PGRD CC 3 A_Wander
    PGRD C 0 A_TurretLook
    PGRD DD 3 A_Wander
    PGRD D 0 A_TurretLook
	Loop
  See:
    PGRD AABBCCDD 3 A_Chase
    Loop
  Melee:
    PGRD E 8 A_FaceTarget
    PGRD F 8 A_CustomMeleeAttack(ACS_NamedExecuteWithResult("WOC Monster Damage Scale",ACTIVATOR,FRandom(3,24)), "reaver/blade", "", "Physical")
    Goto See
  Missile:
    PGRD G 8 Bright A_FaceTarget
	PGRD H 0 Bright A_FaceTarget
	PGRD H 0 Bright A_PlaySound("templar/shoot", CHAN_WEAPON)
	PGRD HHHHHHHHH 0 Bright A_CustomMissile("TemplarTracer", 32, 0, FRandom(-11.25,11.25), CMF_OFFSETPITCH, FRandom(-7,7))
    PGRD H 8 Bright A_CustomMissile("TemplarTracer", 32, 0, FRandom(-11.25,11.25), CMF_OFFSETPITCH, FRandom(-7,7))
    Goto See
  Pain:
    PGRD A 2
    PGRD A 2 A_Pain
    Goto See
  Death:
    PGRD I 0 A_GiveToTarget ("Coin", random(6,12))
    PGRD I 4 A_TossGib
    PGRD J 4 A_Scream
    PGRD K 4 A_TossGib
    PGRD L 4 A_NoBlocking
    PGRD MN 4
    PGRD O 4 A_TossGib
    PGRD "PQRSTUVWXYZ[" 4
    PGRD "\" -1
    Stop
  Ice:
    "----" A 0 A_GiveToTarget ("Coin", random(6,12))
	"----" E 5 A_GenericFreezeDeath
	"----" E 1 A_FreezeDeathChunks
	Wait
  }
}

ACTOR TemplarTracer : FastProjectile
{
   Damage (ACS_NamedExecuteWithResult("WOC Monster Damage Scale",WOCTARGET,FRandom(1,8)))
   Radius 1
   Height 1
   Mass 5
   Speed 250
   PROJECTILE
   Damagetype "Poison"
   +BLOODSPLATTER
   Renderstyle Normal
   Alpha 1.0
   decal RailScorchLower
   States
   {
   Spawn:
      TNT1 A 3
      loop
   Death:
      TNT1 A 1 A_SpawnItem("maulerpuff")
      stop
   }
}

ACTOR NewReaver : Reaver replaces Reaver
{
  MeleeRange 68
  ConversationID 52, -1, -1
  Damagetype "Physical"
  Tag "Reaver"
  Speed 14
  Health 250
  DamageFactor "Lightning", 1.5
	DamageFactor "LightningPlayer", 1.5
	DamageFactor "LightningTime", 1.5
	DamageFactor "PoisonTime", 0
	DamageFactor "Bleed", 0
  States
  {
  Spawn:
    ROB1 A 0
	ROB1 A 0 ACS_NamedExecuteAlways("WOC Monster Init",0,60,0)
  Idle:
    ROB1 A 10 A_Look
    Loop
  Melee:
    ROB1 H 6 A_FaceTarget
    ROB1 I 8 A_CustomMeleeAttack(ACS_NamedExecuteWithResult("WOC Monster Damage Scale",ACTIVATOR,FRandom(3,24)), "reaver/blade", "", "Physical")
    ROB1 H 6
    Goto See
  Missile:
    ROB1 F 8 A_FaceTarget
	ROB1 F 0 A_PlaySound ("reaver/attack", CHAN_WEAPON)
	ROB1 GG 0 A_CustomMissile("ReaverTracer", 32, -8, frandom(-6,6))
    ROB1 G 11 Bright A_CustomMissile("ReaverTracer", 32, -8, frandom(-6,6))
    Goto See
  Pain:
    ROB1 A 2
    ROB1 A 2 A_Pain
    Goto See
  Death:
    ROB1 I 0 A_GiveToTarget ("Coin", random(5,10))
    ROB1 J 6
    ROB1 K 6 A_Scream
    ROB1 L 5
    ROB1 M 5 A_NoBlocking
    ROB1 NOP 5
    ROB1 Q 6 A_Explode(ACS_NamedExecuteWithResult("WOC Monster Damage Scale",ACTIVATOR,32), 32, XF_NOTMISSILE, 1)
    ROB1 R -1
    Stop
  XDeath:
    ROB1 I 0 A_GiveToTarget ("Coin", random(5,10))
    ROB1 L 5 A_TossGib
    ROB1 M 5 A_Scream
    ROB1 N 5 A_TossGib
    ROB1 O 5 A_NoBlocking
    ROB1 P 5 A_TossGib
    Goto Death+7
  Ice:
    "----" A 0 A_GiveToTarget ("Coin", random(5,10))
	"----" E 5 A_GenericFreezeDeath
	"----" E 1 A_FreezeDeathChunks
	Wait
  }
}

ACTOR NewSpectralLightningBall1 : SpectralLightningBall1 replaces SpectralLightningBall1
{
  Damage (ACS_NamedExecuteWithResult("WOC Monster Damage Scale",WOCTARGET,FRandom(147,167)))
  ConversationID 80, -1, -1
  Projectile
  +SPECTRAL
  Damagetype "Lightning"
  States
  {
  Death:
    ZAP1 B 3 A_Explode(ACS_NamedExecuteWithResult("WOC Monster Damage Scale",WOCTARGET,32), 32, 0)
    ZAP1 A 3 A_AlertMonsters
    ZAP1 BCDEFE 3
    ZAP1 DCB 2
    ZAP1 A 1
    Stop
  }
}

ACTOR NewSpectralLightningBall2 : SpectralLightningBall2 replaces SpectralLightningBall2
{
  Damage (ACS_NamedExecuteWithResult("WOC Monster Damage Scale",WOCTARGET,FRandom(35,55)))
  ConversationID 81, -1, -1
  Damagetype "Lightning"
  States
  {
  Death:
    ZAP1 B 3 A_Explode(ACS_NamedExecuteWithResult("WOC Monster Damage Scale",WOCTARGET,32), 32, 0)
    ZAP1 A 3 A_AlertMonsters
    ZAP1 BCDEFE 3
    ZAP1 DCB 2
    ZAP1 A 1
    Stop
  }
}

ACTOR NewSpectralLightningH1 : SpectralLightningH1 replaces SpectralLightningH1
{
  Damage (ACS_NamedExecuteWithResult("WOC Monster Damage Scale",WOCTARGET,FRandom(147,167)))
  ConversationID 78, -1, -1
  Damagetype "Lightning"
  States
  {
  Death:
    ZAP1 B 3 A_Explode(ACS_NamedExecuteWithResult("WOC Monster Damage Scale",WOCTARGET,32), 32, 0)
    ZAP1 A 3 A_AlertMonsters
    ZAP1 BCDEFE 3
    ZAP1 DCB 2
    ZAP1 A 1
    Stop
  }
}

ACTOR NewSpectralLightningH2 : SpectralLightningH2 replaces SpectralLightningH2
{
  Damage (ACS_NamedExecuteWithResult("WOC Monster Damage Scale",WOCTARGET,FRandom(35,55)))
  ConversationID 79, -1, -1
  Damagetype "Lightning"
  States
  {
  Death:
    ZAP1 B 3 A_Explode(ACS_NamedExecuteWithResult("WOC Monster Damage Scale",WOCTARGET,32), 32, 0)
    ZAP1 A 3 A_AlertMonsters
    ZAP1 BCDEFE 3
    ZAP1 DCB 2
    ZAP1 A 1
    Stop
  }
}

ACTOR NewSpectralLightningH3 : SpectralLightningH3 replaces SpectralLightningH3
{
  Damage (ACS_NamedExecuteWithResult("WOC Monster Damage Scale",WOCTARGET,FRandom(15,30)))
  ConversationID 82, -1, -1
  Damagetype "Lightning"
  States
  {
  Death:
    ZAP1 B 3 A_Explode(ACS_NamedExecuteWithResult("WOC Monster Damage Scale",WOCTARGET,32), 32, 0)
    ZAP1 A 3 A_AlertMonsters
    ZAP1 BCDEFE 3
    ZAP1 DCB 2
    ZAP1 A 1
    Stop
  }
}

ACTOR NewSpectralLightningBigBall1 : SpectralLightningBigBall1 replaces SpectralLightningBigBall1
{
  Damage (ACS_NamedExecuteWithResult("WOC Monster Damage Scale",WOCTARGET,FRandom(280,320)))
  ConversationID 84, -1, -1
  Damagetype "Lightning"
  States
  {
  Death:
    ZAP1 B 3 A_Explode(ACS_NamedExecuteWithResult("WOC Monster Damage Scale",WOCTARGET,32), 32, 0)
    ZAP1 A 3 A_AlertMonsters
    ZAP1 BCDEFE 3
    ZAP1 DCB 2
    ZAP1 A 1
    Stop
  }
}

ACTOR NewSpectralLightningBigBall2 : SpectralLightningBigBall2 replaces SpectralLightningBigBall2
{
  Damage (ACS_NamedExecuteWithResult("WOC Monster Damage Scale",WOCTARGET,FRandom(57,77)))
  ConversationID 85, -1, -1
  Damagetype "Lightning"
  States
  {
  Death:
    ZAP1 B 3 A_Explode(ACS_NamedExecuteWithResult("WOC Monster Damage Scale",WOCTARGET,32), 32, 0)
    ZAP1 A 3 A_AlertMonsters
    ZAP1 BCDEFE 3
    ZAP1 DCB 2
    ZAP1 A 1
    Stop
  }
}

ACTOR NewSpectralLightningV1 : SpectralLightningV1 replaces SpectralLightningV1
{
  Damage (ACS_NamedExecuteWithResult("WOC Monster Damage Scale",WOCTARGET,FRandom(205,245)))
  ConversationID 86,-1,-1
  Damagetype "Lightning"
  States
  {
  Death:
    ZAP1 B 3 A_Explode(ACS_NamedExecuteWithResult("WOC Monster Damage Scale",WOCTARGET,32), 32, 0)
    ZAP1 A 3 A_AlertMonsters
    ZAP1 BCDEFE 3
    ZAP1 DCB 2
    ZAP1 A 1
    Stop
  }
}

ACTOR NewSpectralLightningV2 : SpectralLightningV2 replaces SpectralLightningV2
{
  Damage (ACS_NamedExecuteWithResult("WOC Monster Damage Scale",WOCTARGET,FRandom(102,122)))
  ConversationID 87, -1, -1
  Damagetype "Lightning"
  States
  {
  Death:
    ZAP1 B 3 A_Explode(ACS_NamedExecuteWithResult("WOC Monster Damage Scale",WOCTARGET,32), 32, 0)
    ZAP1 A 3 A_AlertMonsters
    ZAP1 BCDEFE 3
    ZAP1 DCB 2
    ZAP1 A 1
    Stop
  }
}

ACTOR NewSpectralLightningBigV1 : SpectralLightningBigV1 replaces SpectralLightningBigV1
{
  Damage (ACS_NamedExecuteWithResult("WOC Monster Damage Scale",WOCTARGET,FRandom(250,290)))
  ConversationID 89, -1, -1
  Damagetype "Lightning"
  States
  {
  Death:
    ZAP1 B 3 A_Explode(ACS_NamedExecuteWithResult("WOC Monster Damage Scale",WOCTARGET,32), 32, 0)
    ZAP1 A 3 A_AlertMonsters
    ZAP1 BCDEFE 3
    ZAP1 DCB 2
    ZAP1 A 1
    Stop
  }
}

ACTOR NewSpectralLightningBigV2 : SpectralLightningBigV2 replaces SpectralLightningBigV2
{
  Damage (ACS_NamedExecuteWithResult("WOC Monster Damage Scale",WOCTARGET,FRandom(120,150)))
  ConversationID 90, -1, -1
  Damagetype "Lightning"
  States
  {
  Death:
    ZAP1 B 3 A_Explode(ACS_NamedExecuteWithResult("WOC Monster Damage Scale",WOCTARGET,32), 32, 0)
    ZAP1 A 3 A_AlertMonsters
    ZAP1 BCDEFE 3
    ZAP1 DCB 2
    ZAP1 A 1
    Stop
  }
}