Actor PhaseTormentor
{
//Creator: High Councilor
//Origin: Nexus Infinity
//Sprite: PVER
//Title: "Phase Tormentor"
  Monster
  Health 2000 //1500
  Radius 31
  Height 70
  Mass 800
  Speed 14
  PainChance 20
  Scale 0.85
  MeleeDamage 20
  MeleeRange 68
  DamageFactor 0.7
  RadiusDamageFactor 0.25
  //Renderstyle Add
  Alpha 0.8
  Obituary "%o was phased out of existence by the Phase Tormentor."
  PainChance "Souls", 0
  PainChance "ChaosSoul", 0
  DamageFactor "CurseComet", 0.0
  DamageFactor "HelementalComet", 0.0
  DamageFactor "SoulToxic", 0.0
  DamageFactor "BombBreath", 0.0
  DamageFactor "C0mm4nder", 0.0
  DamageFactor "EleSouls", 0.0
  DropItem "BossLifeEssence" 200 2
  DropItem "BossArmorBonusMax" 200 1
  DropItem "DemonAmmoBox" 64
  DropItem "DemonAmmo" 256
  DropItem "DemonAmmo" 128 
  DropItem "PhaseArmor" 64
  BloodColor "cf 00 b0"
  Species "EleSouls"
  +BOSS
  +FLOAT
  +NOGRAVITY
  +MISSILEMORE
  +MISSILEEVENMORE
  +DONTHARMSPECIES
  SeeSound "legbanished/see"
  PainSound "legbanished/pain"
  DeathSound "legbanished/death"
  ActiveSound "legbanished/idle"
  MeleeSound "caco/melee"
  Tag "\ctPhase Tormentor\c-"
  var int user_missile;
  var int user_souls;
  var int user_phased;
  States
  {
/*
  Spawn:
	PVER A 10 A_Look
	loop
*/
  Spawn:
	PVER A 1 A_Look
	TNT1 A 0 a_SpawnItemEx("PhaseTormentorASpawner")
	loop
  See:
	PVER A 3 A_Chase
	TNT1 A 0 A_SpawnItemEx("PhaseTormentorASpawner")
	PVER A 3 A_Chase
	TNT1 A 0 A_SpawnItemEx("PhaseTormentorASpawner")
	PVER B 3 A_Chase
	TNT1 A 0 A_SpawnItemEx("PhaseTormentorBSpawner")
	PVER B 3 A_Chase
	TNT1 A 0 A_SpawnItemEx("PhaseTormentorBSpawner")
	PVER A 3 A_Chase
	TNT1 A 0 A_SpawnItemEx("PhaseTormentorASpawner")
	PVER A 3 A_Chase
	TNT1 A 0 A_SpawnItemEx("PhaseTormentorASpawner")
	PVER C 3 A_Chase
	TNT1 A 0 A_SpawnItemEx("PhaseTormentorCSpawner")
	PVER C 3 A_Chase
	TNT1 A 0 A_SpawnItemEx("PhaseTormentorCSpawner")
	PVER A 0 A_Jump(32,"Teleport")
	TNT1 A 0 A_Jump(60,"Phase")
	Loop
  Teleport:
	PVER A 1 Bright A_UnSetShootable
	//TNT1 AAAAAA 0 A_SpawnItemEx("PhaseTormentorASpawner",0,0,0,frandom(-2,2),frandom(-2,2),frandom(0,4))
	TNT1 AAA 0 A_SpawnItem("PhaseBanSmokeSpawner",0,0,0,0)
	PVER AAAAAAAAAAA 1 A_FadeOut(0.1,0)
	PVER A 1 
	TNT1 AAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAA 0 A_Wander
	TNT1 AAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAA 0 A_Wander
	PVER A 1 A_PlayWeaponSound("boss/teleport")
	//TNT1 AAAAAA 0 A_SpawnItemEx("PhaseTormentorASpawner",0,0,0,frandom(-2,2),frandom(-2,2),frandom(0,4))
	TNT1 AAA 0 A_SpawnItem("PhaseBanSmokeSpawner",0,0,0,0)
	PVER AAAAAAAAAAA 1 A_FadeIn(0.1)
	PVER A 1 Bright A_SetShootable
	Goto See
  Phase:
	TNT1 A 0 A_JumpIf(user_phased == 1,"UnPhase")
	TNT1 A 0 A_PlaySound("phaseimp/teleport")
	TNT1 A 0 A_SetUserVar("user_phased",1)
	PVER D 2 A_FaceTarget
	PVER D 1 A_SetTranslucent(0.75)
	PVER D 1 A_SetTranslucent(0.55)
	PVER D 1 A_SetTranslucent(0.35)
	PVER D 1 A_SetTranslucent(0.20)
	Goto Phased
  UnPhase:
	TNT1 A 0 A_PlaySound("phaseimp/teleport")
	TNT1 A 0 A_SetUserVar("user_phased",0)
	PVER D 1 A_SetTranslucent(0.15)
	PVER D 1 A_SetTranslucent(0.35)
	PVER D 1 A_SetTranslucent(0.55)
	PVER D 1 A_SetTranslucent(0.75)
    //TNT1 A 0 A_SetTranslucent(1)
    TNT1 A 0 A_SetTranslucent(0.8)
	PVER D 2 A_FaceTarget		
	Goto See	
  Phased:
	PVER AABBAACCAABBAACCAABBAACCAABBAACC 1 A_ExtChase(0,0)
	PVER AABBAACCAABBAACC 1 A_Chase
	TNT1 A 0 A_Jump(200,"UnPhase")
	Goto Phased+32
  Melee:
	PVER ADF 5 A_FaceTarget
	PVER E 5 A_MeleeAttack
	TNT1 A 0 a_radiusgive("phasemindfuck", 96, RGF_PLAYERS|RGF_MONSTERS)
	goto See
  Missile:
    //TNT1 A 0 A_SetTranslucent(1)
    TNT1 A 0 A_SetTranslucent(0.8)
	TNT1 A 0 A_Jump(128,"Seekers","Minilaser","MiniDarkMatter","CometBarrage","SlowMindfuckers")
	TNT1 A 0 A_Jump(96,"DarkMatter")
	TNT1 A 0 A_Jump(64,"PhaseSouls")
  Normal:
	PVER JJJJJJJJ 1 A_FaceTarget
	TNT1 A 0 a_SpawnItemEx("PhaseTormentorJSpawner")
	PVER K 0 A_FaceTarget
	PVER K 0 Bright A_CustomMissile("PhazoFastShot",82,-34,random(-3,3),0,random(-3,3))
	PVER K 0 Bright A_CustomMissile("PhazoFastShot",82,34,random(-3,3),0,random(-3,3))
	PVER K 0 Bright A_CustomMissile("PurpleDukeBall",54,-42,random(-3,3),0,random(-3,3))
	PVER K 0 Bright A_CustomMissile("PurpleDukeBall",54,42,random(-3,3),0,random(-3,3))
	PVER K 0 Bright A_CustomMissile("PhazoFastShot",16,-34,random(-3,3),0,random(-3,3))
	PVER K 6 Bright A_CustomMissile("PhazoFastShot",16,34,random(-3,3),0,random(-3,3))
	TNT1 A 0 a_SpawnItemEx("PhaseTormentorJSpawner")
	PVER J 6 A_SpidRefire
	TNT1 A 0 a_SpawnItemEx("PhaseTormentorJSpawner")
	PVER J 0 A_Jump(96,"See")
	goto Normal+8
  Seekers:
	PVER J 5 A_FaceTarget
	TNT1 A 0 a_SpawnItemEx("PhaseTormentorJSpawner")
	PVER K 0 Bright A_CustomMissile("PhaseBanSeekBall",82,-34,0)
	PVER K 0 Bright A_CustomMissile("PhaseBanSeekBall",82,34,0)
	PVER K 0 Bright A_CustomMissile("PhaseBanSeekBall",54,-42,0)
	PVER K 0 Bright A_CustomMissile("PhaseBanSeekBall",54,42,0)
	PVER K 0 Bright A_CustomMissile("PhaseBanSeekBall",16,-34,0)
	PVER K 5 Bright A_CustomMissile("PhaseBanSeekBall",16,34,0)
	TNT1 A 0 a_SpawnItemEx("PhaseTormentorJSpawner")
	PVER J 4 A_FaceTarget
	TNT1 A 0 a_SpawnItemEx("PhaseTormentorJSpawner")
	PVER J 0 A_Jump(64,"Seekers")
	Goto See
  SlowMindfuckers:
    PVER DE 4 Bright A_FaceTarget
    PVER F 2 Bright A_CustomMissile("PhaseBanSlowBall",43,0,random(-4,4),0,random(-4,4))
	PVER F 2 Bright A_FaceTarget
    PVER F 2 Bright A_CustomMissile("PhaseBanSlowBall",43,0,random(-4,4),0,random(-4,4))
	PVER F 2 Bright A_FaceTarget
    PVER F 2 Bright A_CustomMissile("PhaseBanSlowBall",43,0,random(-4,4),0,random(-4,4))
	PVER F 2 Bright A_FaceTarget
    PVER F 2 Bright A_CustomMissile("PhaseBanSlowBall",43,0,random(-4,4),0,random(-4,4))
	PVER F 2 Bright A_FaceTarget
    PVER F 2 Bright A_CustomMissile("PhaseBanSlowBall",43,0,random(-4,4),0,random(-4,4))
	PVER F 2 Bright A_FaceTarget
    PVER F 2 Bright A_CustomMissile("PhaseBanSlowBall",43,0,random(-4,4),0,random(-4,4))
	PVER F 2 Bright A_FaceTarget
    PVER F 2 Bright A_CustomMissile("PhaseBanSlowBall",43,0,random(-4,4),0,random(-4,4))
	PVER F 2 Bright A_FaceTarget
    PVER F 2 Bright A_CustomMissile("PhaseBanSlowBall",43,0,random(-4,4),0,random(-4,4))
    Goto See
  MiniLaser:
    PVER DD 4 Bright A_FaceTarget
	TNT1 A 0 a_SpawnItemEx("PhaseTormentorDSpawner")
	PVER EE 4 Bright A_FaceTarget
	TNT1 A 0 a_SpawnItemEx("PhaseTormentorESpawner")
	TNT1 A 0 A_SetUserVar("user_missile",0)
  MiniLaserLoop:
    TNT1 A 0 A_JumpIf(user_missile == 12,"See")
    TNT1 A 0 A_SetUserVar(user_missile,user_missile+1)
    PVER F 3 Bright A_CustomMissile("PhaseBanPhazoLaser",25,0,0,0,0)
	PVER F 0 A_FaceTarget
	Loop
  MiniDarkMatter:
	PVER JJJJJJJJ 1 A_FaceTarget
	TNT1 A 0 a_SpawnItemEx("PhaseTormentorJSpawner")
	PVER K 0 Bright A_CustomMissile("PhasebanDarkMatterBallmini",82,-34,0)
	PVER K 0 Bright A_CustomMissile("PhasebanDarkMatterBallmini",82,34,0)
	PVER K 0 Bright A_CustomMissile("PhasebanDarkMatterBallmini",54,-42,10)
	PVER K 0 Bright A_CustomMissile("PhasebanDarkMatterBallmini",54,42,-10)
	PVER K 0 Bright A_CustomMissile("PhasebanDarkMatterBallmini",16,-34,0)
	PVER K 4 Bright A_CustomMissile("PhasebanDarkMatterBallmini",16,34,0)
	TNT1 A 0 a_SpawnItemEx("PhaseTormentorJSpawner")
	PVER JJJJJJJJ 1 A_FaceTarget
	TNT1 A 0 a_SpawnItemEx("PhaseTormentorJSpawner")
	PVER K 0 Bright A_CustomMissile("PhasebanDarkMatterBallmini",82,-34,0)
	PVER K 0 Bright A_CustomMissile("PhasebanDarkMatterBallmini",82,34,0)
	PVER K 0 Bright A_CustomMissile("PhasebanDarkMatterBallmini",54,-42,10)
	PVER K 0 Bright A_CustomMissile("PhasebanDarkMatterBallmini",54,42,-10)
	PVER K 0 Bright A_CustomMissile("PhasebanDarkMatterBallmini",16,-34,0)
	PVER K 4 Bright A_CustomMissile("PhasebanDarkMatterBallmini",16,34,0)
	TNT1 A 0 a_SpawnItemEx("PhaseTormentorJSpawner")
	goto See
  DarkMatter:
	TNT1 A 0 A_PlaySound("legbanished/see")
	PVER GHI 4 A_FaceTarget
	PVER K 2 Bright A_CustomMissile("DarkMatterBallRM",40,0)
	PVER K 0 Bright A_CustomMissile("DarkMatterBallRM",40,30,-5)
	PVER K 2 Bright A_CustomMissile("DarkMatterBallRM",40,-30,5)
	PVER K 0 Bright A_CustomMissile("DarkMatterBallRM",40,60,-5)
	PVER K 2 Bright A_CustomMissile("DarkMatterBallRM",40,-60,5)
	goto See
  CometBarrage:
	TNT1 A 0 A_PlaySound("legbanished/pain")
	PVER GH 4 A_FaceTarget
	TNT1 A 0 A_FaceTarget
	PVER HI 3 Bright A_CustomMissile("PArchonComet2",40,0,random(-3,3))
	TNT1 A 0 A_FaceTarget
	PVER HI 3 Bright A_CustomMissile("PArchonComet2",40,0,random(-3,3))
	TNT1 A 0 A_FaceTarget
	PVER HI 3 Bright A_CustomMissile("PArchonComet2",40,0,random(-3,3))
	goto See
  PhaseSouls:
    PVER D 0 A_JumpIf(user_souls >= 4,"DarkMatter")
    PVER DE 4 Bright A_FaceTarget
    PVER F 2 A_FaceTarget
	PVER F 3 Bright A_PainAttack("BanPhaseSoul")
    PVER F 2 A_FaceTarget
	PVER F 3 Bright A_PainAttack("BanPhaseSoul")
    PVER F 2 A_FaceTarget
	PVER F 3 Bright A_PainAttack("BanPhaseSoul")
    PVER F 2 A_FaceTarget
	PVER F 3 Bright A_PainAttack("BanPhaseSoul")
    PVER F 2 A_FaceTarget
	PVER F 3 Bright A_PainAttack("BanPhaseSoul")
    TNT1 A 0 A_SetUserVar(user_souls,user_souls+1)
    Goto See
  Pain:
	PVER L 0 A_Jump(20,"Teleport")
	PVER L 6
	PVER Q 0 A_RadiusGive("PhaseMindfuck",300,RGF_PLAYERS)
	PVER L 6 A_Pain
	PVER L 0 A_Jump(128,"Missile")
	goto See
  Death:
    //TNT1 A 0 A_SetTranslucent(1)
    TNT1 A 0 A_SetTranslucent(0.85)
	PVER L 20 A_Scream
	TNT1 A 0 A_RadiusGive("PhaseMindfuck",300,RGF_PLAYERS)
	PVER M 8 bright
	TNT1 A 0 A_Playsound("BFlan/LightningExp",7)
	TNT1 A 0 A_SpawnItem("PurpleDTBFGEx",0,30)
	TNT1 AAAAAA 0 A_SpawnItemEx("PurpleParticleSpawner", 0, 0, random(30,50), 0, 0, 0, 0, 128)  
	TNT1 AAAAAA 0 A_CustomMissile("SmokeFX",random(30,50), 0, random(0,360), 2, random(0,360))
	TNT1 AAAAAAAAA 0 A_CustomMissile("PurpleKaboom",random(30,50),0,random(0,360),2,random(0,360))
	TNT1 A 0 Radius_Quake(20,8,0,12,0)
	TNT1 A 0 A_RadiusGive("PhaseMindfuck",96,RGF_PLAYERS)
	TNT1 A 0 A_Explode(260,200)
	PVER N 4 bright A_SpawnItemEx("MutantGibbedGenerator",Random(10,-10),Random(10,-10),Random(20,40),0,0,0,0,128,0)
	TNT1 A 0 A_RadiusGive("PhaseMindfuck",96,RGF_PLAYERS)
	TNT1 A 0 A_Explode(260,200)
	TNT1 A 0 A_NOBLOCKING
	TNT1 A 0 A_RadiusGive("PhaseMindfuck",96,RGF_PLAYERS)
	PVER NOO 4 bright A_SpawnItemEx("MutantGibbedGenerator",Random(10,-10),Random(10,-10),Random(20,40),0,0,0,0,128,0)
	TNT1 AA 0 A_SpawnItemEx("MutantGibbedGenerator",Random(10,-10),Random(10,-10),Random(20,40),0,0,0,0,128,0)
	TNT1 A 0 A_PainDie("BanPhaseSoul")
	PVER PPPPP 0 bright A_CustomMissile("PhaseBanFlesh1",random(0,90),random(0,40),random(-180,180),2,random(-15,15))
	PVER PPPPP 0 bright A_CustomMissile("PhaseBanFlesh2",random(0,90),random(0,40),random(-180,180),2,random(-15,15))
	PVER PPPPPPPPPP 0 A_CustomMissile("PhaseBanFlesh3",random(0,90),random(0,40),random(-180,180),2,random(-15,15))
	PVER PPPPPPPPPP 0 A_CustomMissile("PhaseBanFlesh4",random(0,90),random(0,40),random(-180,180),2,random(-15,15))
	PVER PPPPPPPPPP 0 A_CustomMissile("PhaseBanFlesh5",random(0,90),random(0,40),random(-180,180),2,random(-15,15))
	PVER PPPPPPPPPP 0 A_CustomMissile("PhaseBanFlesh6",random(0,90),random(0,40),random(-180,180),2,random(-15,15))
	PVER P 0 bright A_CustomMissile("PhaseBanBigArm1",40,-40,-90,2,random(-1,1))
	PVER P 0 bright A_CustomMissile("PhaseBanBigArm2",40,40,90,2,random(-1,1))
	PVER P 0 bright A_CustomMissile("PhaseBanSmallArm1",100,-30,-90,2,random(-15,15))
	PVER P 0 bright A_CustomMissile("PhaseBanSmallArm1",100,30,90,2,random(-15,15))
	PVER P 0 bright A_CustomMissile("PhaseBanSmallArm2",100,-30,-90,2,random(-15,15))
	PVER P 0 bright A_CustomMissile("PhaseBanSmallArm2",100,30,90,2,random(-15,15))
	PVER P 0 bright A_CustomMissile("PhaseBanHorn1",110,-16,-90,2,random(-15,15))
	PVER P 0 bright A_CustomMissile("PhaseBanHorn2",110,16,90,2,random(-15,15))
	PVER PQRSTU 8 BRIGHT
	PVER V 8 bright 
	stop
	}
}

Actor PhaseBanSeekBall : PhaseImpBall
{
Speed 35
FastSpeed 20
Damagetype "EleSouls"
States
{
Spawn:
TNT1 A 0 A_SeekerMissile(6,0)
TNT1 A 0 A_radiusgive("phasemindfuck",80, RGF_PLAYERS)
TNT1 A 0 A_BishopMissileWeave
DIMB A 1 Bright A_SpawnItemEx("PhaseBallTrail",0,0,0,0,0,0,0,128,0)
TNT1 A 0 A_BishopMissileWeave
DIMB B 1 Bright A_SpawnItemEx("PhaseBallTrail",0,0,0,0,0,0,0,128,0)
Loop
Death:
TNT1 A 0
TNT1 A 0 A_radiusgive("phasemindfuck",80, RGF_PLAYERS)
TNT1 A 0 A_SpawnItemEx("PurpleParticleSpawner", 0, 0, 0, 0, 0, 0, 0, 128) 
TNT1 AAA 0 A_CustomMissile("Kaboom8", 0, 0, random(0,360), 2, random(0,360))
TNT1 AAA 0 A_CustomMissile("SmokeFX4", 0, 0, random(0,360), 2, random(0,360))	
DIMB CDE 3 Bright
Stop
}
}

actor PhaseBanSlowBall : phaseimpball
{
  damage 5
  DamageType "EleSouls"
  speed 8
  states
  {
  spawn:
    TNT1 A 0 A_SeekerMissile(4,4)
	PFRT A 1 bright A_SpawnItemEx("phaseballtrail2")
	PFRT A 1 bright A_SpawnItemEx("phaseballtrail2")
	TNT1 A 0 A_Weave(1.0, 1.0, 5.0, 1.0)
	PFRT B 1 bright A_SpawnItemEx("phaseballtrail2")
	PFRT B 1 bright A_SpawnItemEx("phaseballtrail2")
	loop
  death:
	TNT1 A 0
	TNT1 A 0 A_SpawnItemEx("PurpleParticleSpawner", 0, 0, 0, 0, 0, 0, 0, 128) 
	TNT1 AAA 0 A_CustomMissile("Kaboom8", 0, 0, random(0,360), 2, random(0,360))
	TNT1 AAA 0 A_CustomMissile("SmokeFX4", 0, 0, random(0,360), 2, random(0,360))
	TNT1 A 0 a_radiusgive("phasemindfuck", 96, RGF_PLAYERS)
    PFRT CDEFG 2 Bright
    Stop
  }
}

actor PhasebanDarkMatterBallmini : darkmatterballRM
{
Damagetype "EleSouls"
Damage 10
Scale 0.25
-EXTREMEDEATH
States
{
    Death:
	TNT1 A 0 A_SpawnItemEx("DShockWave1", 0, 0, 15, 0, 0, 0, 0, 128)
	TNT1 A 0 A_SpawnItemEx("ShadowVaporSpawnerRM",0,0,0,0,0,0,0,32)
	TNT1 A 0 A_Explode(30,60,0)
	TNT1 A 0 A_radiusgive("phasemindfuck",80, RGF_PLAYERS)
	TNT1 A 15 Radius_Quake(5,5,0,20,0)
	Stop
	}
}

Actor PhaseBanPhazoLaser : PhazoLaser
{
 Damagetype "EleSouls"
 //Missiletype "PhaseBanPhazoLaserTrail"
 //Scale 1
  States
   {
  Spawn:
    TNT1 A 0 A_radiusgive("phasemindfuck",10, RGF_PLAYERS)
	PPB1 ABCBABCB 1 Bright A_Weave(0,4,0,2)
    //TNT1 A 0 A_radiusgive("phasemindfuck",10, RGF_PLAYERS)
	PPB1 ABCBABCB 1 Bright A_Weave(0,4,0,2)
	Loop
  Death:
	TNT1 A 0
    TNT1 A 0 A_radiusgive("phasemindfuck",80, RGF_PLAYERS)
	TNT1 A 0 A_SpawnItemEx("PurpleParticleSpawner", 0, 0, 0, 0, 0, 0, 0, 128) 
	TNT1 AAA 0 A_CustomMissile("Kaboom8", 0, 0, random(0,360), 2, random(0,360))
	TNT1 AAA 0 A_CustomMissile("SmokeFX4", 0, 0, random(0,360), 2, random(0,360))
	PPB1 DDFFGGGGG 2 Bright A_FadeOut
	Stop
   }
}

ACTOR PhaseBanSmokeSpawner : LegendaryRedParticleSpawner
{
  +CLIENTSIDEONLY
  States
  {
  Spawn:
    TNT1 A 0
    TNT1 A 0 A_JumpIf(ACS_ExecuteWithResult(304) == 1,"NULL")
    TNT1 AAAAA 0 A_SpawnItemEx("PHellionSmoke",random(32,-32),random(32,-32),random(12,64),0,0,random(1,3),0,128,0)
    TNT1 A 1
    Stop		
  }
}

ACTOR BanPhaseSoul : PhaseSoul
{
Species "EleSouls"
DamageFactor "BombBreath", 0.0
DamageFactor "EleSouls", 0.0
DamageFactor "SoulToxic", 0.0
DropItem "LifeEssence" 50
DropItem "ArmorBonusMax" 50
DropItem "DemonAmmo" 50 60
+NOINFIGHTING
+NOTARGET
+THRUSPECIES
Tag "\ctPhase Soul\c-"
}

ACTOR PhaseBanFlesh1
{
   Speed 16
   Mass 100
   Radius 1
   Height 1
   PROJECTILE
   +THRUGHOST
   -NOGRAVITY
   States
   {
   Spawn:
      PVF1 ACEGIKM 5 A_SpawnItemEx("PurpleGibTrail", 0, 0, 0, Random(-1,1), Random(-1,1), Random(-1,1), 0, 128)
      loop
   Death:
      PVF1 O 3
      PVF1 Q -1
      stop
   }
}

ACTOR PhaseBanFlesh2 : PhaseBanFlesh1
{
   States
   {
   Spawn:
      PVF1 BDFHJLN 5 A_SpawnItemEx("PurpleGibTrail", 0, 0, 0, Random(-1,1), Random(-1,1), Random(-1,1), 0, 128)
      loop
   Death:
      PVF1 P 3
	  PVF1 R -1
      stop
   }
}

ACTOR PhaseBanFlesh3 : PhaseBanFlesh1
{
   States
   {
   Spawn:
      PVF2 ACEG 5 A_SpawnItemEx("PurpleGibTrail", 0, 0, 0, Random(-1,1), Random(-1,1), Random(-1,1), 0, 128)
      loop
   Death:
      PVF2 I -1
      loop
   }
}

ACTOR PhaseBanFlesh4 : PhaseBanFlesh1
{
   States
   {
   Spawn:
      PVF2 BDFH 5 A_SpawnItemEx("PurpleGibTrail", 0, 0, 0, Random(-1,1), Random(-1,1), Random(-1,1), 0, 128)
      loop
   Death:
      PVF2 J -1
      loop
   }
}

ACTOR PhaseBanFlesh5 : PhaseBanFlesh1
{
   States
   {
   Spawn:
      PVF3 ACEGI 5 A_SpawnItemEx("PurpleGibTrail", 0, 0, 0, Random(-1,1), Random(-1,1), Random(-1,1), 0, 128)
      loop
   Death:
      PVF3 K -1
      loop
   }
}

ACTOR PhaseBanFlesh6 : PhaseBanFlesh1
{
   States
   {
   Spawn:
      PVF3 BDFHJ 5 A_SpawnItemEx("PurpleGibTrail", 0, 0, 0, Random(-1,1), Random(-1,1), Random(-1,1), 0, 128)
      loop
   Death:
      PVF3 L -1
      loop
   }
}

ACTOR PhaseBanBigArm1 : PhaseBanFlesh1
{
   States
   {
   Spawn:
	  PVF4 ACEGI 5 A_SpawnItemEx("PurpleGibTrail", 0, 0, 0, Random(-1,1), Random(-1,1), Random(-1,1), 0, 128)
      loop
   Death:
      PVF4 K 3
      PVF4 M -1
      stop
   }
}

ACTOR PhaseBanBigArm2 : PhaseBanFlesh1
{
   States
   {
   Spawn:
      PVF4 BDFHJ 5 A_SpawnItemEx("PurpleGibTrail", 0, 0, 0, Random(-1,1), Random(-1,1), Random(-1,1), 0, 128)
      loop
   Death:
      PVF4 L 3
      PVF4 N -1
      stop
   }
}

ACTOR PhaseBanSmallArm1 : PhaseBanFlesh1
{
   States
   {
   Spawn:
      PVF5 ACEG 5 A_SpawnItemEx("PurpleGibTrail", 0, 0, 0, Random(-1,1), Random(-1,1), Random(-1,1), 0, 128)
      loop
   Death:
      PVF5 I -1
      stop
   }
}

ACTOR PhaseBanSmallArm2 : PhaseBanFlesh1
{
   States
   {
   Spawn:
      PVF5 BDFH 5 A_SpawnItemEx("PurpleGibTrail", 0, 0, 0, Random(-1,1), Random(-1,1), Random(-1,1), 0, 128)
      loop
   Death:
      PVF5 J -1
      stop
   }
}

ACTOR PhaseBanHorn1 : PhaseBanFlesh1
{
   States
   {
   Spawn:
      PVF6 ACEGI 5
      loop
   Death:
      PVF6 K -1
      stop
   }
}

ACTOR PhaseBanHorn2 : PhaseBanFlesh1
{
   States
   {
   Spawn:
      PVF6 BDFHJ 5
      loop
   Death:
      PVF6 L -1
      stop
   }
}

ACTOR PhaseTormentorASpawner : PhaseNightmareASpawner
{
  Scale 0.85
  States
  {
  Spawn:
	TNT1 A 0
	TNT1 A 0 A_SpawnItemEx("PhaseTormentorA", 0, 0, -20, random(3, -3)*0.5, random(3, -3)*0.5, random(6, 13)*0.5)
	stop
  }
}

ACTOR PhaseTormentorA : PhaseTormentorASpawner
{
  States
  {
  Spawn:
	TNT1 A 8
	PVER A 1 a_fadeout(0.1)
	goto spawn+1
  }
}

ACTOR PhaseTormentorBSpawner : PhaseNightmareASpawner
{
  Scale 1.0
  States
  {
  Spawn:
	TNT1 A 0
	TNT1 A 0 A_SpawnItemEx("PhaseTormentorB", 0, 0, -20, random(3, -3)*0.5, random(3, -3)*0.5, random(6, 13)*0.5)
	stop
  }
}

ACTOR PhaseTormentorB : PhaseTormentorASpawner
{
  States
  {
  Spawn:
	TNT1 A 8
	PVER B 1 a_fadeout(0.1)
	goto spawn+1
  }
}

ACTOR PhaseTormentorCSpawner : PhaseNightmareASpawner
{
  Scale 1.0
  States
  {
  Spawn:
	TNT1 A 0
	TNT1 A 0 A_SpawnItemEx("PhaseTormentorC", 0, 0, -20, random(3, -3)*0.5, random(3, -3)*0.5, random(6, 13)*0.5)
	stop
  }
}

ACTOR PhaseTormentorC : PhaseTormentorASpawner
{
  States
  {
  Spawn:
	TNT1 A 8
	PVER A 1 a_fadeout(0.1)
	goto spawn+1
  }
}

ACTOR PhaseTormentorDSpawner : PhaseNightmareASpawner
{
  Scale 1.0
  States
  {
  Spawn:
	TNT1 A 0
	TNT1 A 0 A_SpawnItemEx("PhaseTormentorD", 0, 0, -20, random(3, -3)*0.5, random(3, -3)*0.5, random(6, 13)*0.5)
	stop
  }
}

ACTOR PhaseTormentorD : PhaseTormentorASpawner
{
  States
  {
  Spawn:
	TNT1 A 8
	PVER D 1 a_fadeout(0.1)
	goto spawn+1
  }
}

ACTOR PhaseTormentorESpawner : PhaseNightmareASpawner
{
  Scale 1.0
  States
  {
  Spawn:
	TNT1 A 0
	TNT1 A 0 A_SpawnItemEx("PhaseTormentorE", 0, 0, -20, random(3, -3)*0.5, random(3, -3)*0.5, random(6, 13)*0.5)
	stop
  }
}

ACTOR PhaseTormentorE : PhaseTormentorASpawner
{
  States
  {
  Spawn:
	TNT1 A 8
	PVER E 1 a_fadeout(0.1)
	goto spawn+1
  }
}

ACTOR PhaseTormentorFSpawner : PhaseNightmareASpawner
{
  Scale 1.0
  States
  {
  Spawn:
	TNT1 A 0
	TNT1 A 0 A_SpawnItemEx("PhaseTormentorF", 0, 0, -20, random(3, -3)*0.5, random(3, -3)*0.5, random(6, 13)*0.5)
	stop
  }
}

ACTOR PhaseTormentorF : PhaseTormentorASpawner
{
  States
  {
  Spawn:
	TNT1 A 8
	PVER F 1 a_fadeout(0.1)
	goto spawn+1
  }
}

ACTOR PhaseTormentorJSpawner : PhaseNightmareASpawner
{
  Scale 1.0
  States
  {
  Spawn:
	TNT1 A 0
	TNT1 A 0 A_SpawnItemEx("PhaseTormentorJ", 0, 0, -20, random(3, -3)*0.5, random(3, -3)*0.5, random(6, 13)*0.5)
	stop
  }
}

ACTOR PhaseTormentorJ : PhaseTormentorJSpawner
{
  States
  {
  Spawn:
	TNT1 A 8
	PVER F 1 a_fadeout(0.1)
	goto spawn+1
  }
}