ACTOR ZombieWithNemesis : ToxicZombie
{
//Creator: Complex Doom CF 3.0 team
//Origin: Complex Doom CF 3.0 Aprilfools
//Sprite: ZOMN
//Title: "Nemesis Zombie"
Health 1000
Mass 500
Scale 1.15
Speed 8
PainChance 10
Damagefactor "SatanGuard", 0.0
DropItem "LifeEssence", 185, 15
DropItem "HEMArmorBonusMax10", 135
DropItem "PortableMedkit", 200
DropItem "HealthFlask", 250, 6
DropItem "ArmorPlate", 100
DropItem "HandGrenadeAmmo", 60, 1
DropItem "MineAmmo", 25, 1
DropItem "AmmoPack", 125
DropItem "Nemesis", 10, 1
DropItem "DemonAmmoBox", 200
Obituary "%o was unmade by a Zombie weilding a Nemesis."
Tag "Nemesis Zombie"
States
{
  Spawn:
	ZOMN A 10 A_Look
	ZOMN "Z" 10 A_Look
	Loop
  Idle:
	ZOMN AAAAAA 1 A_Wander
	TNT1 A 0 A_Look
	ZOMN BBBBBB 1 A_Wander
	TNT1 A 0 A_Look
	TNT1 A 0 HealThing(1)
	TNT1 A 0 A_SpawnItemEx("FootStep2",0,0,2,0,0,-20)
	ZOMN CCCCCC 1 A_Wander
	TNT1 A 0 A_Look
	ZOMN DDDDDD 1 A_Wander
	TNT1 A 0 A_Look
	TNT1 A 0 HealThing(1)
	TNT1 A 0 A_SpawnItemEx("FootStep2",0,0,2,0,0,-20)
	Loop
  See:
	ZOMN AAAAAABBBBBB 1 A_Chase
	TNT1 A 0 A_SpawnItemEx("FootStep2",0,0,2,0,0,-20)
	ZOMN CCCCCCDDDDDD 1 A_Chase
	TNT1 A 0 HealThing(1)
	TNT1 A 0 A_SpawnItemEx("FootStep2",0,0,2,0,0,-20)
	Loop
  Missile:
	TNT1 A 0 A_Jump(64,"SuperNemesisPlasma")
	ZOMN EEEEE 5 A_FaceTarget
	TNT1 A 0 A_PlaySound("NemesisFire",1,1.0,0,0.5)
	ZOMN F 10 Bright A_CustomMissile("MonsterNemesisPlasma",32,0,0)
	ZOMN E 20
	Goto See
  SuperNemesisPlasma:
	ZOMN EEEEEEEE 5 A_FaceTarget
	TNT1 A 0 A_PlaySound("NemesisAltFire",1,1.0,0,ATTN_NONE)
	ZOMN F 10 Bright A_CustomMissile("MonsterNemesisPlasmaSpread",32,0,0)
	ZOMN E 20
	Goto See
  Pain:
	TNT1 A 0
	ZOMN G 6 A_Pain
	Goto See
  Death:
	ZOMN H 5 A_Scream
	ZOMN I 5 A_Fall
	ZOMN J 5 A_SpawnItem("BodyCrash",0,0,0,0)
	ZOMN KLM 5
	ZOMN N 63000 CanRaise
	Stop
  XDeath:
	ZOMN O 3 A_SpawnItemEx("GibbedGenerator",0,0,0,0,0,0,0,128,0)
	ZOMN P 3 A_XScream
	TNT1 A 0 A_GiveInventory("XDeathCheck",1)
	ZOMN Q 3 A_Fall
	ZOMN RSTUV 3
	ZOMN W 63000 CanRaise
	Stop
  Raise:
	TNT1 A 0
	TNT1 A 0 A_SpawnItemEx("VileHealEffect",0,0,0,0,0,0,0,SXF_NOCHECKPOSITION)
	TNT1 A 0 A_JumpIfInventory("XDeathCheck",1,"XRaise")
	ZOMN TSRQPO 5
	Goto See
  XRaise:
	TNT1 A 0
	TNT1 A 0 A_TakeInventory("XDeathCheck",1)
	ZOMN VUTSRQPO 4
	Goto See
	}
}

Actor MonsterNemesisPlasma : NemesisPlasma
{
Species "SatanGuard"
Damagetype "SatanGuard"
States
{
  Spawn:
	TNT1 A 0
	TNT1 A 0 A_PlaySound("NemesisPlasmaFly",CHAN_VOICE,1.0,1)
	TNT1 A 0 A_SetUserVar("user_chance",0)
	TNT1 A 0 A_SetUserVar("user_lcount",0)
	NMPR A 1 Bright A_SpawnItemEx("NemesisPlasmaTrailFX-A",0,0,0,0,0,0,0,SXF_NOCHECKPOSITION|SXF_CLIENTSIDE)
	NMPR B 1 Bright A_SpawnItemEx("NemesisPlasmaTrailFX-B",0,0,0,0,0,0,0,SXF_NOCHECKPOSITION|SXF_CLIENTSIDE)
	NMPR A 1 Bright A_SpawnItemEx("NemesisPlasmaTrailFX-A",0,0,0,0,0,0,0,SXF_NOCHECKPOSITION|SXF_CLIENTSIDE)
	NMPR B 1 Bright A_SpawnItemEx("NemesisPlasmaTrailFX-B",0,0,0,0,0,0,0,SXF_NOCHECKPOSITION|SXF_CLIENTSIDE)
	NMPR A 1 Bright A_SpawnItemEx("NemesisPlasmaTrailFX-A",0,0,0,0,0,0,0,SXF_NOCHECKPOSITION|SXF_CLIENTSIDE)
	NMPR B 1 Bright A_SpawnItemEx("NemesisPlasmaTrailFX-B",0,0,0,0,0,0,0,SXF_NOCHECKPOSITION|SXF_CLIENTSIDE)
  SpawnLoop:
	NMPR A 1 Bright A_Weave(user_lcount,user_lcount,2.0,1.0)
	TNT1 A 0 A_SpawnItemEx("NemesisPlasmaTrailFX-A",0,0,0,0,0,0,0,SXF_NOCHECKPOSITION|SXF_CLIENTSIDE)
	TNT1 A 0 A_SpawnItemEx("MonsterNemesisPlasmaSpray",0,0,0,velx*0.9,vely*0.9,(velz+random(-3,3))*0.9,angle+random(-11,11),SXF_TRANSFERPITCH | SXF_SETMASTER,user_chance)
	NMPR B 1 Bright A_Weave(user_lcount,user_lcount,2.0,1.0)
	TNT1 A 0 A_SpawnItemEx("NemesisPlasmaTrailFX-B",0,0,0,0,0,0,0,SXF_NOCHECKPOSITION|SXF_CLIENTSIDE)
	TNT1 A 0 A_SpawnItemEx("MonsterNemesisPlasmaSpray",0,0,0,velx*0.9,vely*0.9,(velz+random(-3,3))*0.9,angle+random(-11,11),SXF_TRANSFERPITCH | SXF_SETMASTER,user_chance)
	TNT1 A 0 A_JumpIf(user_lcount > 100,2)
	TNT1 A 0 A_SetUserVar("user_lcount",user_lcount+1)
	TNT1 A 0 A_JumpIf(user_chance > 255,"SpawnLoop")
	TNT1 A 0 A_SetUserVar("user_chance",user_chance+1)
	Loop
  Death:
	TNT1 A 0
	TNT1 AAA 0 A_StopSound(CHAN_VOICE)
  Fade:
	NMPR AB 1 Bright A_FadeOut(0.3,1)
	Loop
  Crash:
  XDeath:
	TNT1 A 0
	TNT1 AAA 0 A_StopSound(CHAN_VOICE)
	TNT1 A 0 A_PlaySound("NemesisPlasmaImpact",CHAN_BODY,1.0)
	NMPR CDEEFFGGHHH 1 Bright A_FadeOut(0.1,1)
	Stop
	}
}