Actor Butcher
{
//Creator: "pdxbla's "VDP-MonsterRandomizer" & ElAnexo & Fluffy
//Origin: Realm667
//Sprite: BCHR
//Title: "Butcher"
  Obituary "%o was mashed by a Butcher"
  HitObituary "%o was mashed by a Butcher"
  Species "Fiends"
  Health 825
  Radius 22
  Height 56
  Mass 600
  Speed 6
  MeleeDamage 46
  MeleeRange 58
  PainChance 0
  Damagefactor "0.39"
  SeeSound "Butcher/Sight"
  PainSound "Butcher/Pain"
  DeathSound "Butcher/Death"
  ActiveSound "Butcher/Active"
  MeleeSound "Butcher/Melee"
  Monster
  tag "\c[darkred]Butcher\c-"
  DropItem "BossLifeEssence" 256
  DropItem "BossArmorBonusMax" 256
  DropItem "Backpack" 40
  DropItem "BossLifeEssence", 128, 32
  DropItem "DemonTechAxe", 60, 1
  DropItem "ExtraArmor" 128
  +FloorClip
  +NOBLOOD
  States
  {
  Spawn:
    BCHR AAAAAAAAAABBBBBBBBBB 1 A_Look
    Loop
  See:
    BCHR AAAAAABBBBBB 1 A_Chase
    BCHR C 0 A_PlaySoundEx("Butcher/Step", "SoundSlot7", 0)
    BCHR CCCCCCDDDDDD 1 A_Chase
    BCHR A 0 A_PlaySoundEx("Butcher/Step", "SoundSlot7", 0)
    Loop
  Melee:
    BCHR EF 6 A_FaceTarget
    BCHR G 0 A_PlaySound("Butcher/Miss")
    BCHR G 10 A_VileAttack("Butcher/Melee",random(100,135),0,100,2,"None")
    Goto See
  Pain:
    BCHR H 3
    BCHR H 3 A_Pain
    Goto See
  Death:
    BCHR H 12 A_Scream
    BCHR I 0 A_PlaySound("Butcher/Explode")
    BCHR IJ 6
	BCHR K 6 A_SpawnItemEx("GibbedGenerator",0,0,0,0,0,0,0,128,0)
    BCHR L 0 A_FaceTarget
    BCHR L 6 A_SpawnItemEx("ButcherHammer", 0, -18, 24, 3, 0, 3, -85, 128)
    BCHR M 6 A_NoBlocking
    BCHR NOP 6
    BCHR Q -1
    Stop
   }
}

Actor ButcherHammer
{
  +DoomBounce
  +NoBlockMap
  Gravity 0.4
  Speed 3
  States
  {
  Spawn:
    BRHM ABCD 5
    BRHM E -1
    Stop
  }
}

Actor ButcherHammer2 : ButcherHammer
{
  +SHADOW
  RenderStyle OptFuzzy
  Alpha 0.5
}

ACTOR Butcher2 : Butcher
{
  +SHADOW
  RenderStyle OptFuzzy
  Alpha 0.5
  States
  {
  Death:
    BCHR H 12 A_Scream
    BCHR I 0 A_PlaySound("Butcher/Explode")
    BCHR IJK 6
    BCHR L 0 A_FaceTarget
    BCHR L 6 A_SpawnItemEx("ButcherHammer2", 0, -18, 24, 3, 0, 3, -85, 128)
    BCHR M 6 A_NoBlocking
    BCHR NOP 6
    BCHR Q -1
    Stop
   }
}