Actor Hornet
{
//Creator: Complex Doom CF 3.0 Team
//Origin: Complex Doom CF 3.0
//Sprite: HNT0
//Title: "Hornet" 
  Monster
  Radius 64
  Height 100
  Mass 6000
  Health 5000
  Speed 16
  Floatspeed 16
  Painchance 6
  Species "Masterminds"
  DamageFactor "DemolisherEx", 0.0
  DamageFactor "DarkDemoEx", 0.0
  DamageFactor "CerChainguns", 0.0  
  DamageFactor "CerEnergyBall", 0.0
  DamageFactor "PDTBFG", 0.2
  DamageFactor "PDTBFGTracer", 0.6
  +FLOAT
  +NOGRAVITY
  +BOSS
  +BOSSDEATH
  +NORADIUSDMG
  +QUICKTORETALIATE
  +NOFEAR
  Obituary "%o was stung by the Hornet."
  SeeSound "arachnophyte/sight"
  PainSound "arachnophyte/pain"
  DeathSound "arachnophyte/death"
  States
  {
  Spawn:
	HNT0 A 0 A_PlaySound("Hornet/Hover",7,1.0,1)
	HNT0 ABCDEFGHIJKLMNOPQRST 3 A_Look
	Loop
  See:
	HNT0 A 0 A_ChangeFlag(NOPAIN,0)
	HNT0 ABCDEFGHIJKLMNOPQRST 3 A_Chase
	Loop
  Missile:
	TNT1 A 0 A_Jump(128,"Rockets")
  ExplosiveMinigun:
	HNT1 ABCDEFGHIJ 2 A_FaceTarget 
  ExplosiveMinigunLoop:
	TNT1 A 0 A_FaceTarget
	TNT1 A 0 A_PlaySound("sentient/fire")
	TNT1 A 0 A_SpawnItemEx("OrangeShellCasing",10,53,72,Random(-2,2),random(2,6),Random(1,3))
	TNT1 A 0 A_SpawnItemEx("OrangeShellCasing",10,-53,72,Random(-2,2),random(-6,-2),Random(1,3))
	TNT1 A 0 A_CustomMissile("SentientExplosiveTracer",75,53,frandom(-8,8))
	HNT1 K 3 A_CustomMissile("SentientExplosiveTracer",75,-53,frandom(-8,8))
	TNT1 A 0 A_FaceTarget
	TNT1 A 0 A_PlaySound("sentient/fire")
	TNT1 A 0 A_SpawnItemEx("OrangeShellCasing",10,53,72,Random(-2,2),random(2,6),Random(1,3))
	TNT1 A 0 A_SpawnItemEx("OrangeShellCasing",10,-53,72,Random(-2,2),random(-6,-2),Random(1,3))
	TNT1 A 0 A_CustomMissile("SentientExplosiveTracer",75,53,frandom(-8,8))
	HNT1 J 4 A_CustomMissile("SentientExplosiveTracer",75,-53,frandom(-8,8))
	TNT1 A 0 A_MonsterRefire(220,"See")
	TNT1 A 0 A_Jump(4,"Pause")
	Loop
  Pause:
	HNT1 JIHGFEDCBA 2
	Goto See
  Rockets:
	HNT1 LMNOPQRSSS 2 A_FaceTarget
	TNT1 A 0 A_PlayWeaponSound("Weapons/RocketLauncherFire")
	TNT1 A 0 A_CustomMissile("CyberLordRocket",22,-12)
	TNT1 A 0 A_CustomMissile("CyberLordRocket",22,-4)
	TNT1 A 0 A_CustomMissile("CyberLordRocket",22,10)
	TNT1 A 0 A_CustomMissile("CyberLordRocket",22,16)
	HNT1 SS 3 A_FaceTarget
	HNT1 RQPONML 2 A_FaceTarget
	Goto See
  Pain:
	"----" A 3 A_ChangeFlag(NOPAIN,1)
	HNT2 A 3 A_Pain
	HNT2 BCDEFGHIJKLMNOPQRSTUV 3
	Goto See
  Death:
	"----" A 0 A_StopSound(7)
	"----" A 0 A_Gravity
	"----" A 3 A_Scream
	HNT3 "ABCDEFGHIJKLMNOPQRSTUVWXYZ\[]" 3 A_CustomMissile("Kaboom", random(10,120), random(30,-30), random(0,360), 2, random(0,360))
	HNT4 ABCDEFGHIJKLMNOPQRS 3 A_CustomMissile("Kaboom", random(10,80), random(30,-30), random(0,360), 2, random(0,360))
	TNT1 A 0 A_BossDeath
	HNT4 TTTTTT 8 A_CustomMissile("Kaboom", random(10,60), random(30,-30), random(0,360), 2, random(0,360))
    TNT1 AAAAAAAAAA 0 A_SpawnItemEx("GibbedGenerator",Random(10,-10),Random(10,-10),Random(20,60),0,0,0,0,128,0)
	TNT1 AAAAAAAAAAA 0 A_CustomMissile("BigRedBloodCloud", random(10,80), 0, random(0,360), 2, random(0,360))
	TNT1 AAAAAAAAAAAA 0 A_CustomMissile("SmokeFX3", random(10,60), random(30,-30), random(0,360), 2, random(0,360))	
	TNT1 AAAAAAA 0 A_CustomMissile("Kaboom", random(10,60), random(30,-30), random(0,360), 2, random(0,360))
	TNT4 A 0 A_Fall
	TNT1 A 5 A_XScream
	Stop
  XDeath:
	Stop
  }
}