actor Mars_W : BaseMM8BDMWep_CBM
{
tag "$TAGC_VD"
Dropitem "PhotonMissileWep"
Weapon.AmmoUse 6
Weapon.AmmoGive 336
Obituary "$OB_MARSCLOSE"
Inventory.Pickupmessage "You become the martian!"
weapon.ammotype "RedPlanetAmmo"
weapon.ammotype2 "CandyBarAmmo"
inventory.icon "MARS_I1"
States
{
Spawn:
C_0V D 1
loop

Deselect:
VH_D A 0
goto DeselectSwap
Select:
VH_D A 0
goto SelectSwap

Ready:
VH_D G 0 A_JumpIfInventory("MarsIsATank",1,"ReadyT")
goto Ready0
ReadyT:
VH_D G 2 Offset(0,24)A_TakeInventory("MarsIsATank",999)
VH_D G 2 Offset(0,16)A_GiveInventory("RedPlanetAmmo",3)
goto Ready0
Ready0:
VH_D A 0 ACS_NamedExecuteWithResult("core_weaponcolor",DYE_MARS)
VH_D A 0 A_GunFlash("Flash",0)
goto Ready1

Ready1:
VH_D A 0 A_JumpIfInventory("RedPlanetAmmo",12,"Ready2")
VH_D A 4 A_WeaponReady(12)
VH_D A 0 A_GiveInventory("RedPlanetAmmo",6)
loop
Ready2:
VH_D A 4 A_WeaponReady(8)
VH_D A 0 A_GiveInventory("RedPlanetAmmo",6)
loop

Fire:
VH_D B 0 A_SetArg(0,CallACS("cbm_countinv_acs",503,0))//MarsSpreadFlag
VH_D B 2 A_GiveInventory("Mars_Fire_P1")
VH_D C 2
goto FireH+2
FireH:
VH_D F 2 A_GiveInventory("Mars_Fire_P1")
VH_D C 2
VH_D D 2 A_GiveInventory("Mars_Fire_P2")
VH_D E 2
VH_D A 0 A_JumpIfNoAmmo(3)
VH_D A 0 A_Refire("FireH")
VH_D A 2
VH_D A 8 A_TakeInventory("PowerMarsIsSlowed")
//VH_D A 0 A_TakeInventory("MarsSpreadFlag")
Goto Ready1

Altfire:
VH_D A 1 A_GiveInventory("CandyBarAmmo",1)
Goto Ready1

Flash:
TNT1 A 1 A_GiveInventory("MarsAltCheckF_P",1)
loop
}
}

actor Mars_W2 : Mars_W
{
tag "$TAGC_VD2"
Weapon.AmmoUse 56
Inventory.Pickupmessage "You become the martian?"
inventory.icon "MARS_I2"
States
{

Deselect:
VH_D A 0
goto DeselectSwap
Select:
VH_D A 0
goto SelectSwap

Ready:
VH_D A 0 A_JumpIfInventory("MarsIsATank",1,"Ready0")
goto ReadyT
ReadyT:
VH_D G 2 Offset(0,16)A_GiveInventory("MarsIsATank",1)
VH_D G 2 Offset(0,24)A_GiveInventory("RedPlanetAmmo",3)
goto Ready0
Ready0:
VH_D G 0 ACS_NamedExecuteWithResult("core_weaponcolor",DYE_MARS)
VH_D G 0 A_GunFlash("Flash",0)
goto Ready1

Ready1:
VH_D G 0 A_JumpIfInventory("RedPlanetAmmo",56,"Ready2")
VH_D G 4 A_WeaponReady(12)
VH_D G 0 A_GiveInventory("RedPlanetAmmo",6)
loop
Ready2:
VH_D G 4 A_WeaponReady(8)
VH_D G 0 A_GiveInventory("RedPlanetAmmo",6)
loop

Fire:
VH_D G 0 A_JumpIfNoAmmo("NoAmmo")
VH_D G 0 A_PlaySoundEx("weapon/marsmissile","Weapon")
VH_D G 0 A_FireCustomMissile("MarsPhotonMissile",0,1,0,32)
VH_D HIJ 2
VH_D K 9
VH_D LM 3
VH_D G 2
Goto Ready1
Altfire:
VH_D G 1 A_GiveInventory("CandyBarAmmo",1)
Goto Ready1
NoAmmo:
VH_D G 1
Goto Ready1

Flash:
TNT1 A 1 A_GiveInventory("MarsTankFlash_P",1)
loop
}
}

actor RedPlanetAmmo : Ammo
{
inventory.amount 1
inventory.maxamount 336
+INVENTORY.IGNORESKILL
}

actor CandyBarAmmo : Ammo
{
inventory.amount 1
inventory.maxamount 28
+INVENTORY.IGNORESKILL
}

actor MarsTankFuel_F : Inventory
{
Inventory.amount 1
Inventory.maxamount 500
}

actor MarsIsATank : Inventory{}

actor MarsSpreadFlag : Inventory
{
Inventory.amount 1
Inventory.maxamount 30
}

actor PowerMarsIsSlowed : PowerSpeed
{
Speed 0.675
powerup.duration 20
+POWERSPEED.NOTRAIL
}

actor MarsMortarIsActive : Powerup
{
Powerup.Duration 9
}
actor MarsRocketThrustBonus : Powerup
{
Powerup.Duration 70
}

actor MarsDelayFlag2 : Powerup
{
Powerup.Duration 2
}

actor MarsDelayFlag5 : Powerup
{
Powerup.Duration 5
}

actor Mars_Fire_P1 : CustomInventory
{
States
{
Pickup:
TNT1 A 0 A_GiveInventory("PowerMarsIsSlowed",1)
TNT1 A 0 A_PlaySoundEx("weapon/marsvulcan","Weapon")
//TNT1 A 0 A_FireCustomMissile("MarsVulcanShot",0,1,8+(random(0,1)*2-1)*random(0,Args[0]),(random(0,1)*2-1)*random(0,Args[0]))
TNT1 A 0 A_FireCustomMissile("MarsVulcanShot",random(-Args[0],Args[0]/2)/3.0,1,8,0,1,random(-Args[0],Args[0])/12.0)
stop
}
}
actor Mars_Fire_P2 : CustomInventory
{
States
{
Pickup:
TNT1 A 0 A_PlaySoundEx("weapon/marsvulcan","Body")
TNT1 A 0 A_FireCustomMissile("MarsVulcanShot",random(-Args[0]/2,Args[0])/3.0,1,-8,0,1,random(-Args[0],Args[0])/12.0)
TNT1 A 0 A_GiveInventory("MarsSpreadFlag",3)
TNT1 A 0 A_JumpIf(Args[0]>=30,3)
TNT1 A 0 A_SetArg(0,Args[0]+3)//Args[0]+(Args[0]>=30)*3
TNT1 A 0 A_JumpIf(Args[0]>=31,2)
TNT1 A 0
stop
TNT1 A 0 A_SetArg(0,30)
stop
}
}



actor MarsTankFuel_F_RC : CustomInventory
{
States
{
Pickup:
TNT1 A 0 A_JumpIfInventory("MarsIsATank",1,"No")
TNT1 A 0 A_GiveInventory("MarsTankFuel_F",1+CallACS("core_checkrune",RUNE_RAGE))
stop
No:
TNT1 A 0
stop
}
}

actor MarsAltCheckF_P : CustomInventory
{
States
{
Pickup:
TNT1 A 0 A_JumpIfInventory("MarsIsATank",1,2)
TNT1 A 0 A_GiveInventory("MarsTankFuel_F",1+CallACS("core_checkrune",RUNE_RAGE))
TNT1 A 0 A_JumpIfInventory("PowerMarsIsSlowed",1,2)
TNT1 A 0 A_TakeInventory("MarsSpreadFlag",1)
//TNT1 A 0 A_GiveInventory("MarsTankFuel_F_RC",1)
TNT1 A 0 A_JumpIfInventory("MarsMortarIsActive",1,"No")
TNT1 A 0 A_JumpIfInventory("CandyBarAmmo",28,"Pickup_C")
goto Give
Pickup_C:
TNT1 A 0 A_JumpIf(CallACS("cbm_GetPointerButtonInput",0,true) & BT_ALTATTACK,"P_Fire")
stop
P_Fire:
TNT1 A 0 A_GiveInventory("MarsMortarIsActive",1)
TNT1 A 0 A_SpawnItemEx("MarsMortarSpawner")
stop
Give:
TNT1 A 0 A_JumpIfInventory("MarsDelayFlag5",1,"No")
TNT1 A 0 A_GiveInventory("MarsDelayFlag5",1)
TNT1 A 0 A_GiveInventory("CandyBarAmmo",1+CallACS("core_checkrune",RUNE_RAGE))
stop
No:
TNT1 A 0
stop
}
}

actor MarsTankFlash_P : CustomInventory
{
States
{
Pickup:
TNT1 A 0 A_GiveInventory("MarsAltCheckF_P",1)
TNT1 A 0 A_GiveInventory("MarsTankSnd_P",1)
TNT1 A 0 A_JumpIfInventory("PlayerPropertyRage",1,3)
TNT1 A 0 A_JumpIfInventory("MarsDelayFlag2",1,"No")
TNT1 A 0 A_GiveInventory("MarsDelayFlag2",1)
TNT1 A 0 A_GiveInventory("MarsTankThrust_P",1)
stop
No:
TNT1 A 0
stop
}
}

actor MarsTankThrust_P : CustomInventory
{
States
{
Pickup:
TNT1 A 0 A_SpawnItemEx("MarsTankExhaustFX",Random(-20,-10),Random(30,20),Random(60,70),frandom(-2,0),frandom(-1,1),frandom(4,5),0,1,64)
TNT1 A 0 A_SpawnItemEx("MarsTankExhaustFX",Random(-20,-10),Random(-30,-20),Random(60,70),frandom(-2,0),frandom(-1,1),frandom(4,5),0,1,64)

TNT1 A 0 A_JumpIf(CallACS("cbm_FetchInputDir",0)>0,"Pickup_Forward")
TNT1 A 0 A_JumpIf(CallACS("cbm_FetchInputDir",0)<0,"Pickup_Back")
goto Pickup_None
Pickup_None:
TNT1 A 0
stop
Pickup_Forward:
TNT1 A 0 A_GiveInventory("MarsFloorFX_P",1)
TNT1 A 0 A_GiveInventory("MarsTankThrustCheckF_P",1)
stop
Pickup_Back:
TNT1 A 0 A_GiveInventory("MarsFloorFX_P",1)
TNT1 A 0 A_GiveInventory("MarsTankThrustCheckB_P",1)
stop
}
}
actor MarsTankThrustCheckF_P : CustomInventory
{
States
{
Pickup:
TNT1 A 0 A_JumpIfInventory("MarsTankFuel_F",1,"Pickup2")
TNT1 A 0 A_JumpIfInventory("MarsRocketThrustBonus",1,"GroundW")
TNT1 A 0 A_JumpIf(z-floorz==0,"GroundW")
TNT1 A 0 A_JumpIf(1,"AirW")
stop
Pickup2:
TNT1 A 0 A_JumpIfInventory("MarsRocketThrustBonus",1,"Ground")
TNT1 A 0 A_JumpIf(z-floorz==0,"Ground")
TNT1 A 0 A_JumpIf(1,"Air")
stop
Air:
TNT1 A 0 A_Recoil(-1.25)
goto End
AirW:
TNT1 A 0 A_Recoil(-0.5)
goto End
Ground:
TNT1 A 0 A_Recoil(-1.5)
goto End
GroundW:
TNT1 A 0 A_Recoil(-0.75)
goto End
End:
TNT1 A 0 A_TakeInventory("MarsTankFuel_F",2)
stop
}
}
actor MarsTankThrustCheckB_P : MarsTankThrustCheckF_P
{
States
{
Air:
TNT1 A 0 A_Recoil(0.3125)//1.25
goto End
AirW:
TNT1 A 0 A_Recoil(0.125)//0.5
goto End
Ground:
TNT1 A 0 A_Recoil(0.375)//1.5
goto End
GroundW:
TNT1 A 0 A_Recoil(0.1875)//0.75
goto End
}
}

actor MarsTankSnd_P : CustomInventory
{
States
{
Pickup:
TNT1 A 0 A_JumpIfInventory("VivifyDelay5",1,3)
TNT1 A 0 A_GiveInventory("VivifyDelay5",1)
TNT1 A 0 A_PlaySound("weapon/darktread",4,0.68)
TNT1 A 0
stop
}
}

actor MarsFloorFX_P : CustomInventory
{
States
{
Pickup:
TNT1 A 0 A_JumpIfInventory("VivifyDelay4",1,2)
TNT1 A 0 A_CheckFloor("Pickup_F")
TNT1 A 0 //Haunted online
stop
Pickup_F:
TNT1 A 0 A_GiveInventory("VivifyDelay4",1)
TNT1 A 0 A_SpawnItemEx("MarsTankDustFX",-2, 14,0,-2,0,0,0,1+128)
TNT1 A 0 A_SpawnItemEx("MarsTankDustFX",-2,-14,0,-2,0,0,0,1+128)
stop
}
}

actor MarsVulcanShot : ProjSpawnFuncActorFast
{
PROJECTILE
damagetype "Mars_Shot"
Obituary "$OB_MARSVULCAN"
Damage (70)
radius 8
height 6
Speed 1//120
scale 2.5
States
{
Spawn:
TNT1 A 0
VP_D Q 0 A_SpawnItemEx("MarsVulcanShot2",0,0,0,momx*120,momy*120,momz*120,0,8)
VP_D Q 0
stop
Death:
VP_D STU 2
stop
}
}

actor MarsVulcanShot2 : MarsVulcanShot
{
ReactionTime 1
Speed 120
States
{
Spawn:
TNT1 A 0
VP_D Q 1 //A_SpawnItemEx("MarsVulcanShotFX",0,0,0,momx*0.1,momy*0.1,momz*0.1,0,8)
VP_D QQQQ 1 A_SpawnItemEx("MarsVulcanShotFX_H",0,0,0,momx*0.1,momy*0.1,momz*0.1,0,8)
VP_D Q 0 A_SpawnItemEx("MarsVulcanShotFX_H",0,0,0,momx*0.1,momy*0.1,momz*0.1,0,8)
VP_D Q 1 A_CountDown
wait
}
}

actor MarsVulcanShotFX_H : BasicGraphicEffect
{
ReactionTime 3
States
{
SpawnFrame:
TNT1 A 0
TNT1 A 0 A_SetPitch(pitch+1)
TNT1 A 0 A_SpawnItemEx("MarsVulcanShotFX",0,0,0,momx*(-pitch*5),momy*(-pitch*5),momz*(-pitch*5),0,8)
TNT1 A 0 A_CountDown
loop
}
}

actor MarsVulcanShotFX : BasicGraphicEffect
{
Alpha 0.65
Speed 100
States
{
SpawnFrame:
VP_D R 0
VP_D R 1 A_Stop
VP_D R 0 A_SetScale(ScaleX+0.25)
VP_D R 1 A_FadeOut(0.15)
VP_D R 0 A_SetScale(ScaleX+0.25)
VP_D R 1 A_FadeOut(0.15)
stop
}
}

actor MarsPhotonMissile : ProjSpawnFuncActor
{
PROJECTILE
damagetype "Mars_Photon"
Obituary "$OB_MARSMISSILE"
+RIPPER
+THRUGHOST
+SKYEXPLODE
+EXPLODEONWATER
ReactionTime 1
Damage (50)
radius 9
height 8
Speed 45
scale 2.5
States
{
Spawn:
VP_D C 0
VP_D C 0 A_PlaySoundEX("weapon/marsmissiletravel","Weapon")
VP_D CDECDE 2
//VP_D C 2 A_ScaleVelocity(0.8)//48
//VP_D D 2 A_ScaleVelocity(0.6)//28.8
//VP_D E 2 A_ScaleVelocity(0.4)//11.52
VP_D C 1 A_CountDown
wait
Death:
TNT1 A 0 A_PlaySoundEx("weapon/marsmortarboom","Weapon")
TNT1 A 0 A_Explode(200+((reactiontime == 0)*50),128,0,0,48)
TNT1 A 0 A_SpawnItemEx("MarsPhotonMissileFX",0,0,0,0,0,0,0,1)
TNT1 A 0
TNT1 A 0 A_JumpIfInTargetInventory("MarsTankFuel_F",1,"DeathBoost")
TNT1 A 0 A_JumpIf(!CallACS("cbm_MarsRocketJump",11,128,-64),"DeathGive")
goto DeathWait
DeathBoost:
TNT1 A 0 A_JumpIf(!CallACS("cbm_MarsRocketJump",22,128,-64),"DeathGive")
goto DeathWait
DeathGive:
TNT1 A 0 A_TakeFromTarget("MarsTankFuel_F",33)
TNT1 A 1 A_GiveToTarget("MarsRocketThrustBonus",1)
goto DeathWait
DeathWait:
TNT1 A 10
stop
}
}

actor MarsPhotonMissileFX : BasicGraphicEffect
{
+FORCEXYBILLBOARD
+BRIGHT
States
{
SpawnFrame:
TNT1 A 0
TNT1 A 0 A_Jump(256,"Spawn1","Spawn2")
Spawn1:
Q_VD JKLMNOPQRS 1
stop
Spawn2:
Q_VD JKTUVWXYZS 1
stop
}
}

actor MarsTankExhaustFX : BasicGraphicEffectM
{
+THRUACTORS
States
{
SpawnFrame:
//SMFX XYZ 3
TNT1 A 0
VH_D SSTTUUVV 1 ThrustThingZ(0,random(2,4),0,1)
stop
}
}

actor MarsTankDustFX : BasicGraphicEffect
{
Scale 1.0
States
{
SpawnFrame:
HSHG STU 5
stop
}
}



actor Mars_Alt_P : CustomInventory
{
States
{
Pickup:
TNT1 A 0 A_FireCustomMissile("MarsMortar_H",0,0,0,0)
TNT1 A 0 A_PlaySound("weapon/GrenadeShot",7,1)
stop
}
}

actor MarsMortarSpawner : BasicHelper
{
+NOTIMEFREEZE
ReactionTime 4
States
{
Spawn:
TNT1 A 0
TNT1 A 0 A_JumpIf(!CallACS("cbm_PointerExists",AAPTR_TARGET),"Death")
TNT1 A 0 A_GiveToTarget("Mars_Alt_P")
TNT1 A 0 A_GiveToTarget("MarsMortarIsActive",1)
TNT1 A 0 A_TakeFromTarget("CandyBarAmmo",3)
TNT1 A 0 A_TakeFromTarget("CandyBarAmmo",4,1)
TNT1 A 1
TNT1 A 1 A_JumpIfInventory("PlayerPropertyRage",1,1,2)
TNT1 A 1
TNT1 A 1 A_JumpIfInventory("PlayerPropertyRage",1,1,2)
TNT1 A 1
TNT1 A 1 A_JumpIfInventory("PlayerPropertyRage",1,1,2)
TNT1 A 1 A_CountDown
loop
}
}

actor MarsMortar_H : BasicHelper
{
+NOTIMEFREEZE
States
{
Spawn:
TNT1 A 0
TNT1 A 0 //A_SpawnItemEx("MarsMortar",11,random(-11,11),28,frandom(2,5),frandom(0,1),frandom(15,16),random(0,17)*5,1)
TNT1 A 0 //A_SpawnItemEx("MarsMortar",11,random(-11,11),28,frandom(2,5),frandom(0,1),frandom(15,16),random(18,35)*5,1)
TNT1 A 0 //A_SpawnItemEx("MarsMortar",11,random(-11,11),28,frandom(2,5),frandom(-1,0),frandom(15,16),random(36,53)*5,1)
TNT1 A 0 //A_SpawnItemEx("MarsMortar",11,random(-11,11),28,frandom(2,5),frandom(-1,0),frandom(15,16),random(54,71)*5,1)
TNT1 A 0

TNT1 A 0 A_SpawnItemEx("MarsMortar",11,random(-11,11),28,frandom(6,10),frandom(0.1,4.5),frandom(15,16),frandom(-3,3))
TNT1 A 0 A_SpawnItemEx("MarsMortar",11,random(-11,11),28,frandom(10,14),frandom(0.1,4.5),frandom(15,16),frandom(-3,3))
TNT1 A 0 A_SpawnItemEx("MarsMortar",11,random(-11,11),28,frandom(6,10),frandom(-4.5,-0.1),frandom(15,16),frandom(-3,3))
TNT1 A 0 A_SpawnItemEx("MarsMortar",11,random(-11,11),28,frandom(10,14),frandom(-4.5,-0.1),frandom(15,16),frandom(-3,3))

TNT1 A 4
stop
}
}

actor MarsMortar : ProjSpawnFuncActor
{
PROJECTILE
damagetype "Mars_Mortar"
Obituary "$OB_MARSMORTAR"
-NOGRAVITY
+BOUNCEONWALLS
+BOUNCEONCEILINGS
+USEBOUNCESTATE
+SKYEXPLODE
+DONTREFLECT
//+DONTSPLASH
BounceFactor 1.0
BounceCount 4
Damage (0)
Height 8
Radius 8
Speed 20
scale 2.5
States
{
Spawn:
VP_D G 0
VP_D G 1 A_JumpIf(velz<=4,6)
VP_D G 1 A_JumpIf(velz<=4,6)
VP_D G 1 A_JumpIf(velz<=4,6)
VP_D H 1 A_JumpIf(velz<=4,6)
VP_D H 1 A_JumpIf(velz<=4,6)
VP_D H 1 A_JumpIf(velz<=4,6)
loop
Spawn2:
VP_D I 1 A_JumpIf(velz<=0,"Spawn3_1")
VP_D I 1 A_JumpIf(velz<=0,"Spawn3_2")
VP_D I 1 A_JumpIf(velz<=0,"Spawn3_3")
VP_D J 1 A_JumpIf(velz<=0,"Spawn3_4")
VP_D J 1 A_JumpIf(velz<=0,"Spawn3_5")
VP_D J 1 A_JumpIf(velz<=0,"Spawn3_6")
loop

Bounce.Ceiling:
VP_D K 0 A_ChangeFlag("USEBOUNCESTATE",0)
VP_D K 0 A_ChangeFlag("BOUNCEONCEILINGS",0)
VP_D K 0 A_ChangeVelocity(momx,momy,0,2)
VP_D K 0 A_PlaySound("weapon/marsmortarfly",1,0.45)
goto Spawn3

Spawn3_1:
VP_D K 0 A_ChangeFlag("BOUNCEONCEILINGS",0)
VP_D K 0 A_PlaySound("weapon/marsmortarfly",1,0.45)
goto Spawn3
Spawn3_2:
VP_D K 0 A_ChangeFlag("BOUNCEONCEILINGS",0)
VP_D K 0 A_PlaySound("weapon/marsmortarfly",1,0.45)
goto Spawn3+1
Spawn3_3:
VP_D K 0 A_ChangeFlag("BOUNCEONCEILINGS",0)
VP_D K 0 A_PlaySound("weapon/marsmortarfly",1,0.45)
goto Spawn3+2
Spawn3_4:
VP_D L 0 A_ChangeFlag("BOUNCEONCEILINGS",0)
VP_D L 0 A_PlaySound("weapon/marsmortarfly",1,0.45)
goto Spawn3+3
Spawn3_5:
VP_D L 0 A_ChangeFlag("BOUNCEONCEILINGS",0)
VP_D L 0 A_PlaySound("weapon/marsmortarfly",1,0.45)
goto Spawn3+4
Spawn3_6:
VP_D L 0 A_ChangeFlag("BOUNCEONCEILINGS",0)
VP_D L 0 A_PlaySound("weapon/marsmortarfly",1,0.45)
goto Spawn3+5
Spawn3:
VP_D K 1 A_JumpIf(velz<=-4,6)
VP_D K 1 A_JumpIf(velz<=-4,6)
VP_D K 1 A_JumpIf(velz<=-4,6)
VP_D L 1 A_JumpIf(velz<=-4,6)
VP_D L 1 A_JumpIf(velz<=-4,6)
VP_D L 1 A_JumpIf(velz<=-4,6)
loop
Spawn4:
VP_D M 1 A_JumpIf(velz<=-7,6)
VP_D M 1 A_JumpIf(velz<=-7,6)
VP_D M 1 A_JumpIf(velz<=-7,6)
VP_D N 1 A_JumpIf(velz<=-7,6)
VP_D N 1 A_JumpIf(velz<=-7,6)
VP_D N 1 A_JumpIf(velz<=-7,6)
loop
Spawn5:
VP_D OOOPPP 1
loop

Death:
TNT1 A 0 A_SetGravity(0.0)
TNT1 A 0 A_PlaySound("weapon/marsmortarboom",1,0.45)
TNT1 A 0 A_Explode(100,80,0,0,30)
OMFX CBOM 2 bright
stop
}
}

actor Mars_W_NormalBar : NormalBar {Args 229,199}
actor Mars_W_SecondBar : SecondBar {Args 210,42}
actor Mars_W_ScriptBar : ScriptBar {}
actor Mars_W2_NormalBar : NormalBar {Args 229,199}
actor Mars_W2_SecondBar : SecondBar {Args 210,42}
actor Mars_W2_ScriptBar : ScriptBar {}