Actor NightmareImp : DoomImp
{
//Creator: Titanium
//Origin: Monsterovich (Complex-MM)
//Sprite: TRO5
//Title: "Nightmare Imp"
Radius 20
Height 56
Mass 100
Speed 10
PainChance 50
Monster
GibHealth 50
SeeSound "imp/sight"
PainSound "imp/pain"
DeathSound "imp/death"
ActiveSound "imp/active"
Obituary "%o was scared to death by Nightmare Imp."
Health 125
MeleeDamage 15
DropItem "LifeEssence"
DropItem "ArmorBonusMax"
Species "Imps"
PainChance "SoulToxic", 60
PainChance "FatFlamer", 60
PainChance "FiendFire", 60
DamageFactor "ImpComet", 0.0
Tag "\c[x2]Nightmare Imp\c-"
+FLOORCLIP
States
{
  Spawn:
	TRO5 AB 10 A_Look
	Loop
  See:
	TRO5 AABB 3 A_Chase
	TNT1 A 0 A_SpawnItem("HumanishStep",0,0,0,0)
	TRO5 CCDD 3 A_Chase
	TNT1 A 0 A_SpawnItem("HumanishStep",0,0,0,0)
	Loop
  SpawnTrites:
	TRO5 EF 4 A_FaceTarget
	TRO5 G 3 A_PainAttack("ImpTrite")
	TRO5 EF 4 A_FaceTarget
	TRO5 G 3 A_PainAttack("ImpTrite")
	Goto See
  Melee:
	TRO5 EF 4 A_FaceTarget
	TRO5 G 3 A_MeleeAttack
	Goto See
  Missile:
	TRO5 A 0 A_Jump(128, "SpawnTrites")
	TRO5 EF 8 A_FaceTarget
	TRO5 G 6 A_CustomMissile("NewImpBall", 34, 0, 0)
	TRO5 G 0 A_CustomMissile("NewImpBall", 34, 5, 0)
	TRO5 G 0 A_CustomMissile("NewImpBall", 34, -5, 0)
	TRO5 EF 8 A_FaceTarget
	TRO5 G 6 A_CustomMissile("NewImpBall", 34, 0, 0)
	TRO5 G 0 A_CustomMissile("NewImpBall", 34, 5, 0)
	TRO5 G 0 A_CustomMissile("NewImpBall", 34, -5, 0)
	Goto See
  Pain:
	TRO5 H 2
	TRO5 H 2 A_Pain
	Goto See
  Death:
	TRO5 I 8
	TRO5 J 8 A_Scream
	TRO5 K 6
	TRO5 L 6 A_NoBlocking
	TRO5 A 0 A_SpawnItem("ImpTrite")
	TNT1 A 0 A_SpawnItem("BodyCrash",0,0,0,0)
	TROO M -1
	Stop
  XDeath:
	TROO N 5 A_SpawnItemEx("GibbedGenerator",0,0,0,0,0,0,0,128,0)
	TROO O 5 A_XScream
	TROO P 5
	TROO Q 5 A_NoBlocking
	TROO RST 5
	TROO U -1
	Stop
  Raise:
	TNT1 A 0
	TNT1 A 0 A_SpawnItemEx("VileHealEffect",0,0,0,0,0,0,0,SXF_NOCHECKPOSITION)
	TROO M 8
	TRO5 L 8
	TRO5 KJI 6
	Goto See
	}
}

actor ImpTrite
{
Health 25
Radius 20
Height 24
Speed 20
PainChance 200
Mass 30
MONSTER
SeeSound "impspid/see"
PainSound "impspid/pain"
DeathSound "impspid/death"
ActiveSound "impspid/see"
Obituary "%o was biten by imp trite."
Tag "\c[d4]Imp Trite\c-"
MeleeDamage 4
+NOGRAVITY
States
{
  Spawn:
	IMHD D 5 A_Look
    Loop
  See:
    IMHD A 0 A_SetFloorClip
    IMHD A 3 A_Gravity
    IMHD ABBCC 3 A_Chase
    Loop
  Melee:
    IMHD D 8 A_FaceTarget
    IMHD E 6 A_MeleeAttack
	IMHD A 0 A_Recoil(-2)
    Goto See
  Pain:
    IMHD D 2 A_Pain
    Goto See
  Death:
	TNT1 A 0 A_SpawnItemEx("GibbedGenerator",0,0,0,0,0,0,0,128,0)
    IMHD F 8 A_ScreamAndUnblock
    IMHD G 8
    IMHD H 6
    Stop
    }
}