ACTOR SuicideDog //For your overwhelmingly monstrous behavior, you have become vilified by PETA
{
//Creator: Fluffy
//Origin: Complex Doom CF 3.0 April Fools
//Sprite: SNZD
//Title: "Suicide Doggo"
MONSTER
Health 45
Height 36
Radius 14
Speed 11
Scale 1.1
MeleeDamage 6
+FLOORCLIP
+FASTER
+FASTMELEE
+LONGMELEERANGE
-CANUSEWALLS
+DONTHARMSPECIES
Species "SS"
Damagetype "SS"
Damagefactor "SS", 0.0
SeeSound "suicidedoge/see"
MeleeSound "NULL"
Activesound "suicidedoge/active"
DeathSound "suicidedoge/death"
PainSound "suicidedoge/hurt"
DropItem "LifeEssence", 128
DropItem "ArmorBonusMax", 128
Obituary "%o was destroyed by a nazi suicide bomber doggo."
Tag "Suicide Doggo"
States
	{
	Spawn:
		TNT1 A 0
		TNT1 A 0 A_Jump(128,"Wander")
		Goto Sitting
	Sitting:
		NDOI A 10 A_Look
        Loop
	Wander:
		TNT1 A 0 A_Look
    	SNZD AAAA 2 A_Wander
		TNT1 A 0 A_Look
		SNZD BBBB 2 A_Wander
		TNT1 A 0 A_Look
		SNZD CCCC 2 A_Wander
		TNT1 A 0 A_Look
		SNZD DDDD 2 A_Wander
		TNT1 A 0 A_Jump(15,1)
		Loop
		TNT1 A 0 A_PlaySound("suicidedoge/active")
		Loop
	See:
    	SNZD AAAABBBBCCCCDDDD 1 A_Chase
	    Loop
	Melee:
		TNT1 A 0
		TNT1 A 0 A_ChangeFlag(NOPAIN,1)
		TNT1 A 0 A_Jump(64,"Nuke")
		TNT1 A 0 A_PlaySound("suicidedoge/active",CHAN_VOICE)
		SNZD EF 4 A_FaceTarget
        TNT1 A 0 A_CustomMissile("SuicideBomb",24,0,0,CMF_AIMDIRECTION)
        TNT1 A 0 A_SpawnItemEx("OrangeParticleSpawner",0,0,24,0,0,0,0,128) 
        TNT1 AAA 0 A_CustomMissile("Kaboom3",24,0,random(0,360),2,random(0,360))
	    TNT1 AAA 0 A_CustomMissile("SmokeFX2",24,0,random(0,360),2,random(0,360))
        TNT1 AAAA 0 A_SpawnItemEx("Debris",0,0,24,Random(4,-4),Random(4,-4),Random(4,8),0,128)
        TNT1 A 0 A_SpawnItem("RocketEx",0,24)
	    TNT1 A 0 A_Stop
		SNZD G 1 Bright A_PlaySound("weapons/rocklx")
		Goto XDeath
	Nuke:
	    TNT1 A 0
		TNT1 A 0 A_PlaySound("suicidedoge/active",CHAN_VOICE)
		TNT1 A 0 A_PlaySound("suicidedoge/bip",7)
		SNZD EF 7 A_FaceTarget
		TNT1 A 0 Bright A_CustomMissile("DarkDesNuke",30,0,0)
		SNZD G 1 Bright
		Goto XDeath
	Pain:
		TNT1 A 0
		TNT1 A 0 A_ChangeFlag(NOPAIN,1)
		SNZD A 2
		SNZD A 2 A_Pain
		TNT1 A 0 A_GiveInventory("MonsterAvoid",1)
		Goto See
	Death:
		TNT1 A 0
		TNT1 A 0 A_StopSound(7)
		NDOG H 5 A_Scream
		NDOG I 5 A_Fall
		NDOG J 5 A_SpawnItem("BodyCrash",0,0,0,0)
		NDOG K 63000 CanRaise
		Stop
	XDeath:
		TNT1 A 0
		TNT1 A 0 A_StopSound(7)
		SNZD G 3 A_SpawnItemEx("GibbedGenerator",0,0,0,0,0,0,0,SXF_CLIENTSIDE,0)
		SNZD H 3 A_XScream
		SNZD I 3 A_Fall
		SNZD I 63000 CanRaise
		Stop 
    }
}