ACTOR ChainmailEttin : Ettin
{
//Creator: "pdxbla's "VDP-MonsterRandomizer" & ElAnexo & Fluffy
//Origin: Realm667
//Sprite: CETN
//Title: "Chainmail Ettin"
  Game Doom
  Species "Fiends"
  Health 1000
  Radius 25
  Height 56
  Mass 175
  Speed 13
  PainChance 30
  Meleerange 1
  MaxTargetRange 176
  SeeSound "EttinSight"
  AttackSound "EttinSwing"
  PainSound "EttinPain"
  DeathSound "EttinDeath"
  ActiveSound "EttinActive"
  HowlSound "PuppyBeat"
  Obituary "%o was beat down by an Ettin."
  Damagefactor 0.55
  +MISSILEMORE 
  +MISSILEEVENMORE
  //+NOBLOOD
  tag "\c[cyan]Chainmail Ettin\c-"
  DropItem "BossLifeEssence" 256
  DropItem "BossArmorBonusMax" 256
  DropItem "BossLifeEssence", 80, 32
  DropItem "ExtraArmor" 80
  DropItem "DemonTechAxe", 60, 1
  States
  {
  Spawn:
    CETN AA 10 A_Look
    Loop
  See:
	CETN AABB 2 A_Chase
	TNT1 A 0 A_SpawnItem("BeefyStep",0,0,0,0)
	CETN CCDD 2 A_Chase
	TNT1 A 0 A_SpawnItem("BeefyStep",0,0,0,0)
    Loop
  Pain:
    CETN H 7 A_Pain
    Goto See
  Melee:
    CETN EF 6 A_FaceTarget
    CETN G 8 A_CustomMeleeAttack(random(1,8)*4, "EttinHit")
    Goto See
  Missile:
	CETN EF 6 A_FaceTarget
	CETN G 8 A_CustomMissile("EttinMaceProjectile", 40, 0, 0, CMF_OFFSETPITCH, 10)
	Goto See
  Death:
    CETN IJ 4
    CETN K 4 A_Scream
    CETN L 4 A_NoBlocking
    CETN M 4 A_QueueCorpse
    CETN NOP 4
    CETN Q -1
    Stop
  XDeath:     
    CETN R 4
    CETN S 4 A_NoBlocking
    CETN T 4 A_SpawnItemEx("ChainmailEttinMace",0,0,8.5,random[DropMace](-128,127)*0.03125,random[DropMace](-128,127)*0.03125,10+random[DropMace](0,255)*0.015625,0,SXF_ABSOLUTEVELOCITY)
    CETN U 3 A_Scream
	CETN U 1 A_SpawnItemEx("GibbedGenerator",0,0,0,0,0,0,0,128,0)
    CETN V 4 A_QueueCorpse
    CETN "WXYZ[" 4
    CETN "\" -1
    Stop
  Ice:
    CETN "]" 5 A_FreezeDeath
    CETN "]" 1 A_FreezeDeathChunks
    Wait
  }
}

Actor EttinMaceProjectile
{
  Radius 15
  Height 15
  Speed 20	
  Damage 13
  Gravity 0.5
  PROJECTILE
  -NOGRAVITY
  +THRUGHOST
  +EXPLODEONWATER
  BounceType "Hexen"
  BounceFactor 0.8
  BounceCount 3
  SeeSound "EttinSwing"
  BounceSound "mace/bounce"
  DeathSound "mace/bounce"
  States
  {
  Spawn:
    ET7B MNOP 5		
    Loop
  Death:
    ET7B Q 5 A_Gravity
    ET7B R 5 A_QueueCorpse
	ET7B S 60
	ET7B SSSSSSSSS 1 A_FadeOut(0.1)
    Stop
  }
}

ACTOR ChainmailEttinMace
{
	Radius 5
	Height 5
	+DROPOFF
	+CORPSE
	+NOTELEPORT
	+FLOORCLIP
	States
	{
	Spawn:
		ET7B MNOP 5
		Loop
	Crash:
		ET7B Q 5
		ET7B R 5 A_QueueCorpse
		ET7B S -1
		Stop
	}
}