ACTOR CrowUndeadFury : DravenWeaponBase Replaces Fist
{
	+Weapon.NoAlert
	Weapon.Kickback 100
	Inventory.PickupMessage "Victims, aren't all we?"
	Obituary "%o couldn't survive %k's wrath."
	Tag "Undead Fury"
	+WEAPON.MELEEWEAPON		
	+WEAPON.ALLOW_WITH_RESPAWN_INVUL
	Weapon.BobStyle inversesmooth
	Weapon.BobSpeed 2.0
	Weapon.BobRangeX 0.75
	Weapon.BobRangeY 0.75
	Weapon.UpSound "weapon/switch"
	+FORCEXYBILLBOARD
	Weapon.SlotNumber 1
	Weapon.SelectionOrder 3700
	+weapon.noautoaim
	States
	{
	Ready:
		CFST A 6 A_WeaponReady(WRF_ALLOWZOOM|WRF_ALLOWRELOAD)
		TNT1 A 0 A_GiveInventory("Health",3)
		Loop
	Deselect:
		CFST A 1 A_Lower
		CFST AA 0 A_Lower
		Loop
	Select:
		CFST A 1 A_Raise
		CFST AA 0 A_Raise
		Loop
	Fire:
		CFST ABCDE 1
		Goto Hold
	Hold:
		TNT1 A 0 A_PlaySound("melee/swing",7)
		TNT1 A 0 A_Jump(256,"Hold1","Hold2") 
		Goto Hold1
	Hold1:
		FST3 ABC 1
		FST3 D 1 A_CustomPunch(20, 0, 0, "CrowFistPuff")
		FST3 DEFGH 1
		TNT1 A 0 A_Refire
		TNT1 A 10
		Goto AfterPunch
	Hold2:
		FST4 ABC 1
		FST4 D 1 A_CustomPunch(20, 0, 0, "CrowFistPuff")
		FST4 DEFGH 1
		TNT1 A 0 A_Refire
		TNT1 A 10
		Goto AfterPunch
	AltFire:
		CFST ABCDE 1
		Goto AltHold
	AltHold:
		TNT1 A 0 A_PlaySound("melee/heavyswing")
		FST1 BC 1 
		TNT1 A 0 A_SetAngle(angle-4)
		FST1 D 1 A_CustomPunch(40, 0, 0, "CrowFistPuff", 80)
		FST1 EFGH 1 A_SetAngle(angle+1)
		TNT1 A 10
		TNT1 A 0 A_Refire("AltHold2")
		Goto AfterPunch
	AltHold2:
		TNT1 A 0 A_PlaySound("melee/heavyswing")
		FST2 AB 1 
		TNT1 A 0 A_SetAngle(angle+4)
		FST2 C 1 A_CustomPunch(40, 0, 0, "CrowFistPuff", 80)
		FST2 DEFG 1 A_SetAngle(angle-1)
		TNT1 A 10
		TNT1 A 0 A_Refire("AltHold")
		Goto AfterPunch
	AfterPunch:
		CFST EDCBA 1
		Goto Ready
	Spawn:
		TNT1 A -1
		Stop
	KickFlash:
		CFST A 19 A_WeaponReady(WRF_NOFIRE|WRF_NOSWITCH)
		Stop
	}
}