Actor OneHundredTen
{
//Creator: Titanium
//Origin: Complex-MM
//Sprite: PASK
//Title: "110" 
Health 500
Radius 20
Height 56
Mass 500
Speed 9
PainChance 100
PainChance "SoulToxic", 25
PainChance "FatFlamer", 25
PainChance "FiendFire", 25
Scale 0.85
Obituary "%o has been devided by 110's BFG10K plasma."
Hitobituary "%o tried to fight melee with 110."
SeeSound "heavynant/sight"
PainSound "heavynant/pain"
DeathSound "heavynant/die"
ActiveSound "heavynant/active"
DropItem "LifeEssence"
DropItem "ArmorBonusMax"
Species "Skeletons"
MONSTER
DamageFactor "CadaverRocket", 0
+LONGMELEERANGE
+MISSILEMORE
+FASTMELEE
Tag "\c[o9]110\c-"
States
{
  Spawn:
    PASK AB 10 A_Look
    Loop
  See:
    PASK AAABBBCCC 2 A_Chase
	TNT1 A 0 A_SpawnItem("BonyStep",0,0,0,0)
	PASK DDDEEEFFF 2 A_Chase
	TNT1 A 0 A_SpawnItem("BonyStep",0,0,0,0)
    Loop
  Melee:
    PASK G 1 A_FaceTarget
    PASK G 6 A_SkelWhoosh
	TNT1 A 0 A_Recoil(-5)
    PASK H 6 A_FaceTarget
    PASK I 6 A_SkelFist
    Goto See
  Missile:
	TNT1 A 0 A_PlaySound("weapons/charge15k")
    PASK J 20 A_FaceTarget
	PASK K 5 A_FaceTarget
    PASK K 7 Bright A_CustomMissile("10015KBall", 60, 0, random(-4,4),0) 
	PASK K 5 A_FaceTarget
    PASK K 7 Bright A_CustomMissile("10015KBall", 60, 0, random(-4,4),0) 
	PASK K 5 A_FaceTarget
    PASK K 7 Bright A_CustomMissile("10015KBall", 60, 0, random(-4,4),0) 
    PASK K 10 A_FaceTarget
    Goto See
  Pain:
    PASK L 5
    PASK L 5 A_Pain
    Goto See
  Death:
    PASK LM 7
    PASK N 7 A_Scream
    PASK O 7 A_NoBlocking
    PASK P 7 A_SpawnItem("BodyCrash",0,0,0,0)
    PASK Q -1
    Stop
  Raise:
	TNT1 A 0
	TNT1 A 0 A_SpawnItemEx("VileHealEffect",0,0,0,0,0,0,0,SXF_NOCHECKPOSITION)
    PASK Q 5
    PASK PONML 5
    Goto See
  }
}

Actor 10015KBall : BFG15KBall
{
	DamageType "CadaverRocket"
}