actor MegaWaterS_W : BaseMM8BDMWep_CBM
{
tag "$TAGC_WTB"
dropitem "MegaWaterBarrierWep"
Weapon.AmmoUse 1
Weapon.AmmoGive 28
Obituary "$OB_MWSHARPOON"
Inventory.Pickupmessage "Shiranai. Fuzakenaideyo! Butsu butsu iwanai-de!"
weapon.ammotype "KappaMikeyAmmo"
weapon.ammotype2 "KappaBarrierAmmo"
States
{
Spawn:
C_WT B 1
loop

Deselect:
MWSH A 0
goto DeselectSwap
Select:
MWSH A 0 A_TakeInventory("MWSShieldCharge")
goto SelectSwap

Ready:
MWSH A 0 ACS_NamedExecuteWithResult("core_weaponcolor",DYE_MEGAWATERS)
MWSH A 0 A_GunFlash("Flash",1)
goto Ready2
Ready2:
MWSH A 0 A_JumpIfInventory("MWS_ItemFlag",1,"Ready2a")
MWSH A 0 A_JumpIfInventory("KappaMikeyAmmo",3,"Ready3")
MWSH A 8 A_WeaponReady(WRF_NOSECONDARY)
MWSH A 0 A_JumpIfInventory("MWS_ItemFlag",1,2)
MWSH A 0 A_GiveInventory("KappaBarrierAmmo",1)
MWSH A 0 A_GiveInventory("KappaMikeyAmmo",1)
loop
Ready2a:
MWSH A 0 A_JumpIfInventory("KappaMikeyAmmo",6,"Ready3")
MWSH A 8 A_WeaponReady(WRF_NOSECONDARY)
MWSH A 0 A_JumpIfInventory("MWS_ItemFlag",1,2)
MWSH A 0 A_GiveInventory("KappaBarrierAmmo",1)
MWSH A 0 A_GiveInventory("KappaMikeyAmmo",1)
goto Ready2
Ready3:
MWSH A 8 A_WeaponReady
MWSH A 0 A_JumpIfInventory("MWS_ItemFlag",1,2)
MWSH A 0 A_GiveInventory("KappaBarrierAmmo",1)
MWSH A 0 A_GiveInventory("KappaMikeyAmmo",1)
loop

Fire:
MWSH A 0 A_GiveInventory("VivifyDelay10",1)
MWSH A 0 A_Refire(1)
MWSH B 0 A_PlaySoundEx("weapon/pshot","Weapon")
MWSH B 0 A_FireCustomMissile("MWS_Harpoon",0,0,8,0)
MWSH BC 3
MWSH B 0 A_GiveInventory("KappaMikeyAmmo",1)
MWSH B 0 A_PlaySoundEx("weapon/pshot","Weapon")
MWSH B 0 A_FireCustomMissile("MWS_Harpoon",0,0,8,0)
MWSH BC 3
MWSH B 0 A_PlaySoundEx("weapon/pshot","Weapon")
MWSH B 0 A_FireCustomMissile("MWS_Harpoon",0,0,8,0)
MWSH BC 3
MWSH A 16
MWSH A 0 A_Refire
goto Ready2
AltFire:
MWSH A 0 A_JumpIfInventory("MWS_ItemFlag",1,"AltFire2")
AltFire1:
MWSH A 0 A_JumpIfInventory("KappaMikeyAmmo",3,1)
goto NoAmmo
MWSH B 0 A_GiveInventory("VivifyDelay6",1)
MWSH B 0 A_Refire(1)
MWSH B 0 A_PlaySound("weapon/WaveSummon2",1,0.65)
MWSH B 0 A_TakeInventory("KappaMikeyAmmo",1)
MWSH B 0 A_TakeInventory("KappaMikeyAmmo",2,1)
MWSH B 0 A_FireCustomMissile("MWS_WaterSpoutSpawn",0,0,8,0)
MWSH BC 4
MWSH A 10
MWSH A 0
Goto Ready2


Altfire2:
MWSH C 0 //A_JumpIfInventory("IsUnderWater",1,"Altfire1U")
MWSH A 0 A_JumpIfInventory("KappaMikeyAmmo",6,"Altfire3")
goto NoAmmo
Altfire3:
MWSH BC 2
MWSH C 0 A_PlaySound("weapon/BigRain",1,1.0)
MWSH C 0 A_TakeInventory("KappaMikeyAmmo",3)
MWSH C 0 A_TakeInventory("KappaMikeyAmmo",3,1)
MWSH C 0 A_JumpIfInventory("NoSourcePushFlag",1,"Altfire4")
MWSH CCBBCCBBCCBBCC 1 A_FireCustomMissile("MWS_Water",0,0,8,0)
MWSH C 0 A_JumpIfInventory("PlayerPropertyRage",1,"AltEnd33")
goto AltEnd3
Altfire4:
MWSH CCBBCCBBCCBBCC 1 A_FireCustomMissile("MWS_WaterNoPushPlayer",0,0,8,0)
MWSH C 0 A_JumpIfInventory("PlayerPropertyRage",1,"AltEnd33")
goto AltEnd3
AltEnd3:
MWSH BA 3
MWSH A 10
goto Ready2
AltEnd33:
MWSH BAA 2
goto Ready2

NoAmmo:
MWSH A 0
Goto Ready2

Flash:
TNT1 A 1 A_JumpIfInventory("MWS_ItemFlag",1,"FlashShieldTime")
loop
FlashShieldTime:
MWSH D 0 A_PlaySound("classes/MWS_Shield",4,1.0)
MWSH D 1 A_JumpIfInventory("PlayerPropertyRage",1,1)
MWSH E 1
MWSH F 1 A_JumpIfInventory("PlayerPropertyRage",1,1)
MWSH G 4
MWSH F 1 A_JumpIfInventory("PlayerPropertyRage",1,1)
MWSH E 1
MWSH D 1 A_JumpIfInventory("PlayerPropertyRage",1,1)
MWSH D 0 A_TakeInventory("MWS_ItemHoldIt")
goto FlashShield
FlashShield:
TNT1 A 0 A_JumpIfInventory("PlayerPropertyRage",1,3)
TNT1 A 1 A_SpawnItemEx("MWS_ShieldFX1",0,0,-12,momx,momy,momz,0,1+8)
TNT1 A 0 A_JumpIfInventory("MWS_ItemFlag",1,1)
goto FlashBoom
TNT1 A 1 A_SpawnItemEx("MWS_ShieldFX1",0,0,-12,momx,momy,momz,0,1+8)
TNT1 A 0 A_JumpIfInventory("MWS_ItemFlag",1,1)
goto FlashBoom
TNT1 A 1 A_SpawnItemEx("MWS_ShieldFX1",0,0,-12,momx,momy,momz,0,1+8)
TNT1 A 0 A_JumpIfInventory("MWS_ItemFlag",1,1)
goto FlashBoom
TNT1 A 0 A_JumpIfInventory("PlayerPropertyRage",1,3)
TNT1 A 1 A_SpawnItemEx("MWS_ShieldFX2",0,0,-12,momx,momy,momz,0,1+8)
TNT1 A 0 A_JumpIfInventory("MWS_ItemFlag",1,1)
goto FlashBoom
TNT1 A 1 A_SpawnItemEx("MWS_ShieldFX2",0,0,-12,momx,momy,momz,0,1+8)
TNT1 A 0 A_JumpIfInventory("MWS_ItemFlag",1,1)
goto FlashBoom
TNT1 A 1 A_SpawnItemEx("MWS_ShieldFX2",0,0,-12,momx,momy,momz,0,1+8)
TNT1 A 0 A_GiveInventory("MWSShieldCharge",2)
TNT1 A 0 A_JumpIfInventory("MWS_ItemFlag",1,1)
goto FlashBoom
TNT1 A 0 A_JumpIfInventory("PlayerPropertyRage",1,3)
TNT1 A 1 A_SpawnItemEx("MWS_ShieldFX3",0,0,-12,momx,momy,momz,0,1+8)
TNT1 A 0 A_JumpIfInventory("MWS_ItemFlag",1,1)
goto FlashBoom
TNT1 A 1 A_SpawnItemEx("MWS_ShieldFX3",0,0,-12,momx,momy,momz,0,1+8)
TNT1 A 0 A_JumpIfInventory("MWS_ItemFlag",1,1)
goto FlashBoom
TNT1 A 1 A_SpawnItemEx("MWS_ShieldFX3",0,0,-12,momx,momy,momz,0,1+8)
TNT1 A 0 A_JumpIfInventory("MWS_ItemFlag",1,1)
goto FlashBoom
TNT1 A 0 A_JumpIfInventory("PlayerPropertyRage",1,3)
TNT1 A 1 A_SpawnItemEx("MWS_ShieldFX4",0,0,-12,momx,momy,momz,0,1+8)
TNT1 A 0 A_JumpIfInventory("MWS_ItemFlag",1,1)
goto FlashBoom
TNT1 A 1 A_SpawnItemEx("MWS_ShieldFX4",0,0,-12,momx,momy,momz,0,1+8)
TNT1 A 0 A_JumpIfInventory("MWS_ItemFlag",1,1)
goto FlashBoom
TNT1 A 1 A_SpawnItemEx("MWS_ShieldFX4",0,0,-12,momx,momy,momz,0,1+8)
TNT1 A 0 A_GiveInventory("MWSShieldCharge",2)
TNT1 A 0 A_JumpIfInventory("MWS_ItemFlag",1,"FlashShield")
goto FlashBoom


FlashBoom:

TNT1 A 0 A_PlaySound("classes/ShieldPop",4,1.0)
TNT1 A 0 A_JumpIfInventory("MWS_ItemForceFail",1,3)
TNT1 A 0 A_FireCustomMissile("MWSPush",0,0,0,0)
TNT1 A 0 A_SpawnItemEx("MegaWaterS_PushFX_H",0,0,28)
TNT1 AAAAA 0 A_SpawnItemEx("MWS_WaterSplashFX",0,random(-10,10),16,random(-5,5),random(-5,5),random(2,6),0,1)
TNT1 AAAAA 0 A_SpawnItemEx("MWS_WaterSplashFX",0,random(-10,10),32,random(-5,5),random(-5,5),random(2,6),0,1)
TNT1 AAAAA 0 A_SpawnItemEx("MWS_WaterSplashFX",0,random(-10,10),48,random(-5,5),random(-5,5),random(2,6),0,1)

TNT1 AAAA 1
TNT1 A 0 A_TakeInventory("KappaBarrierAmmo",14)
TNT1 A 0 A_TakeInventory("KappaBarrierAmmo",14,1)
TNT1 A 0 A_TakeInventory("MWSShieldCharge")
TNT1 A 0 A_TakeInventory("MWS_ItemForceFail")
TNT1 A 0 A_TakeInventory("MWS_ItemHoldIt")
goto Flash
}
}

actor KappaMikeyAmmo : Ammo
{
inventory.amount 1
inventory.maxamount 28
+INVENTORY.IGNORESKILL
}

actor KappaBarrierAmmo : Ammo
{
inventory.amount 1
inventory.maxamount 28
+INVENTORY.IGNORESKILL
}

actor MWSShieldCharge : Inventory
{
inventory.amount 1
inventory.maxamount 60
}

actor MWS_ItemFlag : OnceC{}
actor MWS_ItemHoldIt : OnceC{}
actor MWS_ItemForceFail : OnceC{}

actor MWS_ShieldItem : BasicClassItem
{
inventory.icon "MWSHIELD"
inventory.pickupmessage "My shield is better than Pumpman's!"
Tag "MWS Barrier Trigger"
states
{
Spawn:
MWSH I 1
loop
UseCBM:
TNT1 A 0 A_JumpIfInventory("MWS_ItemHoldIt",1,"No")
TNT1 A 1 A_JumpIfInventory("MWS_ItemFlag",1,"Use2")
TNT1 A 1 A_JumpIfInventory("KappaBarrierAmmo",28,"Use1")
fail
Use1:
//TNT1 A 0 //80% slow
TNT1 A 0 A_GiveInventory("MWS_ItemHoldIt",1)
TNT1 A 0 A_GiveInventory("MegaWaterS_BasicArmor_P")
TNT1 A 0 A_GiveInventory("SetDynamicArmorDosage")
TNT1 A 0 A_GiveInventory("MWS_ItemFlag",1)
TNT1 A 0 A_SpawnItemEx("MWS_ShieldWatcher")
fail
Use2:
TNT1 A 0 A_GiveInventory("MWS_ItemHoldIt",1)
TNT1 A 0 A_TakeInventory("MWS_ItemFlag",1)
TNT1 A 0 A_TakeInventory("BasicArmor")
TNT1 A 0 A_TakeInventory("DynamicArmorDosage")
fail
}
}

actor MWS_ShieldWatcher : BasicHelper
{
Args 1
states
{
Spawn:
TNT1 A 0 A_JumpIfInTargetInventory("IsDead",1,"Death")
TNT1 A 1

TNT1 A 0 A_JumpIfInTargetInventory("MWS_ItemFlag",1,2)
TNT1 A 0
goto Death2
TNT1 A 0 A_JumpIfInTargetInventory("MWSShieldCharge",60,"Pressure")
TNT1 A 0 A_JumpIfInTargetInventory("BasicArmor",1,"Spawn")
TNT1 A 0
goto Death3
Pressure:
TNT1 A 0 A_JumpIfInventory("MWSShieldCharge",35,"PressureBuild")//60
TNT1 A 0 A_GiveInventory("MWSShieldCharge",1)
TNT1 A 0 A_JumpIfInTargetInventory("BasicArmor",1,"Spawn")
TNT1 A 0
goto Death3
PressureBuild:
TNT1 A 0 A_SetArg(0,Args[0]*-1)
TNT1 A 0 A_TakeFromTarget("KappaBarrierAmmo",1,(Args[0]==1))
TNT1 A 0 A_TakeInventory("MWSShieldCharge",6-CallACS("core_checkrune",RUNE_RAGE,2)*3)//16-8
TNT1 A 0 A_JumpIfInTargetInventory("KappaBarrierAmmo",1,"Spawn")
TNT1 A 0
goto Death3

Death3:
TNT1 A 0 A_GiveToTarget("MWS_ItemForceFail",1)
goto Death
Death2:
TNT1 A 3
goto Death
Death:
TNT1 A 0 A_TakeFromTarget("BasicArmor")
TNT1 A 0 A_TakeFromTarget("DynamicArmorDosage")
TNT1 A 0 A_TakeFromTarget("MWSShieldCharge",50)
TNT1 A 0 A_TakeFromTarget("MWS_ItemFlag",999)
TNT1 A 1
stop
}
}


actor PainMWS_BarrierHit : Basic_PainFling_H
{
Args 10,0,2
states
{
Spawn:
TNT1 A 0
TNT1 A 0 A_SetArg(0,10+2*CallACS("cbm_countinv_acs_ptr",305,AAPTR_TARGET,AAPTR_TARGET))
goto SpawnCheck
}
}
actor DeathMWS_BarrierHit : Basic_DeathFling_H
{
Args 14,16,0
states
{
Spawn:
TNT1 A 0
TNT1 A 0 A_SetArg(0,14+2*CallACS("cbm_countinv_acs_ptr",305,AAPTR_TARGET,AAPTR_TARGET))
goto Fling
}
}

actor MWSPush : BasicImplosion
{
var int user_P;
damagetype "MWS_Barrier"
Obituary "$OB_MWSPUSH"
States
{
Spawn:
TNT1 A 0
TNT1 A 0 A_SetUserVar("user_P",CallACS("cbm_countinv_acs",305,2))//Max 60
TNT1 A 4 A_Explode(user_P/6*20+90,user_P/6*20+199,0)
stop
}
}

actor MegaWaterS_PushFX_H : BasicHelper
{
States
{
Spawn:
TNT1 A 0 //Transfer MWSShieldCharge as an Angle to spawn FX
TNT1 A 2 A_SpawnItemEx("MegaWaterS_PushFX_H2",0,0,0,0,0,0,CallACS("cbm_countinv_acs",305,2),4)
stop
}
}
actor MegaWaterS_PushFX_H2 : BasicExplosion
{
States
{
Spawn:
TNT1 A 0 //Double spawn to sync online
TNT1 A 1 A_SpawnItemEx("MegaWaterS_PushFX",0,0,0,0,0,0,angle,1+4)
stop
}
}
actor MegaWaterS_PushFX : BasicClientside
{
States
{
Spawn:
TNT1 A 0
TNT1 A 0 A_SetArg(1,Angle)
SpawnL:
TNT1 AAA 0 A_SpawnItemEx("MWS_WaterSplashFX",8,0,random(-10,10),frandom(2+Args[1]*0.1,Args[1]*0.5),0,random(3,8),random(0,359),1)
TNT1 A 0 A_CountDownArg(1)
loop
Death:
TNT1 A 1
stop
}
}


actor MWS_Harpoon : ProjSpawnFuncActor
{
//var int user_P;
PROJECTILE
Damagetype "MWS_Shot"
Obituary "$OB_MWSHARPOON"
+NOGRAVITY
+SKYEXPLODE
+EXPLODEONWATER
damage (90)//(100+user_P*10)
radius 9
height 10
speed 35
scale 2.5
States
{
Spawn:
MWSX K 1
loop
}
}


actor MWS_Water : ProjSpawnFuncActor
{
PROJECTILE
+SKYEXPLODE
+EXPLODEONWATER
+DONTBLAST
+DONTREFLECT
+HITTRACER
RenderStyle Translucent
alpha 0.8
ReactionTime 8
Damage (0)
height 16
radius 16
Speed 40
Scale 1.5
States
{
Spawn:
TNT1 A 1
TNT1 A 0 A_Jump(256,1,4,7)
Spawn2:
MWSX RR 1 A_SpawnItemEx("MWS_WaterFXR",0,0,0,0,0,0,0,1)
MWSX R 0 A_CountDown
MWSX SS 1 A_SpawnItemEx("MWS_WaterFXS",0,0,0,0,0,0,0,1)
MWSX S 0 A_CountDown
MWSX TT 1 A_SpawnItemEx("MWS_WaterFXT",0,0,0,0,0,0,0,1)
MWSX T 0 A_CountDown
Loop

//ACS_NamedExecuteWithResult("cbm_ThrustNearbyPlayers",88,20)
Crash:
XDeath:
TNT1 A 0 A_JumpIfInventory("NoPushFlag",1,"Death",AAPTR_TRACER)
TNT1 A 0 A_JumpIf(CallACS("cbm_istracerenemy"),1)
goto Death
TNT1 A 3 ACS_NamedExecuteWithResult("cbm_MissleThrustThing",AAPTR_TRACER,20,0)
goto Death
Death:
TNT1 A 1 
stop
}
}

actor MWS_WaterNoPushPlayer : MWS_Water
{
States
{
Crash:
XDeath:
//TNT1 A 0 A_JumpIfInventory("NoPushFlag",1,"Death",AAPTR_TRACER)
//TNT1 A 0 A_JumpIf(CallACS("cbm_istracerplayer"),"Death")
//TNT1 A 3 ACS_NamedExecuteWithResult("cbm_MissleThrustThing",AAPTR_TRACER,20,0)
goto Death
}
}



actor MWS_WaterFXR : BasicGraphicEffect
{
alpha 0.8
scale 1.0
States
{
SpawnFrame:
MWSX R 2
stop
}
}

actor MWS_WaterFXS : MWS_WaterFXR
{
States
{
SpawnFrame:
MWSX S 2
stop
}
}

actor MWS_WaterFXT : MWS_WaterFXR
{
States
{
SpawnFrame:
MWSX T 2
stop
}
}


actor MWS_ShieldFX1 : BasicGraphicEffect
{
+NOTIMEFREEZE
renderstyle translucent
alpha 0.5
States
{
SpawnFrame:
MWSX U 1
stop
}
}
actor MWS_ShieldFX2 : MWS_ShieldFX1
{
States
{
SpawnFrame:
MWSX V 1
stop
}
}
actor MWS_ShieldFX3 : MWS_ShieldFX1
{
States
{
SpawnFrame:
MWSX W 1
stop
}
}
actor MWS_ShieldFX4 : MWS_ShieldFX1
{
States
{
SpawnFrame:
MWSX X 1
stop
}
}


actor MWS_WaterSpoutSpawn : FastProjectile
{
+SKYEXPLODE
+EXPLODEONWATER
//+RIPPER
+THRUGHOST
//+THRUACTORS
+DONTBLAST
+DONTREFLECT
RenderStyle None
reactiontime 5
damage (0)
radius 8
height 12
speed 1000
States
{
Spawn:
TNT1 A 0
TNT1 A 1 A_CountDown
loop
Death:
TNT1 A 0 A_SpawnItemEx("MWS_WaterSpout")
stop
XDeath:
TNT1 A 0 A_SpawnItemEx("MWS_WaterSpout",6)
stop

}
}

actor MWS_WaterSpout : ProjSpawnFuncActor
{
PROJECTILE
damagetype "MWS_Lift"
Obituary "$OB_MWSLIFT"
//+NOINTERACTION
+RIPPER
+THRUGHOST
+FLOORHUGGER
+DONTBLAST
+DONTREFLECT
+THRUACTORS
reactiontime 3
damage (0)
radius 4
height 12
scale 0.80
States
{
Spawn:
TNT1 A 0
TNT1 A 0 A_JumpIfCloser(250,26)
TNT1 A 0 //A_LOG("Too far 250")
TNT1 A 0 A_JumpIfCloser(500,20)
TNT1 A 0 //A_LOG("Too far 500")
TNT1 A 0 A_JumpIfCloser(750,13)
TNT1 A 0 //A_LOG("Too far 750")
TNT1 A 0 A_JumpIfCloser(1000,7)
TNT1 A 0 //A_LOG("Too far 1000")
TNT1 A 0 A_PlaySound("weapon/MWS_WaterSlide",1,0.85)
TNT1 AAAAAAAA 1 A_SpawnItemEx("MWS_WaterSplashFX",0,0,4,random(-5,5),random(-5,5),random(5,10),0,1)
TNT1 A 0 A_PlaySound("weapon/MWS_WaterSlide",1,0.85)
TNT1 AAAAAAAA 1 A_SpawnItemEx("MWS_WaterSplashFX",0,0,4,random(-5,5),random(-5,5),random(5,10),0,1)
TNT1 A 0 //A_LOG("Fired")
TNT1 A 1 A_GiveInventory("WeaponCharge",1)
TNT1 AAAAAAAAAAAAAAAA 0 A_SpawnItemEx("MWS_WaterSplashFX",0,0,4,random(-10,10),random(-10,10),15,0,1)
MWSX A 0 A_PlaySound("weapon/WaveSummonGo2",4,0.55)
MWSX A 1 A_SpawnItemEx("MWS_WSpoutLaunchCheck",0,0,32)
MWSX B 0 A_Explode(80,48,0,0,48)
MWSX BCDEFG 1 A_SpawnItemEx("MWS_WSpoutLaunchCheck",0,0,32)
Burst:
MWSX H 0 A_SpawnItemEx("MWS_SpoutDamageF",0,0,35)
MWSX H 0 A_SpawnItemEx("MWS_SpoutDamageF",0,0,70)
MWSX HHIIJJ 1 A_SpawnItemEx("MWS_WSpoutLaunchCheck",0,0,32)
MWSX H 0 A_CountDown
loop
Death:
TNT1 A 1 A_JumpIfInventory("WeaponCharge",1,"RealDeath")
TNT1 A 1
stop
RealDeath:
MWSX GFEDCBA 2
stop
}
}

actor MWS_WSpoutLaunchCheck : BasicHelper
{
+SERVERSIDEONLY
States
{
Spawn:
TNT1 A 0 
TNT1 A 0 A_JumpIfCloser(48,"Thrust")
TNT1 A 1
stop
Thrust:
TNT1 A 0 A_JumpIfInTargetInventory("MWS_SpoutThrust_CD",1,2)
TNT1 A 0 A_GiveToTarget("MWS_WaterSpoutThrust_P")
TNT1 A 1
stop
}
}

actor MWS_SpoutThrust_CD : Powerup
{
Powerup.Duration 20
}

actor MWS_WaterSpoutThrust_P : CustomInventory
{
states
{
Pickup:
TNT1 A 0 A_GiveInventory("MWS_SpoutThrust_CD",1)
TNT1 A 0 A_JumpIf(z-floorz==0,"Ground")
goto Air
Air:
TNT1 A 0 ThrustThingZ(0,52,0,1)
stop
Ground:
TNT1 A 0 ThrustThingZ(0,80,0,0)
stop
}
}

actor MWS_SpoutDamageF : BasicImplosion
{
damagetype "MWS_Lift"
Obituary "$OB_MWSLIFT"
States
{
Spawn:
TNT1 A 0
TNT1 A 1 A_Explode(50,48,0,0,48)
stop
}
}

actor MWS_LiftProtect : PowerProtection
{
Powerup.Duration 14
DamageFactor "MWS_Lift", 0.5
}

actor MWS_WaterSplashFX : BasicGraphicEffectM
{
-NOGRAVITY
+THRUGHOST
+THRUACTORS
speed 25
scale 1.0//1.5
States
{
SpawnFrame:
TNT1 A 0
TNT1 A 0 A_Jump(256,1,2,3,4,5,6)
SpawnL:
MWSX MMNNOO 1 A_FadeOut(0.05)
loop
}
}

actor MegaWaterS_W_NormalBar : NormalBar {Args 218,116}//218,116
actor MegaWaterS_W_SecondBar : SecondBar {Args 204,205}
actor MegaWaterS_W_ScriptBar : ScriptBar {}