ACTOR CorruptedBehemoth
{
//Creator: High Councilor
//Origin: Nexus Infinity
//Sprite: BTBH
//Title: "Corrupted Behemoth"
  Monster
  Health 3000
  Speed 10
  Scale 1.2
  Radius 48
  Height 64
  PainChance 50
  BloodColor "33 66 99"
  DamageFactor "PDTBFG", 0.25
  DamageFactor "PDTBFGTracer", 0.25
  DamageFactor "PlayerDevBall", 0.125
  DamageFactor "PlayerDevBall2", 0.125
  DamageFactor "PlayerDevTracer", 0.125
  DamageFactor "Legendary", 0.2
  DamageFactor "LegendaryPlayer", 0.3
  DamageFactor "Player",0.5
  DamageFactor "BeheComet", 0.0
  DamageFactor "FatFlamer", 0.0
  DamageFactor "DBFG2", 0.0
  DamageFactor "DBFG10K2", 0.0
  DamageFactor "DBFGSplash2", 0.0
  DamageFactor "PlayerDBFG2", 0.65
  DamageFactor "PlayerDBFG10K2", 0.65
  DamageFactor "PlayerDBFGSplash2", 0.65
  DamageFactor "Explosion", 0.5
  DamageFactor "PlayerDTRG", 0.5
  DamageFactor "DTRailgun", 0.5
  DamageFactor "CChainTracer",0.0
  DamageFactor "SuperWeapon", 0.75
  DamageFactor "LegendaryGuru", 0.75
  DamageFactor "LegendaryGuruPlayer", 0.75
  DamageFactor 0.5
  RadiusDamageFactor 0.25
  DropItem "BossLifeEssence", 128, 25
  DropItem "BossArmorBonusMax", 128, 1
  DropItem "DemonAmmoBox", 128, 200
  DropItem "BehemothCannon", 256
  DropItem "BFG15K", 128
  Dropitem "CannongunSphere", 128
  DropItem "UltraSphere", 96
  Dropitem "DCellPack", 96, 25
  Dropitem "DCell", 96, 10
  Dropitem "DCell", 96, 10
  Dropitem "MarineDBFGBeacon", 12, 1
  DropItem "D-BFG" 30 1
  Species "Fatsos"
  +BOSS
  -BOSSDEATH
  +MISSILEMORE
  +MISSILEEVENMORE
  +DONTHURTSPECIES
  +NOTIMEFREEZE
  +NOFEAR
  +NOICEDEATH
  +DONTGIB
  SeeSound "Abomination/See"
  PainSound "CerebralBehemoth/Pain"
  DeathSound "CerebralBehemoth/Death"
  ActiveSound "CerebralBehemoth/Active"
  Obituary "%o was decimated by a Corrupted Behemoth."
  Tag "\c[l5]Corrupted Behemoth\c-"
  var int user_missile;
  States
  {
  Spawn:
	BTBH A 8 A_Look
	Loop
  See:
	TNT1 A 0 A_Jump(75,"Rush")
	TNT1 A 0 A_SpawnItem("BeefyStep",0,0,0,0)
	BTBH AA 3 A_Chase
	BTBH BB 3 A_Chase
	BTBH CC 3 A_Chase
	BTBH DD 3 A_Chase
	TNT1 A 0 A_SpawnItem("BeefyStep",0,0,0,0)
	BTBH EE 3 A_Chase
	BTBH FF 3 A_Chase
	TNT1 A 0 A_Jump(35,"Teleport")
	Loop
  Rush:
	TNT1 A 0 A_SpawnItem("BeefyStep")
	BTBH AAAA 0 A_Chase
	BTBH A 2 A_SpawnItemEx("BlueBehemothGhost")
	BTBH AAAA 0 A_Chase
	BTBH B 2 A_SpawnItemEx("BlueBehemothGhost")
	BTBH AAAA 0 A_Chase
	BTBH C 2 A_SpawnItemEx("BlueBehemothGhost")
	BTBH AAAA 0 A_Chase
	BTBH D 2 A_SpawnItemEx("BlueBehemothGhost")
	TNT1 A 0 A_SpawnItem("BeefyStep")
	BTBH AAAA 0 A_Chase
	BTBH E 2 A_SpawnItemEx("BlueBehemothGhost")
	BTBH AAAA 0 A_Chase
	BTBH F 2 A_SpawnItemEx("BlueBehemothGhost")
	TNT1 A 0 A_Jump(30,"Teleport")
	TNT1 A 0 A_Jump(75,"See")
	Loop   
  Teleport:
	BTBH A 1 A_UnSetShootable
	TNT1 AAA 0 A_SpawnItemEx("BlueSentLineSpawner")
	BTBH AAAAA 1  A_FadeOut(0.2,0)
	BTBH A 2 
	BTBH AAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAA 0 A_Wander
	BTBH AAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAA 0 A_Wander
	BTBH A 1 A_PlayWeaponSound("boss/teleport")
	TNT1 AAA 0 A_SpawnItemEx("BlueSentLineSpawner")
	BTBH AAAAA 1 A_FadeIn(0.2)
	BTBH A 1 A_SetShootable
	Goto See
  Missile:
	TNT1 A 0 A_Jump(128,"Seekers","DBFG10k","BFG15K","Railgun","MiniDTBFG","Grenades")
	TNT1 A 0 A_Jump(32,"DTBFG")
	TNT1 A 0 A_Jump(8,"DBFG")
  Normal:
	TNT1 A 0 A_PlaySound("Abomination/Attack")
	BTBH G 15 A_FaceTarget
	TNT1 A 0 A_CustomMissile("BlueBehemothBall",20,-38,Random(0,6))
	BTBH H 2 Bright A_CustomMissile("BlueBehemothBall",20,38, Random(0,-6))	   
	TNT1 A 0 A_CustomMissile("BlueBehemothBall",20,38,Random(-7,-12))
	BTBH H 4 Bright A_CustomMissile("BlueBehemothBall",20,-38,Random(7,12))
	BTBH IG 6 A_FaceTarget
	TNT1 A 0 A_CustomMissile("BlueBehemothBall",20,-38,Random(0,6))
	BTBH H 2 Bright A_CustomMissile("BlueBehemothBall",20,38, Random(0,-6))	   
	TNT1 A 0 A_CustomMissile("BlueBehemothBall",20,38,Random(-7,-12))
	BTBH H 4 Bright A_CustomMissile("BlueBehemothBall",20,-38,Random(7,12))
	BTBH IG 6 A_FaceTarget
	TNT1 A 0 A_CustomMissile("BlueBehemothBall",20,-38,Random(0,6))
	BTBH H 2 Bright A_CustomMissile("BlueBehemothBall",20,38, Random(0,-6))	   
	TNT1 A 0 A_CustomMissile("BlueBehemothBall",20,38,Random(-7,-12))
	BTBH H 4 Bright A_CustomMissile("BlueBehemothBall",20,-38,Random(7,12))
	BTBH IG 12 A_Jump(32,"BFG15K","Seekers","Railgun","Grenades")
	Goto See
  Seekers:
	TNT1 A 0 A_PlaySound("Abomination/Attack")
	BTBH G 15 A_FaceTarget    
	TNT1 A 0 A_FaceTarget 
	TNT1 A 0 A_CustomMissile("BlueBehemothRocket",20,38,-16)
	BTBH H 6 Bright A_CustomMissile("BlueBehemothRocket",20,-38,16)
	BTBH IG 6 A_FaceTarget
	TNT1 A 0 A_CustomMissile("BlueBehemothRocket",20,38,-16)
	BTBH H 6 Bright A_CustomMissile("BlueBehemothRocket",20,-38,16)
	BTBH IG 6 A_FaceTarget
	TNT1 A 0 A_CustomMissile("BlueBehemothRocket",20,38,-16)
	BTBH H 6 Bright A_CustomMissile("BlueBehemothRocket",20,-38,16)
	BTBH IG 12 A_Jump(32,"DBFG10k")
	Goto See
  Grenades:
	TNT1 A 0 A_PlaySound("Abomination/Attack")
	BTBH GG 8 A_FaceTarget 
	TNT1 A 0 A_SetUserVar("user_missile",0)
  GrenadeLoop:
	TNT1 A 0 A_JumpIf(user_missile >= 10,"GrenadeEnd")	 
	TNT1 A 0 A_SetUserVar("user_missile",user_missile+1) 
	BTBH H 4 Bright A_CustomMissile("BlueBehemothGrenade",30,30,Random(2,-2),CMF_OFFSETPITCH,Random(0,5))
	BTBH IG 3 A_FaceTarget
	BTBH H 4 Bright A_CustomMissile("BlueBehemothGrenade",30,-30,Random(2,-2),CMF_OFFSETPITCH,Random(0,5))
	BTBH IG 3 A_FaceTarget
	Loop
  GrenadeEnd:
	BTBH IG 8 A_Jump(80,"Normal","BFG15K")
	Goto See
  DBFG10k:
	TNT1 A 0 A_PlaySound("Abomination/Attack")
	TNT1 A 0 A_PlaySound("Weapons/dbfgcharge2",7)
	BTBH GGGGGG 5 A_FaceTarget
	TNT1 A 0 A_PlaySound("Weapons/dbfgfire2")
	TNT1 A 0 A_CustomMissile("T3DBFG10kShot",20,-38,Random(0,6))
	BTBH H 4 Bright A_CustomMissile("T3DBFG10kShot",20,38, Random(0,-6))
	TNT1 A 0 A_PlaySound("Weapons/dbfgfire2")
	TNT1 A 0 A_CustomMissile("T3DBFG10kShot",20,38,Random(6,-12))
	BTBH H 4 Bright A_CustomMissile("T3DBFG10kShot",20,-38,Random(12,-6))
	BTBH IG 4 A_FaceTarget
	TNT1 A 0 A_PlaySound("Weapons/dbfgfire2")
	TNT1 A 0 A_CustomMissile("T3DBFG10kShot",20,-38,Random(0,6))
	BTBH H 3 Bright A_CustomMissile("T3DBFG10kShot",20,38, Random(0,-6))
	TNT1 A 0 A_PlaySound("Weapons/dbfgfire2")
	TNT1 A 0 A_CustomMissile("T3DBFG10kShot",20,38,Random(6,-12))
	BTBH H 3 Bright A_CustomMissile("T3DBFG10kShot",20,-38,Random(12,-6))
	TNT1 A 0 A_PlaySound("Weapons/dbfgfire2")
	TNT1 A 0 A_CustomMissile("T3DBFG10kShot",20,38,Random(18,-12))
	BTBH H 3 Bright A_CustomMissile("T3DBFG10kShot",20,-38,Random(12,-18))
	BTBH IG 4 A_FaceTarget
	TNT1 A 0 A_Jump(128,"BFG15K")
	Goto See
  BFG15K:
	TNT1 A 0 A_PlaySound("Abomination/Attack")
	TNT1 A 0 A_PlaySound("weapons/charge15k",7)
	BTBH GGGGGG 5 A_FaceTarget
	TNT1 A 0 A_FaceTarget
	TNT1 A 0 A_CustomMissile("BlueBehemothBFG15K",20,-38,Random(0,6))
	BTBH H 3 Bright A_CustomMissile("BlueBehemothBFG15K",20,38, Random(0,-6))
	TNT1 A 0 A_CustomMissile("BlueBehemothBFG15K",20,38,Random(6,-12))
	BTBH H 3 Bright A_CustomMissile("BlueBehemothBFG15K",20,-38,Random(12,-6))
	BTBH IG 4 A_FaceTarget
	TNT1 A 0 A_CustomMissile("BlueBehemothBFG15K",20,-38,Random(0,6))
	BTBH H 3 Bright A_CustomMissile("BlueBehemothBFG15K",20,38, Random(0,-6))
	TNT1 A 0 A_CustomMissile("BlueBehemothBFG15K",20,38,Random(6,-12))
	BTBH H 3 Bright A_CustomMissile("BlueBehemothBFG15K",20,-38,Random(12,-6))
	BTBH IG 4 A_FaceTarget
	TNT1 A 0 A_CustomMissile("BlueBehemothBFG15K",20,-38,Random(0,6))
	BTBH H 2 Bright A_CustomMissile("BlueBehemothBFG15K",20,38, Random(0,-6))
	TNT1 A 0 A_CustomMissile("BlueBehemothBFG15K",20,38,Random(6,-12))
	BTBH H 2 Bright A_CustomMissile("BlueBehemothBFG15K",20,-38,Random(12,-6))
	TNT1 A 0 A_CustomMissile("BlueBehemothBFG15K",20,38,Random(18,-12))
	BTBH H 2 Bright A_CustomMissile("BlueBehemothBFG15K",20,-38,Random(12,-18))
	BTBH IG 4 A_FaceTarget
	TNT1 A 0 A_Jump(96,"BFG15kSpread")
	Goto See
  BFG15kSpread:
	TNT1 A 0 A_PlaySound("Abomination/Attack")
	TNT1 A 0 A_PlaySound("weapons/charge15k",7)
	BTBH GGGGGG 5 A_FaceTarget
	TNT1 A 0 A_CustomMissile("BlueBehemothBFG15K",20,30)
	TNT1 A 0 A_CustomMissile("BlueBehemothBFG15K",20,30,-15)
	TNT1 A 0 A_CustomMissile("BlueBehemothBFG15K",20,30,-30)
	TNT1 A 0 A_CustomMissile("BlueBehemothBFG15K",20,30,-45)
	TNT1 A 0 A_CustomMissile("BlueBehemothBFG15K",20,30,15)
	TNT1 A 0 A_CustomMissile("BlueBehemothBFG15K",20,30,30)
	TNT1 A 0 A_CustomMissile("BlueBehemothBFG15K",20,30,45)
	TNT1 A 0 A_CustomMissile("BlueBehemothBFG15K",20,-30,-15)
	TNT1 A 0 A_CustomMissile("BlueBehemothBFG15K",20,-30,-30)
	TNT1 A 0 A_CustomMissile("BlueBehemothBFG15K",20,-30,-45)
	TNT1 A 0 A_CustomMissile("BlueBehemothBFG15K",20,-30,15)
	TNT1 A 0 A_CustomMissile("BlueBehemothBFG15K",20,-30,30)
	TNT1 A 0 A_CustomMissile("BlueBehemothBFG15K",20,-30,45)
	BTBH H 6 A_CustomMissile("BlueBehemothBFG15K",20,-30)
	BTBH IG 6 A_FaceTarget
	Goto See
  Railgun:
	TNT1 A 0 A_PlaySound("weapons/rgcharge")
	BTBH GGGGG 5 A_FaceTarget
	TNT1 A 0 A_CustomMissile("BlueAnniRail",20,-38,0)
	BTBH H 2 Bright A_CustomMissile("BlueAnniRail",20,38,0)
	TNT1 A 0 A_CustomMissile("BlueAnniRail",20,38,-12)
	BTBH H 4 Bright A_CustomMissile("BlueAnniRail",20,-38,12)
	BTBH IG 6 A_FaceTarget
	Goto See
  MiniDTBFG:
	TNT1 A 0 A_PlaySound("LesserCardinal/BFGCharge")
	BTBH GGGGGGG 5 Bright A_FaceTarget
	TNT1 A 0 A_PlaySound("LesserCardinal/BFGFire")
	BTBH H 6 Bright A_CustomMissile("BlueBehemothMiniDTBFG",30,30,random(-1,1))
	BTBH IG 6 A_FaceTarget
	TNT1 A 0 A_PlaySound("LesserCardinal/BFGFire")
	BTBH H 6 Bright A_CustomMissile("BlueBehemothMiniDTBFG",30,-30,random(-1,1))
	BTBH IG 6 A_FaceTarget
	TNT1 A 0 A_PlaySound("LesserCardinal/BFGFire")
	BTBH H 6 Bright A_CustomMissile("BlueBehemothMiniDTBFG",30,30,random(-2,2))
	BTBH IG 6 A_FaceTarget
	TNT1 A 0 A_PlaySound("LesserCardinal/BFGFire")
	BTBH H 6 Bright A_CustomMissile("BlueBehemothMiniDTBFG",30,-30,random(-2,2))
	BTBH IG 6 A_FaceTarget
	TNT1 A 0 A_PlaySound("LesserCardinal/BFGFire")
	BTBH H 6 Bright A_CustomMissile("BlueBehemothMiniDTBFG",30,30,random(-4,4))
	BTBH IG 6 A_FaceTarget
	TNT1 A 0 A_PlaySound("LesserCardinal/BFGFire")
	BTBH H 6 Bright A_CustomMissile("BlueBehemothMiniDTBFG",30,-30,random(-4,4))
	BTBH IG 6 A_FaceTarget
	Goto See
  DTBFG:
	TNT1 A 0 A_PlayWeaponSound("Cardinal/9k")
	BTBH GGGGGG 5 A_FaceTarget
	BTBH H 0 A_CustomMissile("BehemothT3DBFG10KBall",30,30,Random(-2,4))
	BTBH H 6 A_CustomMissile("BehemothT3DBFG10KBall",30,-30,Random(2,-4))
	BTBH IG 15
	TNT1 A 0 A_Jump(64,"BFG15kSpread")
	Goto See
  DBFG:
	TNT1 A 0 A_PlaySound("Weapons/dbfgcharge")
	//TNT1 A 0 A_ChangeFlag(NOPAIN,1)
	BTBH GGGGGGGGGGGGGGGGGGGGGGG 5 A_FaceTarget(45)
	TNT1 AA 0 A_PlaySound("Weapons/dbfgfire", CHAN_AUTO)
	BTBH H 8 A_CustomMissile("T3DBFGBall",30,-30,0,CMF_AIMOFFSET)
	BTBH IG 15
	BTBH H 8 A_CustomMissile("T3DBFGBall",30,30,0,CMF_AIMOFFSET)
	TNT1 A 0 A_PlaySound("Weapons/dbfgcooldown")
	//TNT1 A 0 A_ChangeFlag(NOPAIN,0)
	BTBH IG 15
	Goto See
  Pain:	
	TNT1 A 0 A_Jump(87,"PainMissile")
	BTBH J 6 A_Pain
	Goto See
  PainMissile:
	BTBH J 6 A_Pain
	Goto Missile
  Death:
	BTBH K 6
	BTBH L 6 A_Scream
	TNT1 A 0 A_SpawnItemEx("BlueGibbedGenerator",0,0,0,0,0,0,0,128,0)
	BTBH M 6 A_NoBlocking
	TNT1 A 0 A_SpawnItemEx("BlueGibbedGenerator",0,0,0,0,0,0,0,128,0)
	BTBH NOPQR 6
	BTBH S 6
	BTBH T -1 A_KillMaster
	Stop
	}
}

ACTOR BlueBehemothBall : BlueCardball
{
  Scale 0.4
  BounceCount 3
  Speed 30
  +DOOMBOUNCE
  States
  {
  Death:
	TNT1 A 0 A_Explode(128,128,0)
	TNT1 A 0 A_PlaySound("weapons/t2fbx1",0,0.75,0,ATTN_NORM)
	TNT1 A 0 A_SpawnItemEx("LegendaryBlueParticleSpawner",0,0,0,0,0,0,0,128)
	TNT1 A 1 A_SpawnItemEx("BlueCardballExp")
	Stop
	}
}

ACTOR BlueBehemothRocket : BlueCardinalRocket
{
  Speed 20
  Damage 10
  States
  {
  Spawn:
    TNT1 A 0
  Normal:
    BCRC AB 4 Bright
	TNT1 A 0 A_PlaySound("Weapons/homingbeep")
    TNT1 A 0 A_Jump(5,"StartSeek")
    Loop	
  StartSeek:
	BCRC AB 4 Bright A_Tracer2
	TNT1 A 0 A_PlaySound("Weapons/homingbeep")
    TNT1 A 0 A_Jump(10,"Normal")
	Loop
  Death:
	BCRC C 8 Bright A_Explode
	BCRC D 6 Bright
	BCRC E 4 Bright
	Stop
	}
}

ACTOR BlueBehemothBFG15K : BFG15KBall
{
  FastSpeed 50
  -THRUSPECIES
  DamageType "BeheComet"
  States
  {
  Spawn:
	TNT1 A 0 A_SpawnItemEx("BFGTrailParticleBlue",Random(-8,8),Random(-8,8),Random(-8,8),Random(-1,1),Random(-1,1),Random(-1,1),Random(-20,20),128)
	B3S2 AAA 2 Bright 
	TNT1 A 0 A_SpawnItemEx("BFGTrailParticleBlue",Random(-8,8),Random(-8,8),Random(-8,8),Random(-1,1),Random(-1,1),Random(-1,1),Random(-20,20),128)
	B3S2 BBB 2 Bright
    Loop
  Death:
	TNT1 A 0
	TNT1 A 0 A_SpawnItemEx("T3DBFG10kDeathParticleSpawner",0,0,0,0,0,0,0,SXF_CLIENTSIDE,0)
	TNT1 A 0 A_SpawnItemEx("T3DBFGShotShockwave",0,0,0,0,0,0,0,SXF_CLIENTSIDE,0)
    BG3X A 1 Bright A_Explode
	BG3X ABCDEF 3 Bright //A_SpawnItemEx("T3DBFGShotShockwaveDmg",16,16,0,0,0,0,0,SXF_SETMASTER,0)
	Stop
	}
}

ACTOR BlueBehemothGrenade
{
  Radius 10
  Height 10
  Speed 40
  Damage 20
  Damagetype "BeheComet"
  Scale 1.1
  Decal Scorch
  Projectile
  Bouncetype Doom
  +FORCERADIUSDMG
  -NOGRAVITY
  SeeSound "Weapons/GrenadeFire"
  BounceSound "NemesisBehemoth/Grenade"
  DeathSound "weapons/rocklx"
  States
  {
  Spawn:
	BALL A 3 Bright A_SpawnItemEx("BlueCardballTrail",0,0,0,0,0,0,0,SXF_CLIENTSIDE|SXF_NOCHECKPOSITION,0)
	Loop
  Death:
	TNT1 A 0 A_Explode(50,100,0)
	TNT1 A 0 A_SetTranslucent(0.85,1)
	TNT1 A 0 A_SpawnItemEx("BlueCardballExp")
	BCRC CDE 4 Bright
	Stop
	}
}

ACTOR BlueBehemothMiniDTBFG : LesserCardinalMiniDTBFG
{
  +NOTIMEFREEZE
  DamageType "BeheComet"
  Obituary "%o was decimated by a Corrupted Behemoth."
  States
  {
  Spawn:
    TNT1 A 0
    TNT1 A 0 A_PlaySoundEx("LesserCardinal/BFGIdle","Voice",1)
    B3S1 AB 4 Bright A_SpawnItemEx("BFGTrailParticleBlue",Random(-12,12),Random(-12,12),Random(12,22),Random(-2,2),Random(-2,2),Random(-2,2),Random(-20,20),128)
    TNT1 A 0 A_CustomMissile("BlueBehemothBFGProjectileAttack",Random(-10,10),0,0,CMF_TRACKOWNER)
    Loop
  Death:
	TNT1 A 0
	TNT1 A 0 A_SetTranslucent(0.75,1)
	TNT1 A 0 Radius_Quake(5,60,0,10,0)
	TNT1 A 0 A_Explode(60,250)
	B3S1 A 6 Bright A_SpawnItemEx("T3DBFGBallShockwave",0,0,15,0,0,0,0,128)
	TNT1 A 0 A_Explode(60,250)
	B3S1 B 6 Bright A_SpawnItemEx("T3DBFGBallShockwave",0,0,15,0,0,0,0,128)
	TNT1 A 0 A_Explode(60,250)
	B3S1 C 6 Bright A_SpawnItemEx("T3DBFGBallShockwave",0,0,15,0,0,0,0,128)
	TNT1 A 0 A_Explode(60,250)
	B3S1 D 6 Bright A_SpawnItemEx("T3DBFGBallShockwave",0,0,15,0,0,0,0,128)
	TNT1 A 0 A_Explode(300,300)
	TNT1 A 0 A_StopSoundEx("Voice")
	TNT1 A 0 Radius_Quake(20,12,0,12,0)
	TNT1 A 0 A_PlaySound("weapons/bfg95explode")
	TNT1 A 0 A_SpawnItemEx("T3DBFGBallShockwave",0,0,0,0,0,0,0,128)
	TNT1 A 0 A_SpawnItemEx("LegendaryBlueParticleSpawner",0,0,0,0,0,0,0,128)
	TNT1 AAA 0 A_CustomMissile("KaboomBlue2",0,0,random(0,360),2,random(0,360))
	TNT1 A 0 A_SetScale(1.0)
	BG3X ABCDEF 4 Bright
	Stop
    }
}

ACTOR BlueBehemothBFGProjectileAttack : LesserCardinalBFGProjectileAttack
{
Obituary "%o was decimated by a Corrupted Behemoth."
MissileType "BlueBehemothMiniDTBFGLightningProjectile"
}

ACTOR BlueBehemothMiniDTBFGLightningProjectile : LegCyberNobleLightningProjectile
{ 
DamageType "BeheComet"
}

ACTOR BehemothT3DBFG10KBall : T3DBFG10KBall
{
  Species "Fatsos"
  DamageType "DBFG2"
  States
  {
  Spawn:
	TNT1 A 0
	TNT1 A 0 A_Jump(128,"SFX")
	TNT1 A 0 A_AlertMonsters
	TNT1 A 0 A_PlaySoundEx("weapons/dtech10kball","Voice",1)
	TNT1 A 0 A_SpawnItemEx("BFGTrailParticleBlue",Random(-12,12),Random(-12,12),Random(12,22),Random(-2,2),Random(-2,2),Random(-2,2),Random(-20,20),SXF_CLIENTSIDE|SXF_NOCHECKPOSITION,0)
	B3S1 A 1 Bright A_SpawnItemEx("BehemothT3DBFGShockAttack",0,0,0,0,0,0,0,SXF_SETMASTER)
	TNT1 A 0 A_SpawnItemEx("BFGTrailParticleBlue",Random(-12,12),Random(-12,12),Random(12,22),Random(-2,2),Random(-2,2),Random(-2,2),Random(-20,20),SXF_CLIENTSIDE|SXF_NOCHECKPOSITION,0)
	B3S1 B 1 Bright A_SpawnItemEx("BehemothT3DBFGShockAttack",0,0,0,0,0,0,0,SXF_SETMASTER)
	TNT1 A 0 A_SpawnItemEx("BFGTrailParticleBlue",Random(-12,12),Random(-12,12),Random(12,22),Random(-2,2),Random(-2,2),Random(-2,2),Random(-20,20),SXF_CLIENTSIDE|SXF_NOCHECKPOSITION,0)
	B3S1 C 1 Bright A_SpawnItemEx("BehemothT3DBFGShockAttack",0,0,0,0,0,0,0,SXF_SETMASTER)
	TNT1 A 0 A_SpawnItemEx("BFGTrailParticleBlue",Random(-12,12),Random(-12,12),Random(12,22),Random(-2,2),Random(-2,2),Random(-2,2),Random(-20,20),SXF_CLIENTSIDE|SXF_NOCHECKPOSITION,0)
	B3S1 D 1 Bright A_SpawnItemEx("BehemothT3DBFGShockAttack",0,0,0,0,0,0,0,SXF_SETMASTER)
	Loop
  SFX:
	TNT1 A 0 A_AlertMonsters
	TNT1 A 0 A_PlaySoundEx("weapons/dtech10kball","Voice",1)
	TNT1 A 0 A_SpawnItemEx("DTBFGLightningBlue",Random(6,-6),Random(6,-6),Random(16,8),0,0,0,0,SXF_CLIENTSIDE|SXF_NOCHECKPOSITION,0)
	TNT1 A 0 A_SpawnItemEx("BFGTrailParticleBlue",Random(-12,12),Random(-12,12),Random(12,22),Random(-2,2),Random(-2,2),Random(-2,2),Random(-20,20),SXF_CLIENTSIDE|SXF_NOCHECKPOSITION,0)
	B3S1 A 1 Bright A_SpawnItemEx("BehemothT3DBFGShockAttack",0,0,0,0,0,0,0,SXF_SETMASTER)
	TNT1 A 0 A_SpawnItemEx("DTBFGLightningBlue2",Random(6,-6),Random(6,-6),Random(16,8),0,0,0,0,SXF_CLIENTSIDE|SXF_NOCHECKPOSITION,0)
	TNT1 A 0 A_SpawnItemEx("BFGTrailParticleBlue",Random(-12,12),Random(-12,12),Random(12,22),Random(-2,2),Random(-2,2),Random(-2,2),Random(-20,20),SXF_CLIENTSIDE|SXF_NOCHECKPOSITION,0)
	B3S1 B 1 Bright A_SpawnItemEx("BehemothT3DBFGShockAttack",0,0,0,0,0,0,0,SXF_SETMASTER)
	TNT1 A 0 A_SpawnItemEx("DTBFGLightningBlue",Random(6,-6),Random(6,-6),Random(16,8),0,0,0,0,SXF_CLIENTSIDE|SXF_NOCHECKPOSITION,0)
	TNT1 A 0 A_SpawnItemEx("BFGTrailParticleBlue",Random(-12,12),Random(-12,12),Random(12,22),Random(-2,2),Random(-2,2),Random(-2,2),Random(-20,20),SXF_CLIENTSIDE|SXF_NOCHECKPOSITION,0)
	B3S1 C 1 Bright A_SpawnItemEx("BehemothT3DBFGShockAttack",0,0,0,0,0,0,0,SXF_SETMASTER)
	TNT1 A 0 A_SpawnItemEx("DTBFGLightningBlue2",Random(6,-6),Random(6,-6),Random(16,8),0,0,0,0,SXF_CLIENTSIDE|SXF_NOCHECKPOSITION,0)
	TNT1 A 0 A_SpawnItemEx("BFGTrailParticleBlue",Random(-12,12),Random(-12,12),Random(12,22),Random(-2,2),Random(-2,2),Random(-2,2),Random(-20,20),SXF_CLIENTSIDE|SXF_NOCHECKPOSITION,0)
	B3S1 D 1 Bright A_SpawnItemEx("BehemothT3DBFGShockAttack",0,0,0,0,0,0,0,SXF_SETMASTER)
	Goto Spawn
	}
}

ACTOR BehemothT3DBFGShockAttack : T3DBFGShockAttack
{
+FRIENDLY
Species "Fatsos"
DamageType "DBFG2"
MissileType "T3DBFGRailgunSlug"
}

Actor BlueBehemothGhost : LBGhost
{
  Scale 1.2
  States
  {
  Spawn:
    TNT1 A 0
    TNT1 A 0 A_JumpIf(ACS_ExecuteWithResult(304) == 1,"NULL")
    BTBH C 2 A_FadeOut(0.09)
    Wait
    }
}