ACTOR CrowMossberg: DravenWeaponBase Replaces SuperShotgun
{
  	Weapon.AmmoType "Shell"
	Weapon.AmmoUse 1
  	Weapon.AmmoGive 10
  	+WEAPON.NOALERT
  	+FloorClip
  	weapon.bobstyle inversesmooth
    weapon.bobspeed 2.0
  	weapon.bobrangex 0.75
  	weapon.bobrangey 0.75
  	Inventory.Pickupmessage "You got the Shotgun! (Slot 3)"
	inventory.pickupsound "misc/w_pkup"
	Weapon.UpSound "Weapon/switch"
	Obituary "%o was blasted in the face by %k's shotgun."
	+FORCEXYBILLBOARD
	+weapon.noautoaim
	Tag "Mossberg 500 Cruiser"
	States
	{
	Ready:
		MOSB A 1 A_WeaponReady(WRF_ALLOWZOOM|WRF_ALLOWRELOAD)
		Loop
	Fire:
		SHTN A 0 A_ZoomFactor(0.96)
		TNT1 A 0 A_GunFlash
		TNT1 A 0 A_TakeInventory("Shell",1)
		TNT1 A 0 A_AlertMonsters
		TNT1 A 0 A_PlaySound("weapons/mossberg/fire",1)
		SHTN A 0 A_FireBullets (5, 1, 5, 13, "CrowBuckshot", FBF_NORANDOM)
		SHTN A 0 A_FireBullets (7, 5, 5, 13, "CrowBuckshot", FBF_NORANDOM)
		MOSF AB 1 Bright
		SHTN A 0 A_SetPitch(-6.0 + pitch)
		SHTN A 0 A_ZoomFactor(1.00)
		MOSF C 1 A_SetPitch(+1.0 + pitch)
		MOSF DE 1 A_SetPitch(+1.0 + pitch)
		MOSF FGHIJ 1 A_SetPitch(pitch+0.6)
		MOSB A 10
		TNT1 A 0 A_JumpifInventory("Shell",1,"Reloading")
		Goto Ready
	Reloading:
		TNT1 A 0 A_PlaySound("weapons/mossberg/pump",7)
		MOSB BCDE 1
		TNT1 A 0 A_FireCustomMissile("ShotCaseSpawn",5,0,18,-14)
		MOSB FFGGFFEEDCBA 1
		MOSB A 5 //Needs a but of cooldown
		Goto Ready
	Select:
		BNJO AAAAAAAAA 0 A_Raise
		Goto RaiseWeapon
	RaiseWeapon:
		MOSS ABCDEF 1 A_WeaponReady(WRF_NOSWITCH|WRF_NOFIRE)
		TNT1 A 0 A_PlaySound("weapons/mossberg/pump",7)
		MOSB BCDEFFGGFFEEDCBA 1
		Goto Ready
	Deselect:
		MOSS FEDCBA 1 A_WeaponReady(WRF_NOSWITCH|WRF_NOFIRE)
		MOSB AAAAAAAAAAA 0 A_Lower
		Wait
	Spawn:
		MOSB Z -1
		Loop
	KickFlash:
		MOSB A 19 A_WeaponReady(WRF_NOFIRE|WRF_NOSWITCH)
		stop
	}
}