ACTOR AlphaNemesis : DoomWeapon
{
Weapon.Selectionorder 2000
+NOAUTOFIRE
+WEAPON.BFG
+WEAPON.NOAUTOAIM
-INVENTORY.UNDROPPABLE
Weapon.PreferredSkin "Nemesis-Marine"
Weapon.AmmoUse 0
Weapon.AmmoUse2 0
Weapon.AmmoGive 600
Weapon.AmmoType "DemonAmmo"
Weapon.AmmoType2 "DemonAmmo"
Weapon.Kickback 120
Weapon.UpSound "NemesisUp"
Weapon.ReadySound ""
AttackSound ""
Inventory.PickupSound "NemesisGet"
Inventory.PickupMessage "Alpha Nemesis"
Obituary "%o got unmade by %k."
Tag "Alpha Nemesis"
States
	{
	Spawn:
		AUNM Z -1 Bright
		Loop
	Ready:
		TNT1 A 0
		TNT1 A 0 A_JumpIfInventory("DemonAmmo",1,"Ready1")
		TNT1 AAA 0 A_StopSound(CHAN_BODY)
		Goto Ready2
	Ready1:
		TNT1 A 0 A_PlaySound("NemesisReady",CHAN_BODY,0.5,1)
	Ready2:
		AUNM A 1 A_WeaponReady
		Loop
	Deselect:
		TNT1 A 0
		TNT1 A 0 A_TakeInventory("HandGrenadeAction",1)
		TNT1 A 0 A_TakeInventory("MineAction",1)
		TNT1 A 0 A_TakeInventory("RailgunAction",1)
		TNT1 AAA 0 A_StopSound(CHAN_BODY)
		TNT1 A 0 A_PlaySound("weapons/weapondown",CHAN_WEAPON,1.0,0)
	DeselectLoop:
		AUNM A 1 A_Lower
		Loop
	Select:
		TNT1 A 0
		TNT1 A 0 A_JumpIfInventory("DemonAmmo",1,"Select1")
		TNT1 AAA 0 A_StopSound(CHAN_BODY)
		Goto Select2
	Select1:
		TNT1 A 0 A_PlaySound("NemesisReady",CHAN_BODY,0.5,1)
	Select2:
		AUNM A 1 A_Raise
		Loop
	Fire:
		TNT1 A 0
		TNT1 A 0 A_JumpIfNoAmmo("Ready")
		TNT1 A 0 A_JumpIfInventory("DemonAmmo",1,1)
		Goto Ready
		TNT1 A 0
		TNT1 A 0 A_PlaySound("NemesisFire",CHAN_WEAPON,1.0,0)
		TNT1 A 0 A_TakeInventory("DemonAmmo",1)
		TNT1 A 0 A_SpawnItemEx("NemesisFireFlare",8,0,32)
		AUNM D 1 Bright A_FireCustomMissile("NemesisPlasma",0,0,0,6)
		AUNM D 1 Bright A_GunFlash
		TNT1 A 0 A_JumpIf(ACS_NamedExecuteWithResult("Hem_GetCurrentHealth")-1 < 1,2)
		TNT1 A 0 ACS_NamedExecuteAlways("Hem_SetCurrentHealth",0,ACS_NamedExecuteWithResult("Hem_GetCurrentHealth")-1)
		AUNM B 1 A_Recoil(3)
		AUNM C 1
		AUNM E 1
		AUNM C 1
		AUNM B 1
		AUNM A 9
		TNT1 A 0 A_ReFire
		Goto Ready
	AltFire:
		TNT1 A 0
		TNT1 A 0 A_JumpIfNoAmmo("Ready")
		TNT1 A 0 A_JumpIfInventory("DemonAmmo",100,"AltFire1")
		Goto Ready
	AltFire1:
		TNT1 A 0
		TNT1 AAA 0 A_StopSound(CHAN_BODY)
		TNT1 A 0 A_PlaySound("NemesisAltFire",CHAN_WEAPON,1.0,0)
		AUNM D 1 Bright A_TakeInventory("DemonAmmo",100)
		AUNM D 1 Bright A_GunFlash
		TNT1 A 0 A_SpawnItemEx("NemesisFireFlare",8,0,32)
		TNT1 A 0 A_FireCustomMissile("NemesisPlasmaSpread",-1,0,0,6,0,-1)
		TNT1 A 0 A_FireCustomMissile("NemesisPlasmaSpread",1,0,0,6,0,1)
		TNT1 A 0 A_FireCustomMissile("NemesisPlasmaSpread",0,0,0,6,0,0)
		TNT1 A 0 A_FireCustomMissile("NemesisPlasmaSpread",1,0,0,6,0,-1)
		TNT1 A 0 A_FireCustomMissile("NemesisPlasmaSpread",-1,0,0,6,0,1)
		TNT1 A 0 A_JumpIf(ACS_NamedExecuteWithResult("Hem_GetCurrentHealth")-6 < 1,2)
		TNT1 A 0 ACS_NamedExecuteAlways("Hem_SetCurrentHealth",0,ACS_NamedExecuteWithResult("Hem_GetCurrentHealth")-6)
		AUNM B 5 Bright A_Recoil(9)
		AUNM C 5 Bright
		AUNM EFJIHGKGHIJFECBA 4
		TNT1 A 0 A_ReFire
		Goto Ready
	Flash:
		TNT1 A 5 A_Light1
		TNT1 A 10 A_Light2
		TNT1 A 7 A_Light1
		TNT1 A 5 A_Light0
		Stop
	}
}

// Credits
// Sprites : Scuba Steve


